[gentoo-commits] gentoo-x86 commit in sys-apps/pkgcore: ChangeLog pkgcore-0.3.2-r1.ebuild

[Markus Ullmann (jokey)]

jokey       07/12/06 20:57:23

  Modified:             ChangeLog
  Added:                pkgcore-0.3.2-r1.ebuild
  Log:
  Add fix for ebuilds that error out on unknown src_configure error
  (Portage version: 2.1.4_rc7)

Revision  Changes    Path
1.45                 sys-apps/pkgcore/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pkgcore/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pkgcore/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pkgcore/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	6 Nov 2007 17:51:13 -0000	1.44
+++ ChangeLog	6 Dec 2007 20:57:22 -0000	1.45
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/pkgcore
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/ChangeLog,v 1.44 2007/11/06 17:51:13 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/ChangeLog,v 1.45 2007/12/06 20:57:22 jokey Exp $
+
+*pkgcore-0.3.2-r1 (06 Dec 2007)
+
+  06 Dec 2007; Markus Ullmann <jokey@g.o>
+  +files/pkgcore-0.3.2-eapi.patch, +pkgcore-0.3.2-r1.ebuild:
+  Add fix for ebuilds that error out on unknown src_configure error
 
   06 Nov 2007; Raúl Porcel <armin76@g.o> pkgcore-0.3.2.ebuild:
   Add ~alpha



1.1                  sys-apps/pkgcore/pkgcore-0.3.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pkgcore/pkgcore-0.3.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pkgcore/pkgcore-0.3.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: pkgcore-0.3.2-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/pkgcore-0.3.2-r1.ebuild,v 1.1 2007/12/06 20:57:22 jokey Exp $

inherit distutils eutils

DESCRIPTION="pkgcore package manager"
HOMEPAGE="http://www.pkgcore.org"
SRC_URI="http://www.pkgcore.org/releases/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc"

RDEPEND=">=dev-lang/python-2.4
	>=dev-python/snakeoil-0.1
	>=app-shells/bash-3.0
	|| ( >=dev-lang/python-2.5 dev-python/pycrypto )"
DEPEND="${RDEPEND}
	doc? ( >=dev-python/docutils-0.4 )"

DOCS="AUTHORS NEWS"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-eapi.patch
}

src_compile() {
	distutils_src_compile

	if use doc; then
		./build_docs.py || die "doc building failed"
	fi
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml -r doc dev-notes
		doman man/*.1
	fi

	dodoc doc/*.rst man/*.rst
	docinto dev-notes
	dodoc dev-notes/*.rst
}

pkg_postinst() {
	distutils_pkg_postinst
	pplugincache

	if [[ -d "${ROOT}etc/pkgcore/plugins" ]]; then
		elog "You still have an /etc/pkgcore/plugins from pkgcore 0.1."
		elog "It is unused by pkgcore >= 0.2, so you can remove it now."
	fi

	# This is left behind by pkgcore 0.2.
	rm -f "${ROOT}"usr/$(get_libdir)/python${PYVER}/site-packages/pkgcore/plugins/plugincache

	elog "If the new layman sync support causes problems you can disable it"
	elog "with FEATURES=-layman-sync. If you cannot sync a layman overlay"
	elog "using pkgcore, file a bug in pkgcore.org trac instead of complaining"
	elog "to the layman or overlay maintainer."
}

pkg_postrm() {
	python_version
	# Careful not to remove this on up/downgrades.
	local sitep="${ROOT}"usr/$(get_libdir)/python${PYVER}/site-packages
	if [[ -e "${sitep}/pkgcore/plugins/plugincache2" ]] &&
		! [[ -e "${sitep}/pkgcore/plugin.py" ]]; then
		rm "${sitep}/pkgcore/plugins/plugincache2"
	fi
	distutils_pkg_postrm
}

src_test() {
	"${python}" setup.py test || die "testing returned non zero"
}



-- 
gentoo-commits@g.o mailing list