[gentoo-commits] gentoo-x86 commit in media-sound/clementine: ChangeLog clementine-0.5.3.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/09/30 10:19:07

  Modified:             ChangeLog
  Added:                clementine-0.5.3.ebuild
  Log:
  Version bump. Thanks to Caster and Nikoli for information and ebuild.
  
  (Portage version: 2.2_rc87/cvs/Linux x86_64)

Revision  Changes    Path
1.16                 media-sound/clementine/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/clementine/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/clementine/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/clementine/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/clementine/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	21 Sep 2010 19:08:41 -0000	1.15
+++ ChangeLog	30 Sep 2010 10:19:07 -0000	1.16
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/clementine
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/clementine/ChangeLog,v 1.15 2010/09/21 19:08:41 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/clementine/ChangeLog,v 1.16 2010/09/30 10:19:07 ssuominen Exp $
+
+*clementine-0.5.3 (30 Sep 2010)
+
+  30 Sep 2010; Samuli Suominen <ssuominen@g.o>
+  +clementine-0.5.3.ebuild:
+  Version bump. Thanks to Caster and Nikoli for information and ebuild.
 
   21 Sep 2010; Markos Chandras <hwoarang@g.o>
   clementine-0.4.2.ebuild:



1.1                  media-sound/clementine/clementine-0.5.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/clementine/clementine-0.5.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/clementine/clementine-0.5.3.ebuild?rev=1.1&content-type=text/plain

Index: clementine-0.5.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/clementine/clementine-0.5.3.ebuild,v 1.1 2010/09/30 10:19:07 ssuominen Exp $

EAPI=2

LANGS=" ar bg ca cs da de el en_CA en_GB es fi fr gl hu it kk lt nb nl oc pl pt_BR pt ro ru sk sl sr sv tr uk zh_CN zh_TW"

inherit cmake-utils gnome2-utils

DESCRIPTION="A modern music player and library organizer based on Amarok 1.4 and Qt4"
HOMEPAGE="http://code.google.com/p/clementine-player/"
SRC_URI="http://clementine-player.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="iphone ipod mtp projectm wiimote"
IUSE+="${LANGS// / linguas_}"

COMMON_DEPEND="
	x11-libs/qt-gui:4[dbus]
	x11-libs/qt-opengl:4
	x11-libs/qt-sql:4[sqlite]
	>=media-libs/taglib-1.6
	media-libs/liblastfm
	>=dev-libs/glib-2.10:2
	dev-libs/libxml2
	>=media-libs/gstreamer-0.10
	>=media-libs/gst-plugins-base-0.10
	ipod? (
		>=media-libs/libgpod-0.7.92
		iphone? (
			app-pda/libplist
			>=app-pda/libimobiledevice-1.0
			app-pda/usbmuxd
		)
	)
	mtp? ( media-libs/libmtp )
	projectm? ( media-libs/glew )
"
# now only presets are used, libprojectm is internal
# http://code.google.com/p/clementine-player/source/browse/#svn/trunk/3rdparty/libprojectm/patches
# r1966 "Compile with a static sqlite by default, since Qt 4.7 doesn't seem to expose the symbols we need to use FTS"
RDEPEND="${COMMON_DEPEND}
	projectm? ( >=media-libs/libprojectm-1.2.0 )
	>=media-plugins/gst-plugins-meta-0.10
	>=media-plugins/gst-plugins-gio-0.10
	>=media-plugins/gst-plugins-soup-0.10
"
DEPEND="${COMMON_DEPEND}
	>=dev-libs/boost-1.39
	dev-util/pkgconfig
	sys-devel/gettext
	x11-libs/qt-test:4
"
DOCS="Changelog TODO"

PATCHES=( "${FILESDIR}"/${PN}-0.5.1-automagic.patch )

src_configure() {
	# linguas
	local langs x
	for x in ${LANGS}; do
		use linguas_${x} && langs+=" ${x}"
	done

	# Upstream supports only gstreamer engine, other engines are unstable and lacking features.
	local mycmakeargs=(
		-DLINGUAS="${langs}"
		"-DBUNDLE_PROJECTM_PRESETS=OFF"
		$(cmake-utils_use ipod ENABLE_LIBGPOD)
		$(cmake-utils_use iphone ENABLE_IMOBILEDEVICE)
		$(cmake-utils_use mtp ENABLE_LIBMTP)
		"-DENABLE_GIO=ON"
		$(cmake-utils_use wiimote ENABLE_WIIMOTEDEV)
		$(cmake-utils_use projectm ENABLE_VISUALISATIONS)
		"-DSTATIC_SQLITE=OFF"
		"-DENGINE_GSTREAMER_ENABLED=ON"
		"-DENGINE_QT_PHONON_ENABLED=OFF"
		"-DENGINE_LIBVLC_ENABLED=OFF"
		"-DENGINE_LIBXINE_ENABLED=OFF"
		)

	cmake-utils_src_configure
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}