[gentoo-commits] gentoo-x86 commit in net-misc/pino: ChangeLog pino-0.2.10.ebuild pino-0.2.6.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    10/05/27 05:47:45

  Modified:             ChangeLog
  Added:                pino-0.2.10.ebuild
  Removed:              pino-0.2.6.ebuild
  Log:
  Version bump. Dropped old.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  net-misc/pino/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/pino/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/pino/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/pino/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/pino/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	16 May 2010 14:39:17 -0000	1.3
+++ ChangeLog	27 May 2010 05:47:45 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/pino
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/pino/ChangeLog,v 1.3 2010/05/16 14:39:17 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/pino/ChangeLog,v 1.4 2010/05/27 05:47:45 dev-zero Exp $
+
+*pino-0.2.10 (27 May 2010)
+
+  27 May 2010; Tiziano Müller <dev-zero@g.o> -pino-0.2.6.ebuild,
+  +pino-0.2.10.ebuild:
+  Version bump. Dropped old.
 
 *pino-0.2.9 (16 May 2010)
 



1.1                  net-misc/pino/pino-0.2.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/pino/pino-0.2.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/pino/pino-0.2.10.ebuild?rev=1.1&content-type=text/plain

Index: pino-0.2.10.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/pino/pino-0.2.10.ebuild,v 1.1 2010/05/27 05:47:45 dev-zero Exp $

EAPI="3"

DESCRIPTION="Twitter and Identi.ca desktop client written in Vala"
HOMEPAGE="http://pino-app.appspot.com/ http://code.google.com/p/pino-twitter/"
SRC_URI="http://pino-twitter.googlecode.com/files/${P}.tar.bz2"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug indicate"

RDEPEND=">=dev-libs/glib-2.14:2
	>=x11-libs/gtk+-2.10:2
	>=dev-libs/libgee-0.5.0
	x11-libs/libnotify
	net-libs/libsoup:2.4
	dev-libs/libxml2:2
	>=net-libs/webkit-gtk-1.1
	dev-libs/libunique
	app-text/gtkspell
	indicate? ( dev-libs/libindicate )"
DEPEND="${RDEPEND}
	>=dev-lang/vala-0.7.9
	dev-util/pkgconfig
	sys-devel/gettext
	dev-util/intltool"

# TODO:
# write a patch (for CMakeLists.txt) to not ignore LINGUAS

DOCS="AUTHORS README"

src_configure() {
	local myconf=""
	use debug && myconf="--debug"

	if ! use indicate ; then
		# sabotage the detection since no configure option
		sed -i \
			-e 's|indicate|indicate-false|' \
			wscript || die "sed failed"
	fi

	CCFLAGS="${CFLAGS}" LINKFLAGS="${LDFLAGS}" \
	./waf --prefix=/usr \
		configure ${myconf} || die "./waf configure failed"
}

src_compile() {
	local myjobs=$(sed -n -e 's,.*\(-j[[:digit:]]\+\).*,\1,p' <<< ${MAKEOPTS})
	./waf ${myjobs} build || die "./waf configure failed"
}

src_install() {
	./waf \
		--destdir="${D}" \
		install || die "./waf install failed"

	rm -rf "${D}/usr/share/doc"
	dodoc ${DOCS}
}