[gentoo-commits] repo/gentoo:master commit in: dev-python/python-lsp-server/, dev-python/python-lsp-server/files/

[Andrew Ammerlaan]

commit:     b5b3570793227568ad0450616e2bbbd2ec053890
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 29 19:16:24 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Wed Jun 29 19:19:21 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b5b35707

dev-python/python-lsp-server: allow mccabe 0.7

Tests pass just fine with mccabe-0.7.0.

And restrict to numpy<1.23.0:
https://github.com/python-lsp/python-lsp-server/pull/231
Because it makes the tests fail

Closes: https://bugs.gentoo.org/855095
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 .../python-lsp-server-1.4.1-allow-mccabe-0.7.patch | 22 ++++++
 .../python-lsp-server-1.4.1-r1.ebuild              | 90 ++++++++++++++++++++++
 2 files changed, 112 insertions(+)

diff --git a/dev-python/python-lsp-server/files/python-lsp-server-1.4.1-allow-mccabe-0.7.patch b/dev-python/python-lsp-server/files/python-lsp-server-1.4.1-allow-mccabe-0.7.patch
new file mode 100644
index 000000000000..a31201ab6b15
--- /dev/null
+++ b/dev-python/python-lsp-server/files/python-lsp-server-1.4.1-allow-mccabe-0.7.patch
@@ -0,0 +1,22 @@
+diff --git a/setup.cfg b/setup.cfg
+index 156145f..c46fcf3 100644
+--- a/setup.cfg
++++ b/setup.cfg
+@@ -26,7 +26,7 @@ exclude = contrib; docs; test; test.*; test.plugins; test.plugins.*
+ all = 
+ 	autopep8>=1.6.0,<1.7.0
+ 	flake8>=4.0.0,<4.1.0
+-	mccabe>=0.6.0,<0.7.0
++	mccabe>=0.6.0,<0.8.0
+ 	pycodestyle>=2.8.0,<2.9.0
+ 	pydocstyle>=2.0.0
+ 	pyflakes>=2.4.0,<2.5.0
+@@ -35,7 +35,7 @@ all =
+ 	yapf
+ autopep8 = autopep8>=1.6.0,<1.7.0
+ flake8 = flake8>=4.0.0,<4.1.0
+-mccabe = mccabe>=0.6.0,<0.7.0
++mccabe = mccabe>=0.6.0,<0.8.0
+ pycodestyle = pycodestyle>=2.8.0,<2.9.0
+ pydocstyle = pydocstyle>=2.0.0
+ pyflakes = pyflakes>=2.4.0,<2.5.0

diff --git a/dev-python/python-lsp-server/python-lsp-server-1.4.1-r1.ebuild b/dev-python/python-lsp-server/python-lsp-server-1.4.1-r1.ebuild
new file mode 100644
index 000000000000..40340f78ae9d
--- /dev/null
+++ b/dev-python/python-lsp-server/python-lsp-server-1.4.1-r1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python Language Server for the Language Server Protocol"
+HOMEPAGE="https://github.com/python-lsp/python-lsp-server"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="all-plugins"
+
+BDEPEND="
+	test? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		<dev-python/autopep8-1.7.0[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/flake8-4.0.0[${PYTHON_USEDEP}]
+		<dev-python/flake8-4.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
+		<dev-python/mccabe-0.8.0[${PYTHON_USEDEP}]
+		<dev-python/numpy-1.23.0[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.8.0[${PYTHON_USEDEP}]
+		<dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.4.0[${PYTHON_USEDEP}]
+		<dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
+		>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
+		dev-python/yapf[${PYTHON_USEDEP}]
+	)
+"
+
+RDEPEND="
+	>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	<dev-python/jedi-0.19.0[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-jsonrpc-1.0.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	all-plugins? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		<dev-python/autopep8-1.7.0[${PYTHON_USEDEP}]
+		>=dev-python/flake8-4.0.0[${PYTHON_USEDEP}]
+		<dev-python/flake8-4.1.0[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
+		<dev-python/mccabe-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.8.0[${PYTHON_USEDEP}]
+		<dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.4.0[${PYTHON_USEDEP}]
+		<dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
+		dev-python/yapf[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-allow-mccabe-0.7.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e '0,/addopts/I!d' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+pkg_postinst() {
+	optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}