[gentoo-commits] gentoo-x86 commit in sys-fs/btrfs-progs: btrfs-progs-3.16.1.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     14/09/23 18:01:42

  Modified:             ChangeLog
  Added:                btrfs-progs-3.16.1.ebuild
  Log:
  Version bump, bug 523544 by emil karlson.
  
  (Portage version: 2.2.13/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.86                 sys-fs/btrfs-progs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/btrfs-progs/ChangeLog?rev=1.86&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/btrfs-progs/ChangeLog?rev=1.86&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/btrfs-progs/ChangeLog?r1=1.85&r2=1.86

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/btrfs-progs/ChangeLog,v
retrieving revision 1.85
retrieving revision 1.86
diff -u -r1.85 -r1.86
--- ChangeLog	23 Sep 2014 17:53:52 -0000	1.85
+++ ChangeLog	23 Sep 2014 18:01:42 -0000	1.86
@@ -1,6 +1,11 @@
 # ChangeLog for sys-fs/btrfs-progs
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/btrfs-progs/ChangeLog,v 1.85 2014/09/23 17:53:52 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/btrfs-progs/ChangeLog,v 1.86 2014/09/23 18:01:42 floppym Exp $
+
+*btrfs-progs-3.16.1 (23 Sep 2014)
+
+  23 Sep 2014; Mike Gilbert <floppym@g.o> +btrfs-progs-3.16.1.ebuild:
+  Version bump, bug 523544 by emil karlson.
 
   23 Sep 2014; Mike Gilbert <floppym@g.o> btrfs-progs-9999.ebuild:
   Switch to git-r3. Use Dave Sterba's git repo per announcement on linux-btrfs



1.1                  sys-fs/btrfs-progs/btrfs-progs-3.16.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/btrfs-progs/btrfs-progs-3.16.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/btrfs-progs/btrfs-progs-3.16.1.ebuild?rev=1.1&content-type=text/plain

Index: btrfs-progs-3.16.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/btrfs-progs/btrfs-progs-3.16.1.ebuild,v 1.1 2014/09/23 18:01:42 floppym Exp $

EAPI=5

inherit eutils multilib toolchain-funcs

libbtrfs_soname=0

if [[ ${PV} != 9999 ]]; then
	MY_PV=v${PV}
	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
	SRC_URI="https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${PN}-${MY_PV}.tar.xz"
	S="${WORKDIR}"/${PN}-${MY_PV}
else
	inherit git-r3
	EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/kdave/btrfs-progs.git
		https://git.kernel.org/pub/scm/linux/kernel/git/kdave/btrfs-progs.git"
fi

DESCRIPTION="Btrfs filesystem utilities"
HOMEPAGE="https://btrfs.wiki.kernel.org"

LICENSE="GPL-2"
SLOT="0/${libbtrfs_soname}"
IUSE=""

RESTRICT=test # tries to mount repared filesystems

RDEPEND="
	dev-libs/lzo:2=
	sys-libs/zlib:0=
	sys-fs/e2fsprogs:0=
"
DEPEND="${RDEPEND}
	sys-apps/acl
	app-text/asciidoc
	app-text/docbook-xml-dtd:4.5
	app-text/xmlto
"

src_prepare() {
	epatch_user
}

src_compile() {
	emake \
		AR="$(tc-getAR)" \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		BUILD_VERBOSE=1
}

src_install() {
	emake install \
		DESTDIR="${D}" \
		prefix=/usr \
		bindir=/sbin \
		libdir=/usr/$(get_libdir) \
		mandir=/usr/share/man
}