[gentoo-commits] gentoo-x86 commit in gnome-extra/evolution-data-server: metadata.xml ChangeLog evolution-data-server-3.2.1.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    11/10/31 04:57:55

  Modified:             metadata.xml ChangeLog
  Added:                evolution-data-server-3.2.1.ebuild
  Log:
  Bump to 3.2.1 from the gnome overlay. The venerable gentoo_etc_services patch is not needed for any version of baselayout in portage. Drop alpha, arm, ia64, ppc, ppc64, sparc keywords due to new liboauth, libgdata, and gnome-online-accounts dependencies. Keywording bug will be filed later for all of gnome-3.2.
  
  (Portage version: 2.2.0_alpha72/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  gnome-extra/evolution-data-server/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	18 Aug 2011 07:48:34 -0000	1.3
+++ metadata.xml	31 Oct 2011 04:57:54 -0000	1.4
@@ -3,8 +3,11 @@
 <pkgmetadata>
 	<herd>gnome</herd>
 	<use>
+		<flag name="gnome-online-accounts">Enable using
+			<pkg>net-libs/gnome-online-accounts</pkg> for authorization</flag>
 		<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
 			for introspection</flag>
+		<flag name="vala">Build <pkg>dev-lang/vala</pkg> bindings</flag>
 		<flag name="weather">Enable optional weather calendar support</flag>
 	</use>
 </pkgmetadata>



1.316                gnome-extra/evolution-data-server/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?rev=1.316&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?rev=1.316&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?r1=1.315&r2=1.316

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v
retrieving revision 1.315
retrieving revision 1.316
diff -u -r1.315 -r1.316
--- ChangeLog	30 Oct 2011 16:18:51 -0000	1.315
+++ ChangeLog	31 Oct 2011 04:57:54 -0000	1.316
@@ -1,6 +1,15 @@
 # ChangeLog for gnome-extra/evolution-data-server
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v 1.315 2011/10/30 16:18:51 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v 1.316 2011/10/31 04:57:54 tetromino Exp $
+
+*evolution-data-server-3.2.1 (31 Oct 2011)
+
+  31 Oct 2011; Alexandre Rostovtsev <tetromino@g.o>
+  +evolution-data-server-3.2.1.ebuild, metadata.xml:
+  Bump to 3.2.1 from the gnome overlay. The venerable gentoo_etc_services patch
+  is not needed for any version of baselayout in portage. Drop alpha, arm,
+  ia64, ppc, ppc64, sparc keywords due to new liboauth, libgdata, and
+  gnome-online-accounts dependencies.
 
   30 Oct 2011; Raúl Porcel <armin76@g.o>
   evolution-data-server-2.32.3-r1.ebuild:



1.1                  gnome-extra/evolution-data-server/evolution-data-server-3.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-3.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-3.2.1.ebuild?rev=1.1&content-type=text/plain

Index: evolution-data-server-3.2.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-3.2.1.ebuild,v 1.1 2011/10/31 04:57:54 tetromino Exp $

EAPI="4"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"

inherit autotools db-use eutils flag-o-matic gnome2 versionator virtualx

DESCRIPTION="Evolution groupware backend"
HOMEPAGE="http://www.gnome.org/projects/evolution/"

LICENSE="LGPL-2 BSD DB"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-solaris"
IUSE="doc +gnome-online-accounts +introspection ipv6 ldap kerberos ssl vala +weather"

# GNOME3: How do we slot libedataserverui-3.0.so?
# Also, libedata-cal-1.2.so and libecal-1.2.so use gtk-3, but aren't slotted
RDEPEND=">=dev-libs/glib-2.28:2
	>=x11-libs/gtk+-3.0:3
	>=gnome-base/gconf-2
	>=dev-db/sqlite-3.5
	>=dev-libs/libgdata-0.9.1
	>=gnome-base/gnome-keyring-2.20.1
	>=dev-libs/libical-0.43
	>=net-libs/libsoup-2.31.2:2.4
	>=dev-libs/libxml2-2
	>=sys-libs/db-4
	sys-libs/zlib
	virtual/libiconv
	gnome-online-accounts? (
		>=net-libs/gnome-online-accounts-3.1.1
		>=net-libs/liboauth-0.9.4 )
	introspection? ( >=dev-libs/gobject-introspection-0.9.12 )
	kerberos? ( virtual/krb5 )
	ldap? ( >=net-nds/openldap-2 )
	ssl? (
		>=dev-libs/nspr-4.4
		>=dev-libs/nss-3.9 )
	weather? ( >=dev-libs/libgweather-2.90.0:2 )
"
DEPEND="${RDEPEND}
	dev-lang/perl
	dev-util/gperf
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.35.5
	sys-devel/bison
	>=gnome-base/gnome-common-2
	>=dev-util/gtk-doc-am-1.9
	>=sys-devel/gettext-0.17
	doc? ( >=dev-util/gtk-doc-1.9 )
	vala? ( >=dev-lang/vala-0.13.0:0.14[vapigen] )"
# eautoreconf needs:
#	>=gnome-base/gnome-common-2
#	>=dev-util/gtk-doc-am-1.9

REQUIRED_USE="vala? ( introspection )"

# FIXME
RESTRICT="test"

pkg_setup() {
	DOCS="ChangeLog MAINTAINERS NEWS TODO"
	# Uh, what to do about dbus-call-timeout ?
	G2CONF="${G2CONF}
		$(use_enable gnome-online-accounts goa)
		$(use_enable ipv6)
		$(use_with kerberos krb5 ${EPREFIX}/usr)
		$(use_with ldap openldap)
		$(use_enable ssl ssl)
		$(use_enable ssl smime)
		$(use_enable vala vala-bindings)
		$(use_enable weather)
		--enable-calendar
		--enable-nntp
		--enable-largefile
		--with-libdb=${EPREFIX}/usr"
	if use vala; then
		G2CONF="${G2CONF}
			VALAC=$(type -P valac-0.14) VAPIGEN=$(type -P vapigen-0.14)"
	fi
}

src_prepare() {
	gnome2_src_prepare

	# GNOME bug 611353 (skips failing test atm)
	# XXX: uncomment when there's a proper fix
	#epatch "${FILESDIR}/e-d-s-camel-skip-failing-test.patch"

	# GNOME bug 621763 (skip failing test-ebook-stress-factory--fifo)
	#sed -e 's/\(SUBDIRS =.*\)ebook/\1/' \
	#	-i addressbook/tests/Makefile.{am,in} \
	#	|| die "failing test sed 1 failed"

	# /usr/include/db.h is always db-1 on FreeBSD
	# so include the right dir in CPPFLAGS
	append-cppflags "-I$(db_includedir)"

	# FIXME: Fix compilation flags crazyness
	# Touch configure.ac if doing eautoreconf
	sed 's/^\(AM_CPPFLAGS="\)$WARNING_FLAGS/\1/' \
		-i configure || die "sed failed"
}

src_install() {
	# Prevent this evolution-data-server from linking to libs in the installed
	# evolution-data-server libraries by adding -L arguments for build dirs to
	# every .la file's relink_command field, forcing libtool to look there
	# first during relinking. This will mangle the .la files installed by
	# make install, but we don't care because we will be punting them anyway.
	perl "${FILESDIR}/fix_relink_command.pl" . ||
		die "fix_relink_command.pl failed"
	gnome2_src_install

	if use ldap; then
		MY_MAJORV=$(get_version_component_range 1-2)
		insinto /etc/openldap/schema
		doins "${FILESDIR}"/calentry.schema || die "doins failed"
		dosym /usr/share/${PN}-${MY_MAJORV}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
	fi
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	unset ORBIT_SOCKETDIR
	unset SESSION_MANAGER
	export XDG_DATA_HOME="${T}"
	unset DISPLAY
	Xemake check || die "Tests failed."
}

pkg_postinst() {
	gnome2_pkg_postinst

	if use ldap; then
		elog ""
		elog "LDAP schemas needed by evolution are installed in /etc/openldap/schema"
	fi
}