[gentoo-commits] repo/gentoo:master commit in: media-libs/aubio/

[Lars Wendler]

commit:     f0364c704d614ba51a5b7028ecbd0dd5f9bba819
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 12 07:54:01 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed Apr 12 07:54:25 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f0364c70

media-libs/aubio: Bump to version 0.4.5

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 media-libs/aubio/Manifest           |   1 +
 media-libs/aubio/aubio-0.4.5.ebuild | 110 ++++++++++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/media-libs/aubio/Manifest b/media-libs/aubio/Manifest
index 22f5cdc40ba..9e08e592522 100644
--- a/media-libs/aubio/Manifest
+++ b/media-libs/aubio/Manifest
@@ -2,3 +2,4 @@ DIST aubio-0.4.1.tar.bz2 288136 SHA256 25d7df0a9cd6366fda764a803424caddf5fb819fc
 DIST aubio-0.4.2.tar.bz2 304216 SHA256 1cc58e0fed2b9468305b198ad06b889f228b797a082c2ede716dc30fcb4f8f1f SHA512 b57b6d147b305a264f0055726f76a8452f784b556a7fda911f056adbedd2855048e93c0e21b9f359e3f442f1542189aff0c214dd85141e2e06048a07f47703ff WHIRLPOOL 1fa0c877261c82d095144c05f753dd5ea303838d48627edf18af4275f8b4aba0dbe5806bb2504bc2c5a2c169d5bd8edd76bcb3cd990abd7b42842d0223918270
 DIST aubio-0.4.3.tar.bz2 328852 SHA256 b62cdb073c0c64ae301917fa162969d42cba45e478bdf1e74490bd87e9cceaab SHA512 bc286f1af9bc23e8bb5e4fa49a1d392e4f8169b8ca59409ee79bbbebf887f60ac7f68a6ed465272dbfc46f8c1ebf902513428e67cab5b88c4500ffe93f1c21d5 WHIRLPOOL 260e63d3f32a18fef104dfdf175ac7a864b701048fbaa0fc3005dde6058df45ab66329401a3a47e80df407340b8ab6bb13ceda49510d1860c8302720ec55e3e2
 DIST aubio-0.4.4.tar.bz2 334754 SHA256 2acdb92623b9d4ba641c387760ffe3ec1e4c6ab498e64e5e2286c99e36ffbff8 SHA512 ddf9019117b5da752eaf74bee0e5ba51d758f41b4e5a2ea64773fc3332c930c7215235b2ceb58bcb73e04811a3367efe19a606aee76d328a4d9670db82608d83 WHIRLPOOL b91b9de9dd5ac244c0f05fa8ba6e8e3e57ffd563d026f5b3834c9eff0eca9a6bbec3eb795fd2738a3a3f53a47a210648aa3893cd8684be187755c2c036a175d6
+DIST aubio-0.4.5.tar.bz2 350615 SHA256 70c2804e6f4fbf0ebc0fb9ac8cc9d465ef4a4d438311c074c9a7364e98827af6 SHA512 0aeaee5efc117201ca7b1fe2a421826ade83ce5b3ba50c27a8cf65debeedb20dd5a5ac28e20935bb29ca2b0d1b70cf93feee298989dfc79978f689e989235608 WHIRLPOOL b70d452570d1fc8b7168eac5bca3ce150aa33f24576815efa685cffef60511fa3e259c233c8f3d99ae5f88a6d8e94d4686a040912948c3783323eceec202a843

diff --git a/media-libs/aubio/aubio-0.4.5.ebuild b/media-libs/aubio/aubio-0.4.5.ebuild
new file mode 100644
index 00000000000..15673419b95
--- /dev/null
+++ b/media-libs/aubio/aubio-0.4.5.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE='threads(+)'
+
+inherit distutils-r1 waf-utils multilib eutils
+
+DESCRIPTION="Library for audio labelling"
+HOMEPAGE="http://aubio.org/"
+SRC_URI="http://aubio.org//pub/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0/5"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc double-precision examples ffmpeg fftw jack libav libsamplerate sndfile python"
+
+RDEPEND="
+	ffmpeg? (
+		!libav? ( >=media-video/ffmpeg-2.6:0= )
+		libav? ( >=media-video/libav-9:0= )
+	)
+	fftw? ( sci-libs/fftw:3.0 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	libsamplerate? ( media-libs/libsamplerate )
+	python? ( dev-python/numpy[${PYTHON_USEDEP}] ${PYTHON_DEPS} )
+	sndfile? ( media-libs/libsndfile )
+"
+DEPEND="
+	${RDEPEND}
+	${PYTHON_DEPS}
+	app-text/txt2man
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( AUTHORS ChangeLog README.md )
+PYTHON_SRC_DIR="${S}"
+
+src_prepare() {
+	default
+	sed -i -e "s:doxygen:doxygen_disabled:" wscript || die
+}
+
+src_configure() {
+	python_setup
+	waf-utils_src_configure \
+		--enable-complex \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		$(use_enable double-precision double) \
+		$(use_enable fftw fftw3f) \
+		$(use_enable fftw fftw3) \
+		$(use_enable ffmpeg avcodec) \
+		$(use_enable jack) \
+		$(use_enable libsamplerate samplerate) \
+		$(use_enable sndfile)
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_configure
+	fi
+}
+
+src_compile() {
+	waf-utils_src_compile --notests
+
+	if use doc; then
+		cd "${S}"/doc || die
+		doxygen full.cfg || die
+	fi
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_compile
+	fi
+}
+
+src_test() {
+	waf-utils_src_compile --alltests
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		distutils-r1_src_test
+	fi
+}
+
+src_install() {
+	waf-utils_src_install
+
+	if use examples; then
+		# install dist_noinst_SCRIPTS from Makefile.am
+		dodoc -r examples
+	fi
+
+	if use python ; then
+		cd "${PYTHON_SRC_DIR}" || die
+		DOCS="" distutils-r1_src_install
+		newdoc python/README.md README.python
+	fi
+
+	if use doc; then
+		dodoc doc/*.txt
+		docinto html
+		dodoc -r doc/full/html/.
+	fi
+}