[gentoo-commits] repo/gentoo:master commit in: dev-python/ini2toml/

[Michał Górny]

commit:     2ac9dae0460abbf256b54d00aefc52d0f56240db
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 25 10:43:33 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Mar 31 23:02:55 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2ac9dae0

dev-python/ini2toml: New dep for setuptools, v0.10

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/ini2toml/Manifest             |  1 +
 dev-python/ini2toml/ini2toml-0.10.ebuild | 63 ++++++++++++++++++++++++++++++++
 dev-python/ini2toml/metadata.xml         | 12 ++++++
 3 files changed, 76 insertions(+)

diff --git a/dev-python/ini2toml/Manifest b/dev-python/ini2toml/Manifest
new file mode 100644
index 000000000000..9fa4a3fcb1f6
--- /dev/null
+++ b/dev-python/ini2toml/Manifest
@@ -0,0 +1 @@
+DIST ini2toml-0.10.gh.tar.gz 93535 BLAKE2B 8d8a5b31c53b9194e578b473dfd562b1b569d701b36b267ec4f59ea75ec03abd6e1df5541327b9414a2f1c04b1cb41ec57c6f900007f69a3c51a172143d2eacd SHA512 3d88f97c50a13fe3878e3fa35d70c9051874bec99d278411dcc7098d86898deb0e490be26f293e9a304d4c9a2842274e68126a2d20dac77b526161fde682dd75

diff --git a/dev-python/ini2toml/ini2toml-0.10.ebuild b/dev-python/ini2toml/ini2toml-0.10.ebuild
new file mode 100644
index 000000000000..4b26ed461480
--- /dev/null
+++ b/dev-python/ini2toml/ini2toml-0.10.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Automatically conversion of .ini/.cfg files to TOML equivalents"
+HOMEPAGE="
+	https://pypi.org/project/ini2toml/
+	https://github.com/abravalheri/ini2toml/
+"
+SRC_URI="
+	https://github.com/abravalheri/ini2toml/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/packaging-20.7[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-0.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/tomli[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+EPYTEST_DESELECT=(
+	# pyproject_fmt is not packaged
+	tests/test_cli.py::test_auto_formatting
+
+	# fails on whitespace/comments/formatting
+	tests/test_translator.py::test_simple_example
+	tests/test_translator.py::test_parser_opts
+	tests/plugins/test_setuptools_pep621.py::test_move_entry_points_and_apply_value_processing
+	tests/plugins/test_setuptools_pep621.py::test_split_subtables
+	tests/plugins/test_setuptools_pep621.py::test_entrypoints_and_split_subtables
+	tests/plugins/test_setuptools_pep621.py::test_handle_dynamic
+)
+
+EPYTEST_IGNORE=(
+	# configupdater is not packaged
+	tests/test_examples.py
+	tests/test_transformations.py
+	tests/drivers/test_configupdater.py
+)
+
+src_prepare() {
+	sed -i -e 's:--cov ini2toml --cov-report term-missing::' setup.cfg || die
+	distutils-r1_src_prepare
+}

diff --git a/dev-python/ini2toml/metadata.xml b/dev-python/ini2toml/metadata.xml
new file mode 100644
index 000000000000..23719e79daa5
--- /dev/null
+++ b/dev-python/ini2toml/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>python@g.o</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">abravalheri/ini2toml</remote-id>
+		<remote-id type="pypi">ini2toml</remote-id>
+	</upstream>
+</pkgmetadata>