[gentoo-commits] repo/gentoo:master commit in: dev-python/python-dateutil/

[Michał Górny]

commit:     f56740823a78cc239c75843bd5547d15f6f16d2d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May 11 13:54:49 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May 11 13:54:49 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f5674082

dev-python/python-dateutil: Use PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../python-dateutil-2.8.2-r1.ebuild                | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/dev-python/python-dateutil/python-dateutil-2.8.2-r1.ebuild b/dev-python/python-dateutil/python-dateutil-2.8.2-r1.ebuild
new file mode 100644
index 000000000000..63391c2a9f7d
--- /dev/null
+++ b/dev-python/python-dateutil/python-dateutil-2.8.2-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Extensions to the standard Python datetime module"
+HOMEPAGE="
+	https://dateutil.readthedocs.io/
+	https://pypi.org/project/python-dateutil/
+	https://github.com/dateutil/dateutil/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/six-1.5[${PYTHON_USEDEP}]
+	sys-libs/timezone-data
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/python-dateutil-2.8.2-system-tzdata.patch"
+	"${FILESDIR}/python-dateutil-2.8.1-no-pytest-cov.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't install zoneinfo tarball
+	sed -i '/package_data=/d' setup.py || die
+
+	distutils-r1_python_prepare_all
+}