[gentoo-commits] gentoo-x86 commit in dev-util/meld: ChangeLog meld-1.3.1.ebuild

[Gilles Dartiguelongue (eva)]

eva         09/08/31 22:15:43

  Modified:             ChangeLog
  Added:                meld-1.3.1.ebuild
  Log:
  Version bump. Add support for svk.
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.103                dev-util/meld/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/meld/ChangeLog?rev=1.103&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/meld/ChangeLog?rev=1.103&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/meld/ChangeLog?r1=1.102&r2=1.103

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v
retrieving revision 1.102
retrieving revision 1.103
diff -u -r1.102 -r1.103
--- ChangeLog	27 Jul 2009 08:47:50 -0000	1.102
+++ ChangeLog	31 Aug 2009 22:15:43 -0000	1.103
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/meld
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v 1.102 2009/07/27 08:47:50 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v 1.103 2009/08/31 22:15:43 eva Exp $
+
+*meld-1.3.1 (31 Aug 2009)
+
+  31 Aug 2009; Gilles Dartiguelongue <eva@g.o> +meld-1.3.1.ebuild:
+  Version bump. Add support for svk.
 
   27 Jul 2009; Gilles Dartiguelongue <eva@g.o> -meld-1.2.1.ebuild,
   -files/meld-1.2-fr-help-install-fix.patch,



1.1                  dev-util/meld/meld-1.3.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/meld/meld-1.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/meld/meld-1.3.1.ebuild?rev=1.1&content-type=text/plain

Index: meld-1.3.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/meld-1.3.1.ebuild,v 1.1 2009/08/31 22:15:43 eva Exp $

GCONF_DEBUG="no"

inherit python gnome2 eutils multilib

DESCRIPTION="A graphical (GNOME 2) diff and merge tool"
HOMEPAGE="http://meld.sourceforge.net/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc gnome"

RDEPEND=">=dev-lang/python-2.4
	>=gnome-base/libglade-2
	gnome? (
		>=gnome-base/libgnome-2
		>=dev-python/libgnome-python-2.22
		>=dev-python/gconf-python-2.22
		>=dev-python/gnome-vfs-python-2.22 )
	>=dev-python/pygtk-2.8.0
	>=dev-python/pygobject-2.8"

DEPEND="${RDEPEND}
	dev-util/intltool
	app-text/scrollkeeper"

DOCS="AUTHORS NEWS help/ChangeLog"

src_unpack() {
	gnome2_src_unpack

	# fix the prefix so its not in */local/*
	sed -e 's:/usr/local:/usr:' \
		-e "s:\$(prefix)/lib:\$(prefix)/$(get_libdir):" \
		-i INSTALL || die "sed 1 failed"

	# don't install anything to /usr/share/doc/meld
	sed -e "s:\$(docdir)/meld:\$(docdir)/${PF}:" \
		-i INSTALL || die "sed 2 failed"

	# let the python eclass handle python objects
	sed -e '/$(PYTHON) .* .import compileall;/s/\t/&#/g' \
		-i GNUmakefile || die "sed 3 failed"

	# don't run scrollkeeper (with the wrong path), leave that to gnome2.eclass #145833
	sed -e '/scrollkeeper-update/s/\t/&#/' \
		-i help/*/GNUmakefile || die "sed 4 failed"

	strip-linguas -i "${S}/po"
	local mylinguas=""
	for x in ${LINGUAS}; do
		mylinguas="${mylinguas} ${x}.po"
	done

	if [ -n "${mylinguas}" ]; then
		sed -e "s/PO:=.*/PO:=${mylinguas}/" \
			-i po/GNUmakefile || die "sed 5 failed"
	fi
}

src_compile() {
	emake || die "make failed"
}

pkg_postinst() {
	python_mod_optimize /usr/$(get_libdir)/meld
}

pkg_postrm() {
	python_mod_cleanup /usr/$(get_libdir)/meld
}