[gentoo-commits] gentoo-x86 commit in media-video/jubler: ChangeLog jubler-3.4.1.ebuild

[Petteri Raty (betelgeuse)]

betelgeuse    07/11/24 23:43:13

  Modified:             ChangeLog
  Added:                jubler-3.4.1.ebuild
  Log:
  Version bump. Freedesktop patch committed upstream. Fixes bug #200235.
  (Portage version: 2.1.4_rc2)

Revision  Changes    Path
1.6                  media-video/jubler/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/jubler/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	21 Nov 2007 21:11:22 -0000	1.5
+++ ChangeLog	24 Nov 2007 23:43:12 -0000	1.6
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/jubler
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/jubler/ChangeLog,v 1.5 2007/11/21 21:11:22 betelgeuse Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/jubler/ChangeLog,v 1.6 2007/11/24 23:43:12 betelgeuse Exp $
+
+*jubler-3.4.1 (24 Nov 2007)
+
+  24 Nov 2007; Petteri Räty <betelgeuse@g.o>
+  +files/jubler-3.4.1.patch, +jubler-3.4.1.ebuild:
+  Version bump. Freedesktop patch committed upstream. Fixes bug #200235.
 
 *jubler-3.4.0 (21 Nov 2007)
 



1.1                  media-video/jubler/jubler-3.4.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/jubler-3.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/jubler-3.4.1.ebuild?rev=1.1&content-type=text/plain

Index: jubler-3.4.1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/jubler/jubler-3.4.1.ebuild,v 1.1 2007/11/24 23:43:12 betelgeuse Exp $

inherit gnome2 eutils java-pkg-2 java-utils-2 java-ant-2 toolchain-funcs

MY_PN=${PN/#j/J}
DESCRIPTION="Java subtitle editor"
HOMEPAGE="http://www.jubler.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-src-${PV}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="mplayer nls spell"

RDEPEND=">=virtual/jre-1.5
	media-video/ffmpeg
	mplayer? ( media-video/mplayer )
	spell?
	(
		app-text/aspell
		>=dev-java/zemberek-2.0
	)"

DEPEND=">=virtual/jdk-1.5
	media-video/ffmpeg
	app-text/docbook-sgml-utils
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${MY_PN}-${PV}

pkg_setup() {
	if use spell && ! built_with_use dev-java/zemberek linguas_tr; then
		die "Zemberek should be built with Turkish language support"
	fi
	java-pkg-2_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${PN}-3.4.1.patch"
	chmod +x resources/installers/linux/iconinstall
}

src_compile() {
	eant $(use nls && echo i18n) jar faq || die "eant failed"
	cp -v dist/help/jubler-faq.html build/classes/help || die "cp failed"
	cd resources/ffdecode || die
	CC=$(tc-getCC) emake linuxdyn || die "make failed"
}

src_install() {
	java-pkg_dojar dist/Jubler.jar
	use spell && java-pkg_register-dependency zemberek zemberek2-cekirdek.jar
	use spell && java-pkg_register-dependency zemberek zemberek2-tr.jar
	java-pkg_doso resources/ffdecode/libffdecode.so
	doicon resources/installers/linux/jubler.png
	domenu resources/installers/linux/jubler.desktop

	DESTDIR="${D}" eant linuxdesktopintegration
	rm -vr "${D}/usr/share/menu" || die

	java-pkg_dolauncher jubler --main com.panayotis.jubler.Main
	doman resources/installers/linux/jubler.1
	insinto /usr/share/jubler/help
	doins dist/help/*
}



-- 
gentoo-commits@g.o mailing list