[gentoo-commits] gentoo-x86 commit in media-gfx/xsane: xsane-0.997.ebuild ChangeLog

[Patrick Kursawe (phosphan)]

phosphan    09/10/03 07:46:17

  Modified:             ChangeLog
  Added:                xsane-0.997.ebuild
  Log:
  Version bump, see bug #287360
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.82                 media-gfx/xsane/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/xsane/ChangeLog?rev=1.82&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/xsane/ChangeLog?rev=1.82&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/xsane/ChangeLog?r1=1.81&r2=1.82

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/xsane/ChangeLog,v
retrieving revision 1.81
retrieving revision 1.82
diff -u -r1.81 -r1.82
--- ChangeLog	1 Oct 2009 19:39:46 -0000	1.81
+++ ChangeLog	3 Oct 2009 07:46:16 -0000	1.82
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/xsane
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/xsane/ChangeLog,v 1.81 2009/10/01 19:39:46 phosphan Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/xsane/ChangeLog,v 1.82 2009/10/03 07:46:16 phosphan Exp $
+
+*xsane-0.997 (03 Oct 2009)
+
+  03 Oct 2009; Patrick Kursawe <phosphan@g.o> +xsane-0.997.ebuild:
+  Version bump, see bug #287360
 
   01 Oct 2009; Patrick Kursawe <phosphan@g.o> xsane-0.996.ebuild:
   Removing duplicate desktop file (bug #286503).



1.1                  media-gfx/xsane/xsane-0.997.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/xsane/xsane-0.997.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/xsane/xsane-0.997.ebuild?rev=1.1&content-type=text/plain

Index: xsane-0.997.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/xsane/xsane-0.997.ebuild,v 1.1 2009/10/03 07:46:16 phosphan Exp $

inherit eutils

DESCRIPTION="graphical scanning frontend"
HOMEPAGE="http://www.xsane.org/"
SRC_URI="http://www.xsane.org/download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="nls jpeg png tiff gimp lcms"

RDEPEND="media-gfx/sane-backends
	>=x11-libs/gtk+-2.0
	jpeg? ( media-libs/jpeg )
	png? ( media-libs/libpng )
	tiff? ( media-libs/tiff )
	gimp? ( media-gfx/gimp )
	lcms? ( media-libs/lcms )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_setup() {
	export OLDXSANE
	if has_version '<=media-gfx/xsane-0.93'; then
		OLDXSANE="yes"
	else
		OLDXSANE="no"
	fi
}

src_compile() {
	local extraCPPflags
	if use lcms; then
		extraCPPflags="-I /usr/include/lcms"
	fi
	CPPFLAGS="${CPPFLAGS} ${extraCPPflags}" econf --enable-gtk2 \
		$(use_enable nls) \
		$(use_enable jpeg) \
		$(use_enable png) \
		$(use_enable tiff) \
		$(use_enable gimp) \
		$(use_enable lcms) \
		|| die
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc xsane.*
	# link xsane so it is seen as a plugin in gimp
	if use gimp; then
		local plugindir
		if [ -x /usr/bin/gimptool ]; then
			plugindir="$(gimptool --gimpplugindir)/plug-ins"
		elif [ -x /usr/bin/gimptool-2.0 ]; then
			plugindir="$(gimptool-2.0 --gimpplugindir)/plug-ins"
		else
			die "Can't find GIMP plugin directory."
		fi
		dodir "${plugindir}"
		dosym /usr/bin/xsane "${plugindir}"
	fi
	newicon src/xsane-48x48.png ${PN}.png
}

pkg_postinst() {
	if [ x${OLDXSANE} = 'xyes' ]; then
		ewarn "If you are upgrading from <=xsane-0.93, please make sure to"
		ewarn "remove ~/.sane/xsane/xsane.rc _before_ you start xsane for"
		ewarn "the first time."
	fi
}