[gentoo-commits] repo/gentoo:master commit in: app-emulation/runc/

[Manuel Rüger]

commit:     338877c5db2066c54a0b9b54464347e9b9901417
Author:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
AuthorDate: Fri Apr  6 21:41:11 2018 +0000
Commit:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
CommitDate: Fri Apr  6 22:00:52 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=338877c5

app-emulation/runc: Use full commit hash

Package-Manager: Portage-2.3.28, Repoman-2.3.9

 app-emulation/runc/runc-1.0.0_rc5-r1.ebuild | 54 +++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/app-emulation/runc/runc-1.0.0_rc5-r1.ebuild b/app-emulation/runc/runc-1.0.0_rc5-r1.ebuild
new file mode 100644
index 00000000000..d733f98a812
--- /dev/null
+++ b/app-emulation/runc/runc-1.0.0_rc5-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+EGO_PN="github.com/opencontainers/${PN}"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit golang-build golang-vcs
+else
+	MY_PV="${PV/_/-}"
+	EGIT_COMMIT="v${MY_PV}"
+	RUNC_COMMIT="4fc53a81fb7c994640722ac585fa9ca548971871" # Change this when you update the ebuild
+	SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc64"
+	inherit golang-build golang-vcs-snapshot
+fi
+
+DESCRIPTION="runc container cli tools"
+HOMEPAGE="http://runc.io"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+ambient apparmor hardened +seccomp"
+
+RDEPEND="
+	apparmor? ( sys-libs/libapparmor )
+	seccomp? ( sys-libs/libseccomp )
+	!app-emulation/docker-runc
+"
+
+src_compile() {
+	# Taken from app-emulation/docker-1.7.0-r1
+	export CGO_CFLAGS="-I${ROOT}/usr/include"
+	export CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')
+		-L${ROOT}/usr/$(get_libdir)"
+
+	# build up optional flags
+	local options=(
+		$(usex ambient 'ambient')
+		$(usex apparmor 'apparmor')
+		$(usex seccomp 'seccomp')
+	)
+
+	GOPATH="${S}"\
+		emake BUILDTAGS="${options[*]}" \
+		COMMIT="${RUNC_COMMIT}" -C src/${EGO_PN}
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin runc
+	dodoc README.md PRINCIPLES.md
+	popd || die
+}