[gentoo-commits] repo/gentoo:master commit in: x11-misc/j4-dmenu-desktop/

[Conrad Kostecki]

commit:     67b32ca6f2613344577ed24197fe9849b1afdd83
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  3 14:19:40 2020 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sat Oct  3 14:41:51 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=67b32ca6

x11-misc/j4-dmenu-desktop: bump to version 2.18

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 x11-misc/j4-dmenu-desktop/Manifest                 |  1 +
 .../j4-dmenu-desktop/j4-dmenu-desktop-2.18.ebuild  | 56 ++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/x11-misc/j4-dmenu-desktop/Manifest b/x11-misc/j4-dmenu-desktop/Manifest
index cae85a9f547..e6b92c2ca98 100644
--- a/x11-misc/j4-dmenu-desktop/Manifest
+++ b/x11-misc/j4-dmenu-desktop/Manifest
@@ -1 +1,2 @@
 DIST j4-dmenu-desktop-2.17.tar.gz 33531 BLAKE2B c1dd82a444efdbbf2af644ee6cdba6746a81228c5f6b2d212d5ea248628855f1cd1c4dff091ae278eb8c6458db4934b60acd8e2dd9a9c88b32537e76878824b3 SHA512 7a41bb60a6b3afa7bf6229f08674d5f31e0152d0788a17edc210986d1b1f0d4fad13ffaa13c58ed7a0c5d2e67f8f95bb2a0f6556aeb0f2cc24c7d885b346325e
+DIST j4-dmenu-desktop-2.18.tar.gz 34785 BLAKE2B 26d5861d6d7ddcd9653a464d1175d19532001705de193811087fd42fddbdead89b8d49bd14f8e323288d6a7ba37bd4e11f4c7c52dd9b0a454f95a83a14853bcb SHA512 f8b0c825d567d60da0fb418e6f0b24a6d9daa9fb142b194b0a8b249303f4e09b6694fce72bf031007ac67253e488fc7666d4ba7beb032bc74cc2a32aca0f6c96

diff --git a/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-2.18.ebuild b/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-2.18.ebuild
new file mode 100644
index 00000000000..407d1d55918
--- /dev/null
+++ b/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-2.18.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+MY_PV="r${PV}"
+
+DESCRIPTION="A fast desktop replacement for i3-dmenu-desktop"
+HOMEPAGE="https://github.com/enkore/j4-dmenu-desktop"
+SRC_URI="https://github.com/enkore/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+dmenu test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-cpp/catch:1 )"
+RDEPEND="dmenu? ( x11-misc/dmenu )"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Respect users CFLAGS
+	sed -i -e "s/-pedantic -O2//" CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_GIT_CATCH="no"
+		-DWITH_TESTS="$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	doman j4-dmenu-desktop.1
+}
+
+pkg_postinst() {
+	if ! use dmenu; then
+		elog "As you have disabled the 'dmenu' use flag,"
+		elog "x11-misc/dmenu won't be installed by default."
+		elog ""
+		elog "Since x11-misc/j4-dmenu-desktop uses x11-misc/dmenu as default,"
+		elog "you must configure your own replacement with --dmenu=<command>,"
+		elog "as otherwise it won't work."
+	fi
+}