[gentoo-commits] gentoo-x86 commit in app-i18n/fcitx: metadata.xml ChangeLog fcitx-4.2.4.ebuild

[Mu Qiao (qiaomuf)]

qiaomuf     12/06/07 06:28:17

  Modified:             metadata.xml ChangeLog
  Added:                fcitx-4.2.4.ebuild
  Log:
  Version bump for fcitx-4.2.4
  
  (Portage version: 2.1.10.60/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  app-i18n/fcitx/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/fcitx/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	21 Mar 2012 01:54:50 -0000	1.5
+++ metadata.xml	7 Jun 2012 06:28:17 -0000	1.6
@@ -7,10 +7,12 @@
 		<name>Mu Qiao</name>
 	</maintainer>
 	<use>
+		<flag name="gir">Enable GObject Introspection</flag>
 		<flag name="gtk3">Use GTK+3 instead of 2</flag>
 		<flag name='opencc'>Enable OpenCC for Chinese Transform</flag>
 		<flag name='pango'>Enable support for <pkg>x11-libs/pango</pkg></flag>
 		<flag name='qt'>Enable Qt IM Module</flag>
+		<flag name='snooper'>Enable Key Snooper for gtk app</flag>
 		<flag name='table'>Enable Table IM</flag>
 	</use>
 </pkgmetadata>



1.49                 app-i18n/fcitx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/fcitx/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	18 May 2012 14:21:32 -0000	1.48
+++ ChangeLog	7 Jun 2012 06:28:17 -0000	1.49
@@ -1,6 +1,11 @@
 # ChangeLog for app-i18n/fcitx
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/fcitx/ChangeLog,v 1.48 2012/05/18 14:21:32 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/fcitx/ChangeLog,v 1.49 2012/06/07 06:28:17 qiaomuf Exp $
+
+*fcitx-4.2.4 (07 Jun 2012)
+
+  07 Jun 2012; Mu Qiao <qiaomuf@g.o> +fcitx-4.2.4.ebuild, metadata.xml:
+  Version bump for fcitx-4.2.4
 
   18 May 2012; Joseph Jezak <josejx@g.o> fcitx-4.0.0.ebuild,
   fcitx-4.0.1.ebuild, fcitx-4.2.1.ebuild, fcitx-4.2.3.ebuild:



1.1                  app-i18n/fcitx/fcitx-4.2.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/fcitx-4.2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/fcitx/fcitx-4.2.4.ebuild?rev=1.1&content-type=text/plain

Index: fcitx-4.2.4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/fcitx/fcitx-4.2.4.ebuild,v 1.1 2012/06/07 06:28:17 qiaomuf Exp $

EAPI="3"

inherit multilib cmake-utils eutils

DESCRIPTION="Free Chinese Input Toy for X. Another Chinese XIM Input Method"
HOMEPAGE="http://www.fcitx.org/"
SRC_URI="http://fcitx.googlecode.com/files/${P}.tar.xz
		http://fcitx.googlecode.com/files/pinyin.tar.gz
		table? ( http://fcitx.googlecode.com/files/table.tar.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="+cairo debug gir gtk gtk3 lua opencc +pango qt snooper static-libs +table test"

RDEPEND="
	cairo? (
		x11-libs/cairo[X]
		pango? ( x11-libs/pango[X] )
		!pango? ( media-libs/fontconfig )
	)
	gtk? (
		x11-libs/gtk+:2
		dev-libs/glib:2
		dev-libs/dbus-glib
	)
	gtk3? (
		x11-libs/gtk+:3
		dev-libs/glib:2
		dev-libs/dbus-glib
	)
	lua? ( dev-lang/lua )
	opencc? ( app-i18n/opencc )
	qt? (
		x11-libs/qt-gui:4
		x11-libs/qt-dbus:4
	)
	sys-apps/dbus
	x11-libs/libX11"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	dev-util/intltool
	virtual/pkgconfig
	x11-proto/xproto"

update_gtk_immodules() {
	local GTK2_CONFDIR="/etc/gtk-2.0"
	# bug #366889
	if has_version '>=x11-libs/gtk+-2.22.1-r1:2' || has_multilib_profile ; then
		GTK2_CONFDIR="${GTK2_CONFDIR}/$(get_abi_CHOST)"
	fi
	mkdir -p "${EPREFIX}${GTK2_CONFDIR}"

	if [ -x "${EPREFIX}/usr/bin/gtk-query-immodules-2.0" ] ; then
		"${EPREFIX}/usr/bin/gtk-query-immodules-2.0" > "${EPREFIX}${GTK2_CONFDIR}/gtk.immodules"
	fi
}

update_gtk3_immodules() {
	if [ -x "${EPREFIX}/usr/bin/gtk-query-immodules-3.0" ] ; then
		"${EPREFIX}/usr/bin/gtk-query-immodules-3.0" --update-cache
	fi
}

src_prepare() {
	cp "${DISTDIR}/pinyin.tar.gz" "${S}/data" || die "pinyin.tar.gz is not found"
	if use table ; then
		cp "${DISTDIR}/table.tar.gz" "${S}/data/table" || die "table.tar.gz is not found"
	fi
}

src_configure() {
	local mycmakeargs="
		-DLIB_INSTALL_DIR=/usr/$(get_libdir)
		$(cmake-utils_use_enable cairo CARIO)
		$(cmake-utils_use_enable debug DEBUG)
		$(cmake-utils_use_enable gir GIR)
		$(cmake-utils_use_enable gtk GTK2_IM_MODULE)
		$(cmake-utils_use_enable gtk3 GTK3_IM_MODULE)
		$(cmake-utils_use_enable lua LUA)
		$(cmake-utils_use_enable opencc OPENCC)
		$(cmake-utils_use_enable pango PANGO)
		$(cmake-utils_use_enable qt QT_IM_MODULE)
		$(cmake-utils_use_enable snooper SNOOPER)
		$(cmake-utils_use_enable static-libs STATIC)
		$(cmake-utils_use_enable table TABLE)
		$(cmake-utils_use_enable test TEST)"
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	dodoc AUTHORS ChangeLog README THANKS TODO || die

	rm -rf "${ED}"/usr/share/fcitx/doc/ || die
	dodoc doc/pinyin.txt doc/cjkvinput.txt || die
	dohtml doc/wb_fh.htm || die
}

pkg_postinst() {
	use gtk && update_gtk_immodules
	use gtk3 && update_gtk3_immodules
	elog
	elog "You should export the following variables to use fcitx"
	elog " export XMODIFIERS=\"@im=fcitx\""
	elog " export XIM=fcitx"
	elog " export XIM_PROGRAM=fcitx"
	elog
}

pkg_postrm() {
	use gtk && update_gtk_immodules
	use gtk3 && update_gtk3_immodules
}