[gentoo-commits] gentoo-x86 commit in www-client/arora: ChangeLog arora-0.7.1.ebuild

[Ben de Groot (yngwin)]

yngwin      09/05/31 00:35:24

  Modified:             ChangeLog
  Added:                arora-0.7.1.ebuild
  Log:
  Version bump. This release fixes parallel make issues, bug 271240.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 www-client/arora/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/arora/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/arora/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/arora/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/arora/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	25 May 2009 22:43:03 -0000	1.16
+++ ChangeLog	31 May 2009 00:35:24 -0000	1.17
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/arora
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/arora/ChangeLog,v 1.16 2009/05/25 22:43:03 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/arora/ChangeLog,v 1.17 2009/05/31 00:35:24 yngwin Exp $
+
+*arora-0.7.1 (31 May 2009)
+
+  31 May 2009; Ben de Groot <yngwin@g.o> +arora-0.7.1.ebuild:
+  Version bump. This release fixes parallel make issues, bug 271240.
 
   25 May 2009; Ben de Groot <yngwin@g.o> arora-0.7.0.ebuild:
   Ensure compilation by enforcing make -j1, fixes bug 271240



1.1                  www-client/arora/arora-0.7.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/arora/arora-0.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/arora/arora-0.7.1.ebuild?rev=1.1&content-type=text/plain

Index: arora-0.7.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/arora/arora-0.7.1.ebuild,v 1.1 2009/05/31 00:35:24 yngwin Exp $

EAPI=2
inherit eutils qt4

DESCRIPTION="A cross-platform Qt4 WebKit browser"
HOMEPAGE="http://arora.googlecode.com/"
SRC_URI="http://arora.googlecode.com/files/${P}.tar.gz"

LICENSE="|| ( GPL-3 GPL-2 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

RDEPEND="x11-libs/qt-gui
	x11-libs/qt-sql
	x11-libs/qt-webkit"
DEPEND="$RDEPEND"

ARORA_LANGS="es es_CR et_EE fr_CA gl ms nb_NO uk zh_CN"
ARORA_NOLONGLANGS="cs_CZ da_DK de_DE fr_FR he_IL hu_HU it_IT ja_JP nl_NL pl_PL
	ru_RU sk_SK tr_TR"

for L in $ARORA_LANGS; do
	IUSE="$IUSE linguas_$L"
done
for L in $ARORA_NOLONGLANGS; do
	IUSE="$IUSE linguas_${L%_*}"
done

src_prepare() {
	# process linguas
	local langs=
	for lingua in $LINGUAS; do
		if has $lingua $ARORA_LANGS; then
			langs="$langs ${lingua}.ts"
		else
			for a in $ARORA_NOLONGLANGS; do
				if [[ $lingua == ${a%_*} ]]; then
					langs="$langs ${a}.ts"
				fi
			done
		fi
	done

	# remove all translations, then add only the ones we want
	sed -i '/ts/d' src/locale/locale.pri || die 'sed failed'
	sed -i "/^TRANSLATIONS/s:\\\:${langs}:" src/locale/locale.pri \
		|| die 'sed failed'
}

src_configure() {
	eqmake4 arora.pro PREFIX=/usr
}

src_compile() {
	emake || die "make failed"

	# don't pre-strip
	sed -i "/strip/d" src/Makefile || die 'sed failed'
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die 'make install failed'
	dodoc AUTHORS ChangeLog README
}