[gentoo-commits] repo/gentoo:master commit in: dev-python/pygame/

[Pacho Ramos]

commit:     d16e686d30d8e23d5e6dcd2be7d7d2dd113a0d1d
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 27 10:58:24 2019 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Fri Dec 27 10:58:24 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d16e686d

dev-python/pygame: Support python 3.8, drop python2 support

All reverse deps will use only python3 and those python2 consumers are dead
and will be removed.

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 dev-python/pygame/pygame-1.9.6-r1.ebuild | 78 ++++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

diff --git a/dev-python/pygame/pygame-1.9.6-r1.ebuild b/dev-python/pygame/pygame-1.9.6-r1.ebuild
new file mode 100644
index 00000000000..89b0bbacb58
--- /dev/null
+++ b/dev-python/pygame/pygame-1.9.6-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8} )
+
+inherit flag-o-matic distutils-r1 virtualx
+
+DESCRIPTION="Python bindings for SDL multimedia library"
+HOMEPAGE="http://www.pygame.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~sparc ~x86"
+IUSE="doc examples midi X"
+
+DEPEND="dev-python/numpy[${PYTHON_USEDEP}]
+	>=media-libs/sdl-image-1.2.2[png,jpeg]
+	>=media-libs/sdl-mixer-1.2.4
+	>=media-libs/sdl-ttf-2.0.6
+	>=media-libs/smpeg-0.4.4-r1
+	midi? ( media-libs/portmidi )
+	X? ( >=media-libs/libsdl-1.2.5[X,video] )
+	!X? ( >=media-libs/libsdl-1.2.5 )"
+RDEPEND="${DEPEND}"
+
+# various module import and data path issues
+RESTRICT=test
+
+python_configure() {
+	PORTMIDI_INC_PORTTIME=1 LOCALBASE="${EPREFIX}/usr" \
+		"${EPYTHON}" "${S}"/buildconfig/config.py -auto
+
+	if ! use X; then
+		sed -e "s:^scrap :#&:" -i Setup || die "sed failed"
+	fi
+
+	# Disable automagic dependency on PortMidi.
+	if ! use midi; then
+		sed -e "s:^pypm :#&:" -i Setup || die "sed failed"
+	fi
+}
+
+python_compile() {
+	if [[ ${EPYTHON} == python2* ]]; then
+		local CFLAGS=${CFLAGS} CXXFLAGS=${CXXFLAGS}
+
+		append-flags -fno-strict-aliasing
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	PYTHONPATH="${BUILD_DIR}/lib" virtx "${EPYTHON}" -m pygame.tests
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Bug #497720
+	rm -fr "${D}"$(python_get_sitedir)/pygame/{docs,examples,tests}/ || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use doc; then
+		docinto html
+		dodoc -r docs/*
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r examples/*
+	fi
+}