[gentoo-commits] gentoo-x86 commit in net-mail/mailutils: mailutils-2.2.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         10/09/10 00:06:56

  Modified:             ChangeLog
  Added:                mailutils-2.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2_rc78/cvs/Linux i686)

Revision  Changes    Path
1.44                 net-mail/mailutils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/mailutils/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/mailutils/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/mailutils/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/mailutils/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	17 Jun 2010 20:54:47 -0000	1.43
+++ ChangeLog	10 Sep 2010 00:06:56 -0000	1.44
@@ -1,6 +1,11 @@
 # ChangeLog for net-mail/mailutils
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/mailutils/ChangeLog,v 1.43 2010/06/17 20:54:47 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/mailutils/ChangeLog,v 1.44 2010/09/10 00:06:56 jer Exp $
+
+*mailutils-2.2 (10 Sep 2010)
+
+  10 Sep 2010; Jeroen Roovers <jer@g.o> +mailutils-2.2.ebuild:
+  Version bump.
 
   17 Jun 2010; Patrick Lauer <patrick@g.o> mailutils-0.6-r3.ebuild,
   mailutils-1.2.ebuild, mailutils-2.1.ebuild:



1.1                  net-mail/mailutils/mailutils-2.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/mailutils/mailutils-2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/mailutils/mailutils-2.2.ebuild?rev=1.1&content-type=text/plain

Index: mailutils-2.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/mailutils/mailutils-2.2.ebuild,v 1.1 2010/09/10 00:06:56 jer Exp $

EAPI="2"

inherit eutils flag-o-matic python

DESCRIPTION="A useful collection of mail servers, clients, and filters."
HOMEPAGE="http://www.gnu.org/software/mailutils/mailutils.html"
SRC_URI="http://ftp.gnu.org/gnu/mailutils/${P}.tar.bz2"
LICENSE="GPL-2 LGPL-2.1"
SLOT="0"

KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="bidi gdbm guile ldap mysql nls pam postgres python test tokyocabinet"
PROVIDE="virtual/mailx"

RDEPEND="!virtual/mailx
	!mail-client/nmh
	!mail-filter/libsieve
	bidi? ( dev-libs/fribidi )
	guile? ( dev-scheme/guile )
	gdbm? ( sys-libs/gdbm )
	ldap? ( net-nds/openldap )
	mysql? ( virtual/mysql )
	nls? ( sys-devel/gettext )
	postgres? ( dev-db/postgresql-base )
	tokyocabinet? ( dev-db/tokyocabinet )
	virtual/mta"

DEPEND="${RDEPEND}
	test? ( dev-util/dejagnu )"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.1-python.patch
}

src_configure() {
	# TODO: Fix this breakage, starting in examples/cpp/
	append-ldflags $(no-as-needed)

	local myconf="--localstatedir=/var --sharedstatedir=/var"
	myconf="${myconf} --enable-mh"

	# We need sendmail or compiling will fail
	myconf="${myconf} --enable-sendmail"

	econf ${myconf} \
		$(use_with bidi fribidi) \
		$(use_with gdbm) \
		$(use_with guile) \
		$(use_with ldap) \
		$(use_with mysql) \
		$(use_enable nls) \
		$(use_enable pam) \
		$(use_with postgres) \
		$(use_with python) \
		$(use_with tokyocabinet) \
		|| die "configure failed"
}

src_install() {
	emake DESTDIR="${D}" install || die
	# mail.rc stolen from mailx, resolve bug #37302.
	insinto /etc
	doins "${FILESDIR}/mail.rc"
}

pkg_postinst() {
	python_mod_optimize "$(python_get_libdir)/site-packages/mailutils"
}