[gentoo-commits] gentoo-x86 commit in app-emulation/ganeti: ChangeLog ganeti-2.5.0_rc6.ebuild

[Sebastian Pipping (sping)]

sping       12/04/05 14:55:17

  Modified:             ChangeLog
  Added:                ganeti-2.5.0_rc6.ebuild
  Log:
  app-emulation/ganeti: 2.5.0_rc6
  
  (Portage version: 2.1.10.55/cvs/Linux x86_64)

Revision  Changes    Path
1.58                 app-emulation/ganeti/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/ganeti/ChangeLog?rev=1.58&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/ganeti/ChangeLog?rev=1.58&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/ganeti/ChangeLog?r1=1.57&r2=1.58

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ChangeLog,v
retrieving revision 1.57
retrieving revision 1.58
diff -u -r1.57 -r1.58
--- ChangeLog	9 Mar 2012 04:48:43 -0000	1.57
+++ ChangeLog	5 Apr 2012 14:55:17 -0000	1.58
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/ganeti
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ChangeLog,v 1.57 2012/03/09 04:48:43 ramereth Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ChangeLog,v 1.58 2012/04/05 14:55:17 sping Exp $
+
+*ganeti-2.5.0_rc6 (05 Apr 2012)
+
+  05 Apr 2012; Sebastian Pipping <sping@g.o> +ganeti-2.5.0_rc6.ebuild:
+  Bump to 2.5.0_rc6, looks trivial
 
 *ganeti-2.5.0_rc5 (09 Mar 2012)
 



1.1                  app-emulation/ganeti/ganeti-2.5.0_rc6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/ganeti/ganeti-2.5.0_rc6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/ganeti/ganeti-2.5.0_rc6.ebuild?rev=1.1&content-type=text/plain

Index: ganeti-2.5.0_rc6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/ganeti/ganeti-2.5.0_rc6.ebuild,v 1.1 2012/04/05 14:55:17 sping Exp $

EAPI="4"

inherit eutils confutils bash-completion-r1

MY_PV="${PV/_rc/~rc}"
#MY_PV="${PV/_beta/~beta}"
MY_P="${PN}-${MY_PV}"

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://git.ganeti.org/ganeti.git"
	inherit git-2
	KEYWORDS=""
	# you will need to pull in the haskell overlay for pandoc
	GIT_DEPEND="app-text/pandoc
		dev-python/docutils
		dev-python/sphinx
		media-libs/gd[fontconfig,jpeg,png,truetype]
		media-gfx/graphviz
		media-fonts/urw-fonts"
else
	SRC_URI="http://ganeti.googlecode.com/files/${MY_P}.tar.gz"
	KEYWORDS="~amd64 ~x86"
fi

DESCRIPTION="Ganeti is a virtual server management software tool"
HOMEPAGE="http://code.google.com/p/ganeti/"

LICENSE="GPL-2"
SLOT="0"
IUSE="kvm xen lxc drbd +filestorage sharedstorage htools syslog ipv6"

S="${WORKDIR}/${MY_P}"

DEPEND="xen? ( >=app-emulation/xen-3.0 )
	kvm? ( app-emulation/qemu-kvm )
	lxc? ( app-emulation/lxc )
	drbd? ( >=sys-cluster/drbd-8.3 )
	ipv6? ( net-misc/ndisc6 )
	htools? (
		>=dev-lang/ghc-6.10
		dev-haskell/json
		dev-haskell/curl
		dev-haskell/network
		dev-haskell/parallel )
	dev-libs/openssl
	dev-python/paramiko
	dev-python/pyopenssl
	>=dev-python/pyparsing-1.4.6
	dev-python/pycurl
	dev-python/pyinotify
	dev-python/simplejson
	net-analyzer/arping
	net-misc/bridge-utils
	net-misc/curl[ssl]
	net-misc/openssh
	net-misc/socat
	sys-apps/iproute2
	sys-fs/lvm2
	>=sys-apps/baselayout-2.0
	${GIT_DEPEND}"
RDEPEND="${DEPEND}
	!app-emulation/ganeti-htools"

pkg_setup () {
	confutils_require_any kvm xen lxc
}

src_prepare() {
	if [[ ${PV} == "9999" ]] ; then
		./autogen.sh
	fi
	epatch "${FILESDIR}/${PN}-fix-start-stop.patch"
}

src_configure () {
	local myconf
	if use filestorage ; then
		myconf="--with-file-storage-dir=/var/lib/ganeti-storage/file"
	else
		myconf="--with-file-storage-dir=no"
	fi
	if use sharedstorage ; then
		myconf="--with-shared-file-storage-dir=/var/lib/ganeti-storage/shared"
	else
		myconf="--with-shared-file-storage-dir=no"
	fi
	econf --localstatedir=/var \
		--docdir=/usr/share/doc/${P} \
		--with-ssh-initscript=/etc/init.d/sshd \
		--with-export-dir=/var/lib/ganeti-storage/export \
		--with-os-search-path=/usr/share/ganeti/os \
		$(use_enable syslog) \
		$(use_enable htools) \
		$(use_enable htools htools-rapi) \
		${myconf}
}

src_install () {
	emake DESTDIR="${D}" install || die "emake install failed"
	newinitd "${FILESDIR}"/ganeti-2.1.initd ganeti
	newconfd "${FILESDIR}"/ganeti.confd ganeti
	use kvm && newinitd "${FILESDIR}"/ganeti-kvm-poweroff.initd ganeti-kvm-poweroff
	use kvm && newconfd "${FILESDIR}"/ganeti-kvm-poweroff.confd ganeti-kvm-poweroff
	newbashcomp doc/examples/bash_completion ganeti
	dodoc INSTALL UPGRADE NEWS README doc/*.rst
	rm -rf "${D}"/usr/share/doc/ganeti
	docinto examples
	#dodoc doc/examples/{basic-oob,ganeti.cron,gnt-config-backup}
	dodoc doc/examples/{ganeti.cron,gnt-config-backup}
	docinto examples/hooks
	dodoc doc/examples/hooks/{ipsec,ethers}

	keepdir /var/{lib,log,run}/ganeti/
	keepdir /usr/share/ganeti/os/
	keepdir /var/lib/ganeti-storage/{export,file,shared}/
}

pkg_postinst () {
	bash-completion_pkg_postinst
}