[gentoo-commits] repo/gentoo:master commit in: dev-python/sympy/

[罗百科]

commit:     ea56104140966212404bc7b426852fffe5b4a029
Author:     Patrick Lauer <patrick <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 28 11:56:49 2019 +0000
Commit:     罗百科 <patrick <AT> gentoo <DOT> org>
CommitDate: Sat Dec 28 11:56:59 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ea561041

dev-python/sympy: Bump

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Patrick Lauer <patrick <AT> gentoo.org>

 dev-python/sympy/Manifest         |  1 +
 dev-python/sympy/sympy-1.5.ebuild | 90 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 91 insertions(+)

diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
index 2b7673282b3..5fab8c9b261 100644
--- a/dev-python/sympy/Manifest
+++ b/dev-python/sympy/Manifest
@@ -1,2 +1,3 @@
 DIST sympy-1.0.tar.gz 4281528 BLAKE2B b222be6ec486a01ac73e9778a7423aab45e368386003de965308cfa4e08fef07b64046f62ef707b6fa124ee6367fb051b9722e138bfe2eae4661f9e2a66c2365 SHA512 977db6e9bc6a5918cceb255981a57e85e7060c0922aefd2968b004d25d704e25a5cb5bbe09eb387e8695581e23e2825d9c40310068fe25ece7e9c23037a21f39
 DIST sympy-1.3.tar.gz 5885611 BLAKE2B 14b0639960432cd6aac087a57f81a80497a0bc40ed61eae92166cf5549deaefc611ce63c2e7a89922374e9bb902fb0a7402f5a4e425278f34c028cdc3582eb35 SHA512 3b47dcf80e9a0ca7d65860907264bbcd6f6022275c717784cd165a7a824dca3471bc5a3be9d1af6ab31e04b29f7d5305713fc47ccb67f798f45281e0ab7e03bf
+DIST sympy-1.5.tar.gz 6294079 BLAKE2B ee6764264d87454c9713a6e99b70b123e1cc2d36a691287a53e8b69a548df5503168989afa2ca85a08cd5f6792c952e5556352fde07332b1fe47b3746d02b47a SHA512 882ed99cbc7333cbed85d247d04a764a92855e3d26cee96163d18ece566115b9d38999bbe022225521834037dbdfc4c567548112dfddd5ece65af8f672a06091

diff --git a/dev-python/sympy/sympy-1.5.ebuild b/dev-python/sympy/sympy-1.5.ebuild
new file mode 100644
index 00000000000..718e9d516db
--- /dev/null
+++ b/dev-python/sympy/sympy-1.5.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit distutils-r1 eutils virtualx
+
+DESCRIPTION="Computer Algebra System in pure Python"
+HOMEPAGE="https://sympy.org"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${P}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples gtk imaging ipython latex mathml opengl pdf png pyglet symengine test texmacs theano"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	doc? ( || ( $(python_gen_useflags 'python2*') ) )
+	ipython? ( || ( $(python_gen_useflags -3) ) )"
+
+RESTRICT="test"
+# All tests actually pass, except a bunch of tests related to the deprecated pygletplot
+# It is a non-trivial work to wipe out all such tests :-(
+
+RDEPEND="dev-python/mpmath[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	ipython? ( $(python_gen_cond_dep 'dev-python/ipython[${PYTHON_USEDEP}]' -3) )
+	latex? (
+		virtual/latex-base
+		dev-texlive/texlive-fontsextra
+		png? ( app-text/dvipng )
+		pdf? ( app-text/ghostscript-gpl )
+	)
+	mathml? (
+		dev-libs/libxml2:2[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-libs/libxslt[${PYTHON_USEDEP}]' python2_7)
+		gtk? ( x11-libs/gtkmathview[gtk] )
+	)
+	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
+	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
+	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
+	texmacs? ( app-office/texmacs )
+	theano? ( dev-python/theano[${PYTHON_USEDEP}] )
+"
+
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] app-text/docbook2X )
+	test? ( ${RDEPEND} dev-python/pytest[${PYTHON_USEDEP}] )"
+
+pkg_setup() {
+	use doc && DISTUTILS_ALL_SUBPHASE_IMPLS=( 'python2*' )
+}
+
+python_compile_all() {
+	if use doc; then
+		export XDG_CONFIG_HOME="${T}/config-dir"
+		mkdir "${XDG_CONFIG_HOME}" || die
+		chmod 0700 "${XDG_CONFIG_HOME}" || die
+		emake -j1 -C doc html info man cheatsheet
+	fi
+}
+
+python_test() {
+	virtx "${PYTHON}" setup.py test
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.rst )
+	if use doc; then
+		DOCS+=( doc/_build/cheatsheet/cheatsheet.pdf \
+				doc/_build/cheatsheet/combinatoric_cheatsheet.pdf )
+		local HTML_DOCS=( doc/_build/html/. )
+		doinfo doc/_build/texinfo/${PN}.info
+	fi
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+
+	if use texmacs; then
+		exeinto /usr/libexec/TeXmacs/bin/
+		doexe data/TeXmacs/bin/tm_sympy
+		insinto /usr/share/TeXmacs/plugins/sympy/
+		doins -r data/TeXmacs/progs
+	fi
+}