[gentoo-commits] gentoo-x86 commit in sys-apps/pciutils: ChangeLog pciutils-3.0.2.ebuild

[Robin H. Johnson (robbat2)]

robbat2     08/10/07 10:13:18

  Modified:             ChangeLog
  Added:                pciutils-3.0.2.ebuild
  Log:
  Bug #240292, version bump.
  (Portage version: 2.2_rc11/cvs/Linux 2.6.27-rc1-10246-gca5de40 x86_64)

Revision  Changes    Path
1.145                sys-apps/pciutils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pciutils/ChangeLog?rev=1.145&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pciutils/ChangeLog?rev=1.145&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pciutils/ChangeLog?r1=1.144&r2=1.145

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pciutils/ChangeLog,v
retrieving revision 1.144
retrieving revision 1.145
diff -p -w -b -B -u -u -r1.144 -r1.145
--- ChangeLog	25 Aug 2008 13:10:06 -0000	1.144
+++ ChangeLog	7 Oct 2008 10:13:18 -0000	1.145
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/pciutils
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/ChangeLog,v 1.144 2008/08/25 13:10:06 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/ChangeLog,v 1.145 2008/10/07 10:13:18 robbat2 Exp $
+
+*pciutils-3.0.2 (07 Oct 2008)
+
+  07 Oct 2008; Robin H. Johnson <robbat2@g.o>
+  +files/pciutils-3.0.0-locale-happiness.patch, +pciutils-3.0.2.ebuild:
+  Bug #240292, version bump.
 
   25 Aug 2008; Raúl Porcel <armin76@g.o> pciutils-3.0.0.ebuild:
   ia64 stable wrt #235028



1.1                  sys-apps/pciutils/pciutils-3.0.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pciutils/pciutils-3.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pciutils/pciutils-3.0.2.ebuild?rev=1.1&content-type=text/plain

Index: pciutils-3.0.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/pciutils-3.0.2.ebuild,v 1.1 2008/10/07 10:13:18 robbat2 Exp $

inherit eutils flag-o-matic toolchain-funcs multilib

DESCRIPTION="Various utilities dealing with the PCI bus"
HOMEPAGE="http://atrey.karlin.mff.cuni.cz/~mj/pciutils.html"
SRC_URI="ftp://atrey.karlin.mff.cuni.cz/pub/linux/pci/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="network-cron zlib"

DEPEND="zlib? ( sys-libs/zlib )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-3.0.0-build.patch #233314
	#epatch "${FILESDIR}"/${PN}-3.0.0-resolv.patch #218555 #Merged
	epatch "${FILESDIR}"/pcimodules-${PN}-3.0.0.patch
	epatch "${FILESDIR}"/${PN}-2.2.7-update-pciids-both-forms.patch
	epatch "${FILESDIR}"/${PN}-3.0.0-locale-happiness.patch
	sed -i -e "/^LIBDIR=/s:/lib:/$(get_libdir):" Makefile
}

uyesno() { use $1 && echo yes || echo no ; }
pemake() {
	emake \
		DNS="yes" \
		IDSDIR="/usr/share/misc" \
		MANDIR="/usr/share/man" \
		PREFIX="/usr" \
		SHARED="yes" \
		STRIP="" \
		ZLIB=$(uyesno zlib) \
		"$@"
}

src_compile() {
	tc-export AR CC RANLIB
	pemake OPT="${CFLAGS}" all pcimodules || die "emake failed"
}

src_install() {
	pemake DESTDIR="${D}" install install-lib || die
	dosbin pcimodules || die
	newman pcimodules.man pcimodules.8

	if use network-cron ; then
		exeinto /etc/cron.monthly
		newexe "${FILESDIR}"/pciutils.cron update-pciids \
			|| die "Failed to install update cronjob"
	fi

	# Install both forms until HAL has migrated
	if use zlib ; then
		local sharedir="${D}/usr/share/misc"
		elog "Providing a backwards compatibility non-compressed pci.ids"
		gzip -d <"${sharedir}"/pci.ids.gz >"${sharedir}"/pci.ids
	fi
}