[gentoo-commits] gentoo-x86 commit in dev-python/imaging: imaging-2.0.0.ebuild metadata.xml ChangeLog

[Mike Gilbert (floppym)]

floppym     13/05/27 23:27:33

  Modified:             metadata.xml ChangeLog
  Added:                imaging-2.0.0.ebuild
  Log:
  Copy dev-python/pillow-2.0.0 to dev-python/imaging-2.0.0 in preparation for a pkgmove. Apply rebased patches from Arfrever's Progress overlay. Enable python3 support. Bug 401009.
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.2                  dev-python/imaging/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/imaging/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/imaging/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/imaging/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/imaging/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	19 Jul 2004 21:50:44 -0000	1.1
+++ metadata.xml	27 May 2013 23:27:33 -0000	1.2
@@ -1,5 +1,8 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>python</herd>
+	<herd>python</herd>
+	<use>
+		<flag name='webp'>Enable support for webp image format.</flag>
+	</use>
 </pkgmetadata>



1.86                 dev-python/imaging/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/imaging/ChangeLog?rev=1.86&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/imaging/ChangeLog?rev=1.86&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/imaging/ChangeLog?r1=1.85&r2=1.86

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/imaging/ChangeLog,v
retrieving revision 1.85
retrieving revision 1.86
diff -u -r1.85 -r1.86
--- ChangeLog	7 May 2013 23:27:25 -0000	1.85
+++ ChangeLog	27 May 2013 23:27:33 -0000	1.86
@@ -1,6 +1,17 @@
 # ChangeLog for dev-python/imaging
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/imaging/ChangeLog,v 1.85 2013/05/07 23:27:25 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/imaging/ChangeLog,v 1.86 2013/05/27 23:27:33 floppym Exp $
+
+*imaging-2.0.0 (27 May 2013)
+
+  27 May 2013; Mike Gilbert <floppym@g.o>
+  +files/imaging-2.0.0-GifImagePlugin.patch,
+  +files/imaging-2.0.0-delete_hardcoded_paths.patch,
+  +files/imaging-2.0.0-gif_transparency.patch,
+  +files/imaging-2.0.0-libm_linking.patch, +imaging-2.0.0.ebuild, metadata.xml:
+  Copy dev-python/pillow-2.0.0 to dev-python/imaging-2.0.0 in preparation for a
+  pkgmove. Apply rebased patches from Arfrever's Progress overlay. Enable
+  python3 support. Bug 401009.
 
 *imaging-1.1.7-r4 (07 May 2013)
 



1.1                  dev-python/imaging/imaging-2.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/imaging/imaging-2.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/imaging/imaging-2.0.0.ebuild?rev=1.1&content-type=text/plain

Index: imaging-2.0.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/imaging/imaging-2.0.0.ebuild,v 1.1 2013/05/27 23:27:33 floppym Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
PYTHON_REQ_USE='tk?'

inherit distutils-r1 eutils

MY_PN=Pillow
MY_P=${MY_PN}-${PV}

DESCRIPTION="Python Imaging Library (fork)"
HOMEPAGE="https://github.com/python-imaging/Pillow https://pypi.python.org/pypi/Pillow"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"

LICENSE="HPND"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
IUSE="doc examples jpeg lcms scanner test tiff tk truetype webp zlib"

RDEPEND="
	truetype? ( media-libs/freetype:2= )
	jpeg? ( virtual/jpeg )
	lcms? ( media-libs/lcms:0= )
	scanner? ( media-gfx/sane-backends:0= )
	tiff? ( media-libs/tiff:0= )
	webp? ( media-libs/libwebp:0= )
	zlib? ( sys-libs/zlib:0= )"
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx )"

# Tests don't handle missing jpeg, tiff & zlib properly.
# https://github.com/python-imaging/Pillow/pull/199
REQUIRED_USE="test? ( jpeg tiff zlib )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# Tests like to write to cwd.
	# https://github.com/python-imaging/Pillow/pull/200
	use test && DISTUTILS_IN_SOURCE_BUILD=1

	distutils-r1_src_prepare
}

python_prepare_all() {
	# Apply patches before executing sed.
	local patches=(
		"${FILESDIR}/imaging-1.1.7-no-xv.patch"
		"${FILESDIR}/imaging-2.0.0-delete_hardcoded_paths.patch"
		"${FILESDIR}/imaging-2.0.0-gif_transparency.patch"
		"${FILESDIR}/imaging-2.0.0-libm_linking.patch"
		"${FILESDIR}/imaging-2.0.0-GifImagePlugin.patch"
	)
	epatch "${patches[@]}"

	# Add shebangs.
	# https://github.com/python-imaging/Pillow/pull/197
	sed -e "1i#!/usr/bin/env python" -i Scripts/*.py || die

	# Disable all the stuff we don't want.
	local f
	for f in jpeg lcms tiff tk webp zlib; do
		if ! use ${f}; then
			sed -i -e "s:feature.${f} =:& None #:" setup.py || die
		fi
	done
	if ! use truetype; then
		sed -i -e 's:feature.freetype =:& None #:' setup.py || die
	fi

	distutils-r1_python_prepare_all
}

# XXX: split into two ebuilds?
wrap_phase() {
	"${@}"

	if use scanner; then
		cd Sane || die
		"${@}"
	fi
}

python_compile() {
	wrap_phase distutils-r1_python_compile
}

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	"${PYTHON}" selftest.py || die "Tests fail with ${EPYTHON}"
	"${PYTHON}" Tests/run.py --installed || die "Tests fail with ${EPYTHON}"
}

python_install() {
	python_doheader libImaging/{Imaging.h,ImPlatform.h}

	wrap_phase distutils-r1_python_install
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/. )
	use examples && local EXAMPLES=( Scripts/. )

	distutils-r1_python_install_all

	if use scanner; then
		docinto sane
		dodoc Sane/{CHANGES,README,sanedoc.txt}
	fi

	if use examples && use scanner; then
		docinto examples/sane
		doins Sane/demo_*.py
	fi
}