[gentoo-commits] repo/gentoo:master commit in: sci-visualization/gle/

[Andrey Grozin]

commit:     318f6b2af9bde35c8bb573c6535e53ffc1c9fc5c
Author:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 31 03:19:00 2017 +0000
Commit:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
CommitDate: Sun Dec 31 03:19:00 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=318f6b2a

sci-visualization/gle: drop an optional Qt4 gui

Package-Manager: Portage-2.3.19, Repoman-2.3.6

 sci-visualization/gle/gle-4.2.5-r1.ebuild | 94 +++++++++++++++++++++++++++++++
 1 file changed, 94 insertions(+)

diff --git a/sci-visualization/gle/gle-4.2.5-r1.ebuild b/sci-visualization/gle/gle-4.2.5-r1.ebuild
new file mode 100644
index 00000000000..322a1e5c6b2
--- /dev/null
+++ b/sci-visualization/gle/gle-4.2.5-r1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils elisp-common flag-o-matic autotools
+
+DESCRIPTION="Graphics Layout Engine"
+HOMEPAGE="http://glx.sourceforge.net/"
+MY_P=${PN}-graphics-${PV}
+MAN_V=4.2.2
+SRC_URI="mirror://sourceforge/glx/${MY_P}f-src.tar.gz"
+SLOT="0"
+LICENSE="BSD-2 emacs? ( GPL-2 )"
+IUSE="X jpeg png tiff doc emacs vim-syntax"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="
+	sys-libs/ncurses:0=
+	X? ( x11-libs/libX11 )
+	jpeg? ( virtual/jpeg:0 )
+	png? ( media-libs/libpng:0= )
+	tiff? ( media-libs/tiff:0 )
+	doc? ( dev-texlive/texlive-latexextra )
+	emacs? ( virtual/emacs )"
+
+RDEPEND="${DEPEND}
+	app-text/ghostscript-gpl
+	virtual/latex-base
+	vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-4.2.4b-parallel.patch
+	eaclocal
+	eautoconf
+}
+
+src_configure() {
+	# CPPFLAGS are understood as C++ flags
+	append-cppflags ${CXXFLAGS}
+	econf \
+		--without-rpath \
+		--with-manip \
+		$(use_with X x) \
+		$(use_with jpeg) \
+		$(use_with png) \
+		$(use_with tiff)
+}
+
+src_compile() {
+	emake
+	if use doc; then
+		emake -j1 doc
+	fi
+	if use emacs; then
+		cd contrib/editors/highlighting
+		mv ${PN}-emacs.el ${PN}-mode.el
+		elisp-compile ${PN}-mode.el || die
+	fi
+}
+
+src_install() {
+	# -jN failed to install some data files
+	emake -j1 DESTDIR="${D}" install
+	rm -rf "${ED}"/usr/share/doc/gle-graphics
+	dodoc README.txt
+
+	if use doc; then
+		insinto /usr/share/doc/${PF}
+		doins build/doc/gle-manual.pdf
+	fi
+
+	if use emacs; then
+		elisp-install ${PN} contrib/editors/highlighting/gle-mode.{el,elc} || die
+		elisp-site-file-install "${FILESDIR}"/64gle-gentoo.el || die
+	fi
+
+	if use vim-syntax ; then
+		dodir /usr/share/vim/vimfiles/{ftplugins,indent,syntax}
+		cd contrib/editors/highlighting/vim || die
+		chmod 644 ftplugin/* indent/* syntax/*
+		insinto /usr/share/vim/vimfiles
+		doins -r ftplugin indent syntax
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}