[gentoo-commits] gentoo-x86 commit in sys-fs/zfs-kmod: zfs-kmod-0.6.2-r3.ebuild zfs-kmod-9999.ebuild ChangeLog zfs-kmod-0.6.2-r2.ebuild zfs-kmod-0.6.2.ebuild zfs-kmod-0.6.2-r1.ebuild

[Richard Yao (ryao)]

ryao        13/11/21 15:47:44

  Modified:             zfs-kmod-9999.ebuild ChangeLog
  Added:                zfs-kmod-0.6.2-r3.ebuild
  Removed:              zfs-kmod-0.6.2-r2.ebuild zfs-kmod-0.6.2.ebuild
                        zfs-kmod-0.6.2-r1.ebuild
  Log:
  Fix writeback regression introduced in -r2 that affected mmap() and AIO writes; Apply locking fixes from Illumos; Reintroduce uio_prefaultpages() to minimize the possibility of hitting zfsonlinux/zfs#1689; Add Linux 3.12 Support
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0xBEE84C64)

Revision  Changes    Path
1.18                 sys-fs/zfs-kmod/zfs-kmod-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild?r1=1.17&r2=1.18

Index: zfs-kmod-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- zfs-kmod-9999.ebuild	17 Apr 2013 14:30:18 -0000	1.17
+++ zfs-kmod-9999.ebuild	21 Nov 2013 15:47:44 -0000	1.18
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild,v 1.17 2013/04/17 14:30:18 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-9999.ebuild,v 1.18 2013/11/21 15:47:44 ryao Exp $
 
 EAPI="4"
 
@@ -17,7 +17,8 @@
 else
 	inherit eutils versionator
 	MY_PV=$(replace_version_separator 3 '-')
-	SRC_URI="https://github.com/zfsonlinux/zfs/archive/zfs-${MY_PV}.tar.gz"
+	SRC_URI="https://github.com/zfsonlinux/zfs/archive/zfs-${MY_PV}.tar.gz
+		http://dev.gentoo.org/~ryao/dist/${PN}-${MY_PV}-p2.tar.xz"
 	S="${WORKDIR}/zfs-zfs-${MY_PV}"
 	KEYWORDS="~amd64"
 fi
@@ -59,7 +60,7 @@
 	kernel_is ge 2 6 26 || die "Linux 2.6.26 or newer required"
 
 	[ ${PV} != "9999" ] && \
-		{ kernel_is le 3 9 || die "Linux 3.9 is the latest supported version."; }
+		{ kernel_is le 3 12 || die "Linux 3.12 is the latest supported version."; }
 
 	check_extra_config
 }
@@ -68,6 +69,14 @@
 	# Remove GPLv2-licensed ZPIOS unless we are debugging
 	use debug || sed -e 's/^subdir-m += zpios$//' -i "${S}/module/Makefile.in"
 
+	if [ ${PV} != "9999" ]
+	then
+		# Apply patch set
+		EPATCH_SUFFIX="patch" \
+		EPATCH_FORCE="yes" \
+		epatch "${WORKDIR}/${PN}-${MY_PV}-patches"
+	fi
+
 	autotools-utils_src_prepare
 }
 



1.40                 sys-fs/zfs-kmod/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	18 Oct 2013 16:25:53 -0000	1.39
+++ ChangeLog	21 Nov 2013 15:47:44 -0000	1.40
@@ -1,6 +1,16 @@
 # ChangeLog for sys-fs/zfs-kmod
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/ChangeLog,v 1.39 2013/10/18 16:25:53 ryao Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/ChangeLog,v 1.40 2013/11/21 15:47:44 ryao Exp $
+
+*zfs-kmod-0.6.2-r3 (21 Nov 2013)
+
+  21 Nov 2013; Richard Yao <ryao@g.o> +zfs-kmod-0.6.2-r3.ebuild,
+  -zfs-kmod-0.6.2-r1.ebuild, -zfs-kmod-0.6.2-r2.ebuild, -zfs-kmod-0.6.2.ebuild,
+  zfs-kmod-9999.ebuild:
+  Fix writeback regression introduced in -r2 that affected mmap() and AIO
+  writes; Apply locking fixes from Illumos; Reintroduce uio_prefaultpages() to
+  minimize the possibility of hitting zfsonlinux/zfs#1689; Add Linux 3.12
+  Support
 
 *zfs-kmod-0.6.2-r2 (18 Oct 2013)
 



1.1                  sys-fs/zfs-kmod/zfs-kmod-0.6.2-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r3.ebuild?rev=1.1&content-type=text/plain

Index: zfs-kmod-0.6.2-r3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/zfs-kmod/zfs-kmod-0.6.2-r3.ebuild,v 1.1 2013/11/21 15:47:44 ryao Exp $

EAPI="4"

AT_M4DIR="config"
AUTOTOOLS_AUTORECONF="1"
AUTOTOOLS_IN_SOURCE_BUILD="1"

inherit bash-completion-r1 flag-o-matic linux-info linux-mod toolchain-funcs autotools-utils

if [ ${PV} == "9999" ] ; then
	inherit git-2
	MY_PV=9999
	EGIT_REPO_URI="git://github.com/zfsonlinux/zfs.git"
else
	inherit eutils versionator
	MY_PV=$(replace_version_separator 3 '-')
	SRC_URI="https://github.com/zfsonlinux/zfs/archive/zfs-${MY_PV}.tar.gz
		http://dev.gentoo.org/~ryao/dist/${PN}-${MY_PV}-p2.tar.xz"
	S="${WORKDIR}/zfs-zfs-${MY_PV}"
	KEYWORDS="~amd64"
fi

DESCRIPTION="Linux ZFS kernel module for sys-fs/zfs"
HOMEPAGE="http://zfsonlinux.org/"

LICENSE="CDDL debug? ( GPL-2+ )"
SLOT="0"
IUSE="custom-cflags debug +rootfs"
RESTRICT="test"

DEPEND="
	=sys-kernel/spl-${PV}*
	dev-lang/perl
	virtual/awk
"

RDEPEND="${DEPEND}
	!sys-fs/zfs-fuse
"

pkg_setup() {
	linux-info_pkg_setup
	CONFIG_CHECK="!DEBUG_LOCK_ALLOC
		BLK_DEV_LOOP
		EFI_PARTITION
		IOSCHED_NOOP
		MODULES
		!PAX_KERNEXEC_PLUGIN_METHOD_OR
		ZLIB_DEFLATE
		ZLIB_INFLATE
	"

	use rootfs && \
		CONFIG_CHECK="${CONFIG_CHECK} BLK_DEV_INITRD
			DEVTMPFS"

	kernel_is ge 2 6 26 || die "Linux 2.6.26 or newer required"

	[ ${PV} != "9999" ] && \
		{ kernel_is le 3 12 || die "Linux 3.12 is the latest supported version."; }

	check_extra_config
}

src_prepare() {
	# Remove GPLv2-licensed ZPIOS unless we are debugging
	use debug || sed -e 's/^subdir-m += zpios$//' -i "${S}/module/Makefile.in"

	if [ ${PV} != "9999" ]
	then
		# Apply patch set
		EPATCH_SUFFIX="patch" \
		EPATCH_FORCE="yes" \
		epatch "${WORKDIR}/${PN}-${MY_PV}-patches"
	fi

	autotools-utils_src_prepare
}

src_configure() {
	use custom-cflags || strip-flags
	filter-ldflags -Wl,*

	set_arch_to_kernel
	local myeconfargs=(
		--bindir="${EPREFIX}/bin"
		--sbindir="${EPREFIX}/sbin"
		--with-config=kernel
		--with-linux="${KV_DIR}"
		--with-linux-obj="${KV_OUT_DIR}"
		$(use_enable debug)
	)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install
	dodoc AUTHORS COPYRIGHT DISCLAIMER README.markdown
}

pkg_postinst() {
	linux-mod_pkg_postinst

	# Remove old modules
	if [ -d "${EROOT}lib/modules/${KV_FULL}/addon/zfs" ]
	then
		ewarn "${PN} now installs modules in ${EROOT}lib/modules/${KV_FULL}/extra/zfs"
		ewarn "Old modules were detected in ${EROOT}lib/modules/${KV_FULL}/addon/zfs"
		ewarn "Automatically removing old modules to avoid problems."
		rm -r "${EROOT}lib/modules/${KV_FULL}/addon/zfs" || die "Cannot remove modules"
		rmdir --ignore-fail-on-non-empty "${EROOT}lib/modules/${KV_FULL}/addon"
	fi

	if use x86 || use arm
	then
		ewarn "32-bit kernels will likely require increasing vmalloc to"
		ewarn "at least 256M and decreasing zfs_arc_max to some value less than that."
	fi

	ewarn "This version of ZFSOnLinux includes support for features flags."
	ewarn "If you upgrade your pools to make use of feature flags, you will lose"
	ewarn "the ability to import them using older versions of ZFSOnLinux."
	ewarn "Any new pools will be created with feature flag support and will"
	ewarn "not be compatible with older versions of ZFSOnLinux. To create a new"
	ewarn "pool that is backward compatible, use zpool create -o version=28 ..."
}