[gentoo-commits] gentoo-x86 commit in www-plugins/mozilla-weave: ChangeLog mozilla-weave-0.7.ebuild

[Mounir Lamouri (volkmar)]

volkmar     09/10/01 17:06:10

  Modified:             ChangeLog
  Added:                mozilla-weave-0.7.ebuild
  Log:
  Version bump to 0.7.
  (Portage version: 14420-svn/cvs/Linux ppc)

Revision  Changes    Path
1.15                 www-plugins/mozilla-weave/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-plugins/mozilla-weave/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-plugins/mozilla-weave/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-plugins/mozilla-weave/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-plugins/mozilla-weave/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	30 Aug 2009 10:36:50 -0000	1.14
+++ ChangeLog	1 Oct 2009 17:06:10 -0000	1.15
@@ -1,6 +1,12 @@
 # ChangeLog for www-plugins/mozilla-weave
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-plugins/mozilla-weave/ChangeLog,v 1.14 2009/08/30 10:36:50 volkmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-plugins/mozilla-weave/ChangeLog,v 1.15 2009/10/01 17:06:10 volkmar Exp $
+
+*mozilla-weave-0.7 (01 Oct 2009)
+
+  01 Oct 2009; Mounir Lamouri <volkmar@g.o>
+  +mozilla-weave-0.7.ebuild:
+  Version bump to 0.7.
 
   30 Aug 2009; Mounir Lamouri <volkmar@g.o> mozilla-weave-0.6.ebuild:
   Workaround for parallel compilation issues



1.1                  www-plugins/mozilla-weave/mozilla-weave-0.7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-plugins/mozilla-weave/mozilla-weave-0.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-plugins/mozilla-weave/mozilla-weave-0.7.ebuild?rev=1.1&content-type=text/plain

Index: mozilla-weave-0.7.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-plugins/mozilla-weave/mozilla-weave-0.7.ebuild,v 1.1 2009/10/01 17:06:10 volkmar Exp $

EAPI="2"

inherit eutils mozextension multilib

MY_PN="weave"
MY_P=${MY_PN}-${PV}

DESCRIPTION="Mozilla Labs prototype for online services"
HOMEPAGE="http://labs.mozilla.com/projects/weave/"
SRC_URI="http://hg.mozilla.org/labs/${MY_PN}/archive/${PV}.tar.bz2
	-> ${P}.tar.bz2"

LICENSE="|| ( MPL-1.1 GPL-2 LGPL-2.1 )"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

RDEPEND="|| (
		>=www-client/mozilla-firefox-3.5
		>=www-client/mozilla-firefox-bin-3.5
		>=www-client/seamonkey-2.0_alpha3
		>=www-client/seamonkey-bin-2.0_alpha3
		>=mail-client/mozilla-thunderbird-3.0_beta2
		>=mail-client/mozilla-thunderbird-bin-3.0_beta2
	)
	>=net-libs/xulrunner-1.9.1
	>=dev-libs/nss-3.12
	>=dev-libs/nspr-4.7.1"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${MY_P}

RESTRICT="test"

# NOTES:
# fennec is also listed in install.rdf but not in-tree

# TODO:
# tests are failing because they are not using pkgconfig
# parallel compilation isssues
# server ebuild: https://wiki.mozilla.org/Labs/Weave/0.5/Setup/Storage

src_prepare() {
	# remove compiled files
	rm -rf crypto/platform/* || die "rm -rf never dies"

	# upstream bug 504022
	epatch "${FILESDIR}"/${PN}-0.5.1-pkgconfig.patch
}

src_compile() {
	export WEAVE_BUILDID=${PV}

	emake -j1 rebuild_crypto=1 build || die "emake failed"
}

#src_test() {
#	emake -j1 test || die "emake test"
#}

src_install() {
	local MOZILLA_FIVE_HOME xpiname

	emake release_build=1 xpi || die "emake xpi failed"

	mozillas=""
	xpiname="${MY_P}-rel"
	xpi_unpack "${S}/dist/xpi/${xpiname}.xpi"

	# FIXME: Hard-coded MOZILLA_FIVE_HOME dirs
	if has_version '>=www-client/mozilla-firefox-3.5'; then
		MOZILLA_FIVE_HOME="/usr/$(get_libdir)/mozilla-firefox"
		xpi_install "${WORKDIR}/${xpiname}"
		mozillas="$(best_version www-client/mozilla-firefox) ${mozillas}"
	fi
	if has_version '>=www-client/mozilla-firefox-bin-3.5'; then
		MOZILLA_FIVE_HOME="/opt/firefox"
		xpi_install "${WORKDIR}/${xpiname}"
		mozillas="$(best_version www-client/mozilla-firefox-bin) ${mozillas}"
	fi
	if has_version '>=www-client/seamonkey-2.0_alpha3'; then
		MOZILLA_FIVE_HOME="/usr/$(get_libdir)/seamonkey"
		xpi_install "${WORKDIR}/${xpiname}"
		mozillas="$(best_version www-client/seamonkey) ${mozillas}"
	fi
	if has_version '>=www-client/seamonkey-bin-2.0_alpha3'; then
		MOZILLA_FIVE_HOME="/opt/seamonkey"
		xpi_install "${WORKDIR}/${xpiname}"
		mozillas="$(best_version www-client/seamonkey-bin) ${mozillas}"
	fi
	if has_version '>=mail-client/mozilla-thunderbird-3.0_beta2'; then
		MOZILLA_FIVE_HOME="/usr/$(get_libdir)/mozilla-thunderbird"
		xpi_install "${WORKDIR}/${xpiname}"
		mozillas="$(best_version mail-client/mozilla-thunderbird) ${mozillas}"
	fi
	if has_version '>=mail-client/mozilla-thunderbird-bin-3.0_beta2'; then
		MOZILLA_FIVE_HOME="/opt/thunderbird"
		xpi_install "${WORKDIR}/${xpiname}"
		mozillas="$(best_version mail-client/mozilla-thunderbird-bin) ${mozillas}"
	fi
}

pkg_postinst() {
	elog "Weave has been installed for the following packages:"
	for i in ${mozillas}; do
		elog "	$i"
	done
	elog
	elog "After installing other mozilla ebuilds, if you want to use weave with them,"
	elog "reinstall www-plugins/mozilla-weave"
}