[gentoo-commits] gentoo-x86 commit in dev-embedded/sdcc: ChangeLog sdcc-2.8.0.ebuild

[Denis Dupeyron (calchan)]

calchan     08/04/20 17:58:59

  Modified:             ChangeLog
  Added:                sdcc-2.8.0.ebuild
  Log:
  Version bump, thanks to Karl Hiramoto (bug #218007).
  (Portage version: 2.1.5_rc5)

Revision  Changes    Path
1.39                 dev-embedded/sdcc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-embedded/sdcc/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-embedded/sdcc/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-embedded/sdcc/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-embedded/sdcc/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	1 Sep 2007 22:32:33 -0000	1.38
+++ ChangeLog	20 Apr 2008 17:58:58 -0000	1.39
@@ -1,6 +1,12 @@
 # ChangeLog for dev-embedded/sdcc
-# Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-embedded/sdcc/ChangeLog,v 1.38 2007/09/01 22:32:33 calchan Exp $
+# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-embedded/sdcc/ChangeLog,v 1.39 2008/04/20 17:58:58 calchan Exp $
+
+*sdcc-2.8.0 (20 Apr 2008)
+
+  20 Apr 2008; Denis Dupeyron <calchan@g.o>
+  +files/sdcc-2.8.0-flags.patch, +sdcc-2.8.0.ebuild:
+  Version bump, thanks to Karl Hiramoto (bug #218007).
 
 *sdcc-2.7.0 (01 Sep 2007)
 



1.1                  dev-embedded/sdcc/sdcc-2.8.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-embedded/sdcc/sdcc-2.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-embedded/sdcc/sdcc-2.8.0.ebuild?rev=1.1&content-type=text/plain

Index: sdcc-2.8.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-embedded/sdcc/sdcc-2.8.0.ebuild,v 1.1 2008/04/20 17:58:58 calchan Exp $

inherit eutils autotools

DESCRIPTION="Small device C compiler (for various microprocessors)."
HOMEPAGE="http://sdcc.sourceforge.net/"
SRC_URI="mirror://sourceforge/sdcc/${PN}-src-${PV}.tar.bz2
	doc? ( mirror://sourceforge/sdcc/${PN}-doc-${PV}.tar.bz2 )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="boehmgc doc"

DEPEND=">=dev-embedded/gputils-0.13.2
	boehmgc? ( dev-libs/boehm-gc )"
RDEPEND="!dev-embedded/sdcc-svn"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Fix conflicting variable names between Gentoo and sdcc
	find ./ -type f -exec sed -i s:PORTDIR:PORTINGDIR:g  {} \; || die "sed failed"
	find device/lib/pic*/ -type f -exec sed -i s:ARCH:SDCCARCH:g  {} \; || die "sed failed"
	find device/lib/pic/libdev/ -type f -exec sed -i s:CFLAGS:SDCCFLAGS:g  {} \; || die "sed failed"

	# Fix automagic C{,XX}FLAGS
	epatch "${FILESDIR}"/${P}-flags.patch

	# We'll install doc manually
	sed -i -e '/SDCC_DOC/d' Makefile.in || die "sed failed"
	sed -i -e 's/all install-doc/all/' as/Makefile.in || die "sed failed"
	sed -i -e 's/ doc//' sim/ucsim/packages_in.mk || die "sed failed"

	eautoreconf
}

src_compile() {
	econf \
		$(use_enable boehmgc libgc) \
		--disable-doc \
		|| die "configure failed"
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "Install failed"

	insinto /usr/share/doc/${PF}
	if use doc ; then
		cd "${WORKDIR}"/doc
		dohtml -r *.html ucsim
		rm -rf *.html ucsim
		dohtml as/asxhtm.html
		rm -f as/asxhtm.html
		rm -f INSTALL.txt
	else
		dohtml as/doc/asxhtm.html
		rm -f as/doc/asxhtm.html
		mv as/doc as/as || die "Failed to rename as/doc"
		doins -r as/as
		mv sim/ucsim/doc sim/ucsim/ucsim || die "Failed to rename sim/ucsim/doc"
		dohtml -r sim/ucsim/ucsim
		rm -f INSTALL.txt Makefile* *.mk
		cd doc
	fi
	doins -r *
	prepalldocs
}



-- 
gentoo-commits@l.g.o mailing list