[gentoo-commits] gentoo-x86 commit in net-misc/dhcpcd: ChangeLog dhcpcd-5.1.4.ebuild

[William Hubbs (williamh)]

williamh    09/12/29 20:58:10

  Modified:             ChangeLog
  Added:                dhcpcd-5.1.4.ebuild
  Log:
  version bump
  (Portage version: 2.2_rc61/cvs/Linux i686)

Revision  Changes    Path
1.274                net-misc/dhcpcd/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/dhcpcd/ChangeLog?rev=1.274&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/dhcpcd/ChangeLog?rev=1.274&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/dhcpcd/ChangeLog?r1=1.273&r2=1.274

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/ChangeLog,v
retrieving revision 1.273
retrieving revision 1.274
diff -u -r1.273 -r1.274
--- ChangeLog	28 Dec 2009 18:41:32 -0000	1.273
+++ ChangeLog	29 Dec 2009 20:58:10 -0000	1.274
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/dhcpcd
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/ChangeLog,v 1.273 2009/12/28 18:41:32 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/ChangeLog,v 1.274 2009/12/29 20:58:10 williamh Exp $
+
+*dhcpcd-5.1.4 (29 Dec 2009)
+
+  29 Dec 2009; William Hubbs <williamh@g.o> +dhcpcd-5.1.4.ebuild:
+  version bump
 
   28 Dec 2009; nixnut <nixnut@g.o> dhcpcd-4.0.15.ebuild:
   ppc stable #293502



1.1                  net-misc/dhcpcd/dhcpcd-5.1.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/dhcpcd/dhcpcd-5.1.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/dhcpcd/dhcpcd-5.1.4.ebuild?rev=1.1&content-type=text/plain

Index: dhcpcd-5.1.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/dhcpcd/dhcpcd-5.1.4.ebuild,v 1.1 2009/12/29 20:58:10 williamh Exp $

EAPI=1

inherit eutils

MY_P="${P/_alpha/-alpha}"
MY_P="${MY_P/_beta/-beta}"
MY_P="${MY_P/_rc/-rc}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="A fully featured, yet light weight RFC2131 compliant DHCP client"
HOMEPAGE="http://roy.marples.name/projects/dhcpcd/"
SRC_URI="http://roy.marples.name/downloads/${PN}/${MY_P}.tar.bz2"
LICENSE="BSD-2"

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"

SLOT="0"
IUSE="+zeroconf"

DEPEND=""
PROVIDE="virtual/dhcpc"

src_unpack() {
	unpack ${A}
	cd "${S}"

	if ! use zeroconf; then
		elog "Disabling zeroconf support"
		{
			echo
			echo "# dhcpcd ebuild requested no zeroconf"
			echo "noipv4ll"
		} >> dhcpcd.conf
	fi
}

src_compile() {
	local hooks="--with-hook=ntp.conf"
	use elibc_glibc && hooks="${hooks} --with-hook=yp.conf"
	econf --prefix= --libexecdir=/lib/dhcpcd --dbdir=/var/lib/dhcpcd \
		--localstatedir=/var ${hooks}
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	newinitd "${FILESDIR}"/${PN}.initd ${PN}
}

pkg_postinst() {
	# Upgrade the duid file to the new format if needed
	local old_duid="${ROOT}"/var/lib/dhcpcd/dhcpcd.duid
	local new_duid="${ROOT}"/etc/dhcpcd.duid
	if [ -e "${old_duid}" ] && ! grep -q '..:..:..:..:..:..' "${old_duid}"; then
		sed -i -e 's/\(..\)/\1:/g; s/:$//g' "${old_duid}"
	fi

	# Move the duid to /etc, a more sensible location
	if [ -e "${old_duid}" -a ! -e "${new_duid}" ]; then
		cp -p "${old_duid}" "${new_duid}"
	fi

	if use zeroconf; then
		elog "You have installed dhcpcd with zeroconf support."
		elog "This means that it will always obtain an IP address even if no"
		elog "DHCP server can be contacted, which will break any existing"
		elog "failover support you may have configured in your net configuration."
		elog "This behaviour can be controlled with the -L flag."
		elog "See the dhcpcd man page for more details."
	fi

	elog
	elog "Users transfering from 4.0 series should pay attention to removal"
	elog "of compat useflag. This changes behavior of dhcp in wide manner:"
	elog "dhcpcd no longer sends a default ClientID for ethernet interfaces."
	elog "This is so we can re-use the address the kernel DHCP client found."
	elog "To retain the old behaviour of sending a default ClientID based on the"
	elog "hardware address for interface, simply add the keyword clientid"
	elog "to dhcpcd.conf or use commandline parameter -I ''"
}