[gentoo-commits] repo/gentoo:master commit in: app-misc/uptimed/

[John Helmert III]

commit:     106d5ab4c5c1ec11f14e74dfb0ebcc4b72197b53
Author:     John Helmert III <ajak <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 11 04:15:20 2022 +0000
Commit:     John Helmert III <ajak <AT> gentoo <DOT> org>
CommitDate: Thu Aug 11 18:22:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=106d5ab4

app-misc/uptimed: drop ownership changes in pkg_postinst

Bug: https://bugs.gentoo.org/630810
Signed-off-by: John Helmert III <ajak <AT> gentoo.org>

 app-misc/uptimed/uptimed-0.4.6-r1.ebuild | 45 ++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/app-misc/uptimed/uptimed-0.4.6-r1.ebuild b/app-misc/uptimed/uptimed-0.4.6-r1.ebuild
new file mode 100644
index 000000000000..5df4993bf443
--- /dev/null
+++ b/app-misc/uptimed/uptimed-0.4.6-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools systemd
+
+DESCRIPTION="System uptime record daemon that keeps track of your highest uptimes"
+HOMEPAGE="https://github.com/rpodgorny/uptimed/"
+SRC_URI="https://github.com/rpodgorny/uptimed/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	acct-group/uptimed
+	acct-user/uptimed
+"
+DEPEND="${RDEPEND}"
+BDEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_install() {
+	local DOCS=( ChangeLog README.md TODO AUTHORS CREDITS INSTALL.cgi sample-cgi/* )
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+
+	local spooldir="/var/spool/${PN}"
+	keepdir ${spooldir}
+	fowners uptimed:uptimed ${spooldir}
+
+	newinitd "${FILESDIR}"/${PN}.init-r1 uptimed
+	systemd_dounit "${FILESDIR}/${PN}.service"
+}
+
+pkg_postinst() {
+	elog "Start uptimed with '/etc/init.d/uptimed start' (for openRC)"
+	elog "or systemctl start uptimed (for systemd)"
+	elog "To view your uptime records, use the command 'uprecords'."
+}