[gentoo-commits] repo/gentoo:master commit in: dev-python/nbconvert/

[Arthur Zamarin]

commit:     3d51184eab3336f3f47c541ebdc75673ea22a9f8
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Tue Jan  4 20:43:34 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Tue Jan  4 20:43:34 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d51184e

dev-python/nbconvert: add 6.4.0

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/nbconvert/Manifest               |  1 +
 dev-python/nbconvert/nbconvert-6.4.0.ebuild | 73 +++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index 089ca9e3bdc8..d0665ac6c8c4 100644
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -1 +1,2 @@
 DIST nbconvert-6.3.0.tar.gz 900850 BLAKE2B 8ef7d3bfcb914bf4be064ef440faab283fcc71e53579a681deb343d307a8b39cca2d0b83828b9df7c45ee7e9e06164ba6daa234b678197bc8a3202cd7e560c06 SHA512 efbe18c50e408fcb7d920c5ee070d19e19f0347f7073cf86b45046f3e30bd30ab8174115c539020fbf404faf5fc6e55dc7df1ad27accb45f1b2acf2db1d325e6
+DIST nbconvert-6.4.0.tar.gz 901586 BLAKE2B 85087046fe9a211c077165f47c03e7b025c770e2d409278703ddeef3c84b3d60e1ad28650f67fb9d68b72ad077db5bbd99af5c81ddf94fd7bf67471701dbdc4a SHA512 12662cca240a4c57a41e3bc7fedebd51c6fb83a0740afa7acfcc25424ca544a44b4dbfecfb9edb396360866de0b8fafad124fbb87c46c6f796661a7f40e96f68

diff --git a/dev-python/nbconvert/nbconvert-6.4.0.ebuild b/dev-python/nbconvert/nbconvert-6.4.0.ebuild
new file mode 100644
index 000000000000..3b031affd2a1
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-6.4.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="https://nbconvert.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyterlab_pygments[${PYTHON_USEDEP}]
+	>=dev-python/mistune-0.7.4[${PYTHON_USEDEP}]
+	dev-python/nbclient[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1.1[${PYTHON_USEDEP}]
+	dev-python/testpath[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+"
+# Skip inkscape on hppa b/c tests should skip it gracefully if not around
+# It's a heavy dependency.
+BDEPEND="
+	test? (
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		>=dev-python/jupyter_client-4.2[${PYTHON_USEDEP}]
+		!hppa? ( media-gfx/inkscape )
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	mkdir -p "${HOME}/.local" || die
+	cp -r share "${HOME}/.local/" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Missing pyppeteer for now
+		# TODO: Doesn't skip?
+		nbconvert/exporters/tests/test_webpdf.py
+		# Needs pyppeteer too
+		'nbconvert/tests/test_nbconvertapp.py::TestNbConvertApp::test_webpdf_with_chromium'
+	)
+
+	distutils_install_for_testing bdist_egg
+	cd "${TEST_DIR}"/lib || die
+	epytest --pyargs nbconvert
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}