1 |
floppym 13/07/28 17:27:18 |
2 |
|
3 |
Modified: grub-9999.ebuild ChangeLog |
4 |
Added: grub-2.00_p4946.ebuild |
5 |
Log: |
6 |
Add new snapshot for bug 468136. |
7 |
|
8 |
(Portage version: 2.2.0_alpha190/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4) |
9 |
|
10 |
Revision Changes Path |
11 |
1.97 sys-boot/grub/grub-9999.ebuild |
12 |
|
13 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-9999.ebuild?rev=1.97&view=markup |
14 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-9999.ebuild?rev=1.97&content-type=text/plain |
15 |
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-9999.ebuild?r1=1.96&r2=1.97 |
16 |
|
17 |
Index: grub-9999.ebuild |
18 |
=================================================================== |
19 |
RCS file: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999.ebuild,v |
20 |
retrieving revision 1.96 |
21 |
retrieving revision 1.97 |
22 |
diff -u -r1.96 -r1.97 |
23 |
--- grub-9999.ebuild 21 Jul 2013 19:22:48 -0000 1.96 |
24 |
+++ grub-9999.ebuild 28 Jul 2013 17:27:18 -0000 1.97 |
25 |
@@ -1,9 +1,12 @@ |
26 |
# Copyright 1999-2013 Gentoo Foundation |
27 |
# Distributed under the terms of the GNU General Public License v2 |
28 |
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999.ebuild,v 1.96 2013/07/21 19:22:48 floppym Exp $ |
29 |
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999.ebuild,v 1.97 2013/07/28 17:27:18 floppym Exp $ |
30 |
|
31 |
EAPI=5 |
32 |
-AUTOTOOLS_AUTO_DEPEND=yes |
33 |
+ |
34 |
+if [[ ${PV} == 9999 ]]; then |
35 |
+ AUTOTOOLS_AUTORECONF=1 |
36 |
+fi |
37 |
|
38 |
inherit autotools-utils bash-completion-r1 eutils flag-o-matic multibuild pax-utils toolchain-funcs |
39 |
|
40 |
@@ -13,24 +16,12 @@ |
41 |
SRC_URI="mirror://gnu-alpha/${PN}/${MY_P}.tar.xz" |
42 |
else |
43 |
SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.xz |
44 |
- mirror://gentoo/${MY_P}.tar.xz" |
45 |
+ mirror://gentoo/${MY_P}.tar.xz |
46 |
+ http://dev.gentoo.org/~floppym/dist/${MY_P}.tar.xz" |
47 |
fi |
48 |
KEYWORDS="~amd64 ~x86" |
49 |
S=${WORKDIR}/${MY_P} |
50 |
- PATCHES=( |
51 |
- "${FILESDIR}/${P}-parallel-make.patch" #424231 |
52 |
- "${FILESDIR}/${P}-no-gets.patch" #424703 |
53 |
- "${FILESDIR}/${P}-config-quoting.patch" #426364 |
54 |
- "${FILESDIR}/${P}-tftp-endian.patch" # 438612 |
55 |
- "${FILESDIR}/${P}-hardcoded-awk.patch" #424137 |
56 |
- "${FILESDIR}/${P}-freebsd.patch" #442050 |
57 |
- "${FILESDIR}/${P}-compression.patch" #424527 |
58 |
- "${FILESDIR}/${P}-zfs-feature-flag-support-r1.patch" #455358 |
59 |
- "${FILESDIR}/${P}-20_linux_xen.patch" #463992 |
60 |
- "${FILESDIR}/${P}-dmraid.patch" #430748 |
61 |
- "${FILESDIR}/${P}-texinfo.patch" |
62 |
- "${FILESDIR}/${P}-os-prober-efi-system.patch" #477314 |
63 |
- ) |
64 |
+ PATCHES=() |
65 |
else |
66 |
inherit bzr |
67 |
EBZR_REPO_URI="http://bzr.savannah.gnu.org/r/grub/trunk/grub/" |
68 |
@@ -148,9 +139,11 @@ |
69 |
sed -i -e 's/^\* GRUB:/* GRUB2:/' -e 's/(grub)/(grub2)/' docs/grub.texi || die |
70 |
fi |
71 |
epatch_user |
72 |
- bash autogen.sh || die |
73 |
- autopoint() { return 0; } |
74 |
- eautoreconf |
75 |
+ if [[ -n ${AUTOTOOLS_AUTORECONF} ]]; then |
76 |
+ bash autogen.sh || die |
77 |
+ autopoint() { return 0; } |
78 |
+ eautoreconf |
79 |
+ fi |
80 |
} |
81 |
|
82 |
grub_configure() { |
83 |
|
84 |
|
85 |
|
86 |
1.268 sys-boot/grub/ChangeLog |
87 |
|
88 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?rev=1.268&view=markup |
89 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?rev=1.268&content-type=text/plain |
90 |
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?r1=1.267&r2=1.268 |
91 |
|
92 |
Index: ChangeLog |
93 |
=================================================================== |
94 |
RCS file: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v |
95 |
retrieving revision 1.267 |
96 |
retrieving revision 1.268 |
97 |
diff -u -r1.267 -r1.268 |
98 |
--- ChangeLog 21 Jul 2013 19:22:48 -0000 1.267 |
99 |
+++ ChangeLog 28 Jul 2013 17:27:18 -0000 1.268 |
100 |
@@ -1,6 +1,12 @@ |
101 |
# ChangeLog for sys-boot/grub |
102 |
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2 |
103 |
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.267 2013/07/21 19:22:48 floppym Exp $ |
104 |
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.268 2013/07/28 17:27:18 floppym Exp $ |
105 |
+ |
106 |
+*grub-2.00_p4946 (28 Jul 2013) |
107 |
+ |
108 |
+ 28 Jul 2013; Mike Gilbert <floppym@g.o> +grub-2.00_p4946.ebuild, |
109 |
+ grub-9999.ebuild: |
110 |
+ Add new snapshot for bug 468136. |
111 |
|
112 |
21 Jul 2013; Mike Gilbert <floppym@g.o> grub-2.00-r4.ebuild, |
113 |
grub-9999.ebuild: |
114 |
|
115 |
|
116 |
|
117 |
1.1 sys-boot/grub/grub-2.00_p4946.ebuild |
118 |
|
119 |
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.00_p4946.ebuild?rev=1.1&view=markup |
120 |
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.00_p4946.ebuild?rev=1.1&content-type=text/plain |
121 |
|
122 |
Index: grub-2.00_p4946.ebuild |
123 |
=================================================================== |
124 |
# Copyright 1999-2013 Gentoo Foundation |
125 |
# Distributed under the terms of the GNU General Public License v2 |
126 |
# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-2.00_p4946.ebuild,v 1.1 2013/07/28 17:27:18 floppym Exp $ |
127 |
|
128 |
EAPI=5 |
129 |
|
130 |
if [[ ${PV} == 9999 ]]; then |
131 |
AUTOTOOLS_AUTORECONF=1 |
132 |
fi |
133 |
|
134 |
inherit autotools-utils bash-completion-r1 eutils flag-o-matic multibuild pax-utils toolchain-funcs |
135 |
|
136 |
if [[ ${PV} != 9999 ]]; then |
137 |
MY_P=${P/_/\~} |
138 |
if [[ ${PV} == *_alpha* || ${PV} == *_beta* || ${PV} == *_rc* ]]; then |
139 |
SRC_URI="mirror://gnu-alpha/${PN}/${MY_P}.tar.xz" |
140 |
else |
141 |
SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.xz |
142 |
mirror://gentoo/${MY_P}.tar.xz |
143 |
http://dev.gentoo.org/~floppym/dist/${MY_P}.tar.xz" |
144 |
fi |
145 |
KEYWORDS="~amd64 ~x86" |
146 |
S=${WORKDIR}/${MY_P} |
147 |
PATCHES=() |
148 |
else |
149 |
inherit bzr |
150 |
EBZR_REPO_URI="http://bzr.savannah.gnu.org/r/grub/trunk/grub/" |
151 |
fi |
152 |
|
153 |
DESCRIPTION="GNU GRUB boot loader" |
154 |
HOMEPAGE="http://www.gnu.org/software/grub/" |
155 |
|
156 |
LICENSE="GPL-3" |
157 |
SLOT="2" |
158 |
IUSE="custom-cflags debug device-mapper doc efiemu mount +multislot nls static sdl test truetype libzfs" |
159 |
|
160 |
GRUB_ALL_PLATFORMS=( |
161 |
# everywhere: |
162 |
emu |
163 |
# mips only: |
164 |
qemu-mips yeeloong |
165 |
# amd64, x86, ppc, ppc64: |
166 |
ieee1275 |
167 |
# amd64, x86: |
168 |
coreboot multiboot efi-32 pc qemu |
169 |
# amd64, ia64: |
170 |
efi-64 |
171 |
) |
172 |
IUSE+=" ${GRUB_ALL_PLATFORMS[@]/#/grub_platforms_}" |
173 |
|
174 |
REQUIRED_USE="grub_platforms_qemu? ( truetype ) |
175 |
grub_platforms_yeeloong? ( truetype )" |
176 |
|
177 |
# os-prober: Used on runtime to detect other OSes |
178 |
# xorriso (dev-libs/libisoburn): Used on runtime for mkrescue |
179 |
RDEPEND=" |
180 |
app-arch/xz-utils |
181 |
>=sys-libs/ncurses-5.2-r5 |
182 |
debug? ( |
183 |
sdl? ( media-libs/libsdl ) |
184 |
) |
185 |
device-mapper? ( >=sys-fs/lvm2-2.02.45 ) |
186 |
libzfs? ( sys-fs/zfs ) |
187 |
mount? ( sys-fs/fuse ) |
188 |
truetype? ( |
189 |
media-libs/freetype |
190 |
media-fonts/dejavu |
191 |
>=media-fonts/unifont-5 |
192 |
) |
193 |
ppc? ( sys-apps/ibm-powerpc-utils sys-apps/powerpc-utils ) |
194 |
ppc64? ( sys-apps/ibm-powerpc-utils sys-apps/powerpc-utils ) |
195 |
" |
196 |
DEPEND="${RDEPEND} |
197 |
app-misc/pax-utils |
198 |
>=dev-lang/python-2.5.2 |
199 |
sys-devel/flex |
200 |
sys-devel/bison |
201 |
sys-apps/help2man |
202 |
sys-apps/texinfo |
203 |
>=sys-devel/autogen-5.10 |
204 |
static? ( |
205 |
truetype? ( |
206 |
app-arch/bzip2[static-libs(+)] |
207 |
media-libs/freetype[static-libs(+)] |
208 |
sys-libs/zlib[static-libs(+)] |
209 |
) |
210 |
) |
211 |
test? ( |
212 |
dev-libs/libisoburn |
213 |
app-emulation/qemu |
214 |
) |
215 |
" |
216 |
RDEPEND+=" |
217 |
kernel_linux? ( |
218 |
grub_platforms_efi-32? ( sys-boot/efibootmgr ) |
219 |
grub_platforms_efi-64? ( sys-boot/efibootmgr ) |
220 |
) |
221 |
!multislot? ( !sys-boot/grub:0 ) |
222 |
" |
223 |
|
224 |
STRIP_MASK="*/grub/*/*.{mod,img}" |
225 |
RESTRICT="test" |
226 |
|
227 |
QA_EXECSTACK=" |
228 |
usr/bin/grub* |
229 |
usr/sbin/grub* |
230 |
usr/lib*/grub/*/*.mod |
231 |
usr/lib*/grub/*/*.module |
232 |
usr/lib*/grub/*/kernel.exec |
233 |
usr/lib*/grub/*/kernel.img |
234 |
" |
235 |
|
236 |
QA_WX_LOAD=" |
237 |
usr/lib*/grub/*/kernel.exec |
238 |
usr/lib*/grub/*/kernel.img |
239 |
usr/lib*/grub/*/*.image |
240 |
" |
241 |
|
242 |
QA_PRESTRIPPED=" |
243 |
usr/lib.*/grub/.*/kernel.img |
244 |
" |
245 |
|
246 |
pkg_pretend() { |
247 |
if [[ ${MERGE_TYPE} != binary ]]; then |
248 |
# Bug 439082 |
249 |
if $(tc-getLD) --version | grep -q "GNU gold"; then |
250 |
eerror "GRUB does not function correctly when built with the gold linker." |
251 |
eerror "Please select the bfd linker with binutils-config." |
252 |
die "GNU gold detected" |
253 |
fi |
254 |
fi |
255 |
} |
256 |
|
257 |
src_prepare() { |
258 |
[[ ${PATCHES} ]] && epatch "${PATCHES[@]}" |
259 |
sed -i -e /autoreconf/d autogen.sh || die |
260 |
if use multislot; then |
261 |
# fix texinfo file name, bug 416035 |
262 |
sed -i -e 's/^\* GRUB:/* GRUB2:/' -e 's/(grub)/(grub2)/' docs/grub.texi || die |
263 |
fi |
264 |
epatch_user |
265 |
if [[ -n ${AUTOTOOLS_AUTORECONF} ]]; then |
266 |
bash autogen.sh || die |
267 |
autopoint() { return 0; } |
268 |
eautoreconf |
269 |
fi |
270 |
} |
271 |
|
272 |
grub_configure() { |
273 |
local platform |
274 |
|
275 |
case ${MULTIBUILD_VARIANT} in |
276 |
efi-32) |
277 |
platform=efi |
278 |
if [[ ${CTARGET:-${CHOST}} == x86_64* ]]; then |
279 |
local CTARGET=${CTARGET:-i386} |
280 |
fi ;; |
281 |
efi-64) |
282 |
platform=efi |
283 |
if [[ ${CTARGET:-${CHOST}} == i?86* ]]; then |
284 |
local CTARGET=${CTARGET:-x86_64} |
285 |
local TARGET_CFLAGS="-Os -march=x86-64 ${TARGET_CFLAGS}" |
286 |
local TARGET_CPPFLAGS="-march=x86-64 ${TARGET_CPPFLAGS}" |
287 |
export TARGET_CFLAGS TARGET_CPPFLAGS |
288 |
fi ;; |
289 |
guessed) ;; |
290 |
*) platform=${MULTIBUILD_VARIANT} ;; |
291 |
esac |
292 |
|
293 |
local myeconfargs=( |
294 |
--disable-werror |
295 |
--program-prefix= |
296 |
--libdir="${EPREFIX}"/usr/lib |
297 |
--htmldir="${EPREFIX}"/usr/share/doc/${PF}/html |
298 |
$(use_enable debug mm-debug) |
299 |
$(use_enable debug grub-emu-usb) |
300 |
$(use_enable mount grub-mount) |
301 |
$(use_enable nls) |
302 |
$(use_enable truetype grub-mkfont) |
303 |
$(use_enable libzfs) |
304 |
$(use sdl && use_enable debug grub-emu-sdl) |
305 |
${platform:+--with-platform=}${platform} |
306 |
|
307 |
# Let configure detect this where supported |
308 |
$(usex efiemu '' --disable-efiemu) |
309 |
) |
310 |
|
311 |
if use multislot; then |
312 |
myeconfargs+=( |
313 |
--program-transform-name="s,grub,grub2," |
314 |
--with-grubdir=grub2 |
315 |
) |
316 |
fi |
317 |
|
318 |
autotools-utils_src_configure |
319 |
} |
320 |
|
321 |
src_configure() { |
322 |
use custom-cflags || unset CCASFLAGS CFLAGS CPPFLAGS LDFLAGS |
323 |
use static && append-ldflags -static |
324 |
|
325 |
tc-export CC NM OBJCOPY STRIP |
326 |
export TARGET_CC=${TARGET_CC:-${CC}} |
327 |
|
328 |
# Portage will take care of cleaning up GRUB_PLATFORMS |
329 |
MULTIBUILD_VARIANTS=( ${GRUB_PLATFORMS:-guessed} ) |
330 |
multibuild_parallel_foreach_variant grub_configure |
331 |
} |
332 |
|
333 |
src_compile() { |
334 |
# Sandbox bug 404013. |
335 |
use libzfs && addpredict /etc/dfs:/dev/zfs |
336 |
|
337 |
multibuild_foreach_variant autotools-utils_src_compile |
338 |
|
339 |
use doc && multibuild_for_best_variant \ |
340 |
autotools-utils_src_compile -C docs html |
341 |
} |
342 |
|
343 |
src_test() { |
344 |
# The qemu dependency is a bit complex. |
345 |
# You will need to adjust QEMU_SOFTMMU_TARGETS to match the cpu/platform. |
346 |
multibuild_foreach_variant autotools-utils_src_test |
347 |
} |
348 |
|
349 |
src_install() { |
350 |
multibuild_foreach_variant autotools-utils_src_install \ |
351 |
bashcompletiondir="$(get_bashcompdir)" |
352 |
|
353 |
use doc && multibuild_for_best_variant run_in_build_dir \ |
354 |
emake -C docs DESTDIR="${D}" install-html |
355 |
|
356 |
if use multislot; then |
357 |
mv "${ED%/}"/usr/share/info/grub{,2}.info || die |
358 |
fi |
359 |
|
360 |
insinto /etc/default |
361 |
newins "${FILESDIR}"/grub.default-2 grub |
362 |
|
363 |
cd "${ED}" || die |
364 |
pax-mark mpes $(scanelf -BF %F usr/{bin,sbin}) |
365 |
} |
366 |
|
367 |
pkg_postinst() { |
368 |
elog "For information on how to configure grub-2 please refer to the guide:" |
369 |
elog " http://wiki.gentoo.org/wiki/GRUB2_Quick_Start" |
370 |
if [[ -z ${REPLACING_VERSIONS} ]]; then |
371 |
if ! has_version sys-boot/os-prober; then |
372 |
elog "Install sys-boot/os-prober to enable detection of other operating systems using grub2-mkconfig." |
373 |
fi |
374 |
if ! has_version dev-libs/libisoburn; then |
375 |
elog "Install dev-libs/libisoburn to enable creation of rescue media using grub2-mkrescue." |
376 |
fi |
377 |
fi |
378 |
} |