[gentoo-commits] repo/gentoo:master commit in: dev-python/pillow/

[Patrick Lauer]

commit:     fae497a5da7f72854f58b467219a105ccbeaba6f
Author:     Patrick Lauer <patrick <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 22 18:34:48 2017 +0000
Commit:     Patrick Lauer <patrick <AT> gentoo <DOT> org>
CommitDate: Sun Oct 22 18:35:03 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fae497a5

dev-python/pillow: Bump

Package-Manager: Portage-2.3.12, Repoman-2.3.3

 dev-python/pillow/Manifest            |  1 +
 dev-python/pillow/pillow-4.3.0.ebuild | 82 +++++++++++++++++++++++++++++++++++
 2 files changed, 83 insertions(+)

diff --git a/dev-python/pillow/Manifest b/dev-python/pillow/Manifest
index 41aa52af0fc..0e3db490a26 100644
--- a/dev-python/pillow/Manifest
+++ b/dev-python/pillow/Manifest
@@ -1,2 +1,3 @@
 DIST Pillow-3.4.2.zip 11042238 SHA256 85b237840ad8b30a1572bf9e3898a26c77910a56554d73ed4f58a42197c2e4c2 SHA512 5e05206db5bc1b4177384f7e91ee79015c6e1bbdc7c31c997da054391b9b5ec7c1ebdec258a33f598986533894f3324b03d0b4b385b94e72a0517a3437553b39 WHIRLPOOL f92d4320ca5fd3e004a2ace41d14f0816dbea6fcfc9b10739a59d2dd393725a47c28f5b9f643d0b3243b9003701094ee953b38118412647155e8ba13fafe0582
 DIST Pillow-4.2.1.tar.gz 12673417 SHA256 c724f65870e545316f9e82e4c6d608ab5aa9dd82d5185e5b2e72119378740073 SHA512 8a1c691f067c1127b941a94ae991c728c94eab876fe2a511ed0ad8af9702d4969325bd565b11e656ffefe867bf385725a5c14e3c28f8945730fa21986f934f69 WHIRLPOOL af93b67a60843d9f853921d5dd1332209cefc87a9680201cca5010f935527abcacac57e9d2afeac6bd3ccf8ab6636ffc2321e0888b73babfdb9ff0a933a77951
+DIST Pillow-4.3.0.tar.gz 13874155 SHA256 a97c715d44efd5b4aa8d739b8fad88b93ed79f1b33fc2822d5802043f3b1b527 SHA512 5811252802bd01ac86157235d42138685e746723df48b67ec7c7ebd3f172532b40cf86ca9d3d792e82f03986303a084bf3491c0d511dc068dea1bc631afdeabb WHIRLPOOL 60b418d8e549f72a295c632a5caee148179d8bb931f63959fb4ee383db43e68bcab92789791fa912b74386410ac6023cc8232f3cdb0b7e7eb5a92467b8611034

diff --git a/dev-python/pillow/pillow-4.3.0.ebuild b/dev-python/pillow/pillow-4.3.0.ebuild
new file mode 100644
index 00000000000..785dfedc3b9
--- /dev/null
+++ b/dev-python/pillow/pillow-4.3.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_REQ_USE='tk?,threads(+)'
+
+inherit distutils-r1 eutils virtualx
+
+MY_PN=Pillow
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python Imaging Library (fork)"
+HOMEPAGE="https://python-pillow.org/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples imagequant jpeg2k lcms test tiff tk truetype webp zlib"
+
+REQUIRED_USE="test? ( tiff )"
+
+RDEPEND="
+	dev-python/olefile[${PYTHON_USEDEP}]
+	imagequant? ( media-gfx/libimagequant:0 )
+	virtual/jpeg:0
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lcms? ( media-libs/lcms:2= )
+	tiff? ( media-libs/tiff:0=[jpeg] )
+	truetype? ( media-libs/freetype:2= )
+	webp? ( media-libs/libwebp:0= )
+	zlib? ( sys-libs/zlib:0= )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (	dev-python/nose[${PYTHON_USEDEP}] )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+src_compile() {
+	# raqm not in portage yet
+	distutils-r1_src_compile \
+		--disable-raqm \
+		$(use_enable truetype freetype) \
+		$(use_enable jpeg2k jpeg2000) \
+		$(use_enable lcms) \
+		$(use_enable tiff) \
+		$(use_enable imagequant) \
+		$(use_enable webp) \
+		$(use_enable webp webpmux) \
+		$(use_enable zlib)
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	"${PYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
+	virtx nosetests -vx Tests/test_*.py
+}
+
+python_install() {
+	python_doheader libImaging/*.h
+	distutils-r1_python_install
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	if use examples ; then
+		docinto examples
+		dodoc Scripts/*
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}