[gentoo-commits] repo/gentoo:master commit in: dev-libs/xmlsec/

[Alon Bar-Lev]

commit:     1f8cd8ab1af5102621085ba3abbf2b4a8b752d04
Author:     Alon Bar-Lev <alonbl <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 25 21:55:28 2017 +0000
Commit:     Alon Bar-Lev <alonbl <AT> gentoo <DOT> org>
CommitDate: Sun Jun 25 21:55:45 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f8cd8ab

dev-libs/xmlsec: version bump

Bug: 622714

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 dev-libs/xmlsec/Manifest             |  1 +
 dev-libs/xmlsec/xmlsec-1.2.24.ebuild | 62 ++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-libs/xmlsec/Manifest b/dev-libs/xmlsec/Manifest
index 2fdd4904b82..d08cb985f78 100644
--- a/dev-libs/xmlsec/Manifest
+++ b/dev-libs/xmlsec/Manifest
@@ -1 +1,2 @@
 DIST xmlsec1-1.2.23.tar.gz 1794694 SHA256 41d463d16c9894cd3317098d027c038039c6d896b9cbb9bad9c4e29959e10e9f SHA512 20b0c0ba517c764fcd32165254ae6dcdda8fb72ca3279dbfcf42d899e91d380b78d9be3b1c3d32910eaad5544a4fc51218e32579b10e6b6639338a7bd8b1ddc5 WHIRLPOOL f4d783d01346860ed2cf1d15e692e70e65034bee120c853cf7692358799a6e3339a1bb022f4d72ee4364adddd43766aa01770070a0081d1adcc588e4f84786f9
+DIST xmlsec1-1.2.24.tar.gz 1835762 SHA256 99a8643f118bb1261a72162f83e2deba0f4f690893b4b90e1be4f708e8d481cc SHA512 a01feb9af8f85e77f2c5d2d7f596fba3ef58bc593cb9a7c3e883deb38f8292598ba5aa09fa59897fe303f10336a10b0bb0f27171f2b6e6251e694f37f0b9b7d4 WHIRLPOOL d6fbaf232c10a589a2dbe608ad1a29ebc7b80b535e1036a66b75fbdf3d7154e7297b901b035fdd31b992684b4006050a6421dcd9a9f7c1ea2e4b11d83544bf73

diff --git a/dev-libs/xmlsec/xmlsec-1.2.24.ebuild b/dev-libs/xmlsec/xmlsec-1.2.24.ebuild
new file mode 100644
index 00000000000..ce5133a74ab
--- /dev/null
+++ b/dev-libs/xmlsec/xmlsec-1.2.24.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools ltprune
+
+DESCRIPTION="Command line tool for signing, verifying, encrypting and decrypting XML"
+HOMEPAGE="http://www.aleksey.com/xmlsec"
+SRC_URI="http://www.aleksey.com/xmlsec/download/${PN}1-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc gcrypt gnutls nss +openssl static-libs"
+REQUIRED_USE="|| ( gcrypt gnutls nss openssl )
+	gnutls? ( gcrypt )"
+
+RDEPEND=">=dev-libs/libxml2-2.7.4
+	>=dev-libs/libxslt-1.0.20
+	gcrypt? ( >=dev-libs/libgcrypt-1.4.0:0 )
+	gnutls? ( >=net-libs/gnutls-2.8.0 )
+	nss? (
+		>=dev-libs/nspr-4.4.1
+		>=dev-libs/nss-3.9
+	)
+	openssl? ( >=dev-libs/openssl-1.0.0:* )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${PN}1-${PV}
+
+src_prepare() {
+	default
+	# conditionally install extra documentation
+	if ! use doc ; then
+		sed -i '/^SUBDIRS/s/docs//' Makefile.am || die
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	econf \
+		--enable-pkgconfig \
+		--with-html-dir=/usr/share/doc/${PF}/html \
+		$(use_enable static-libs static) \
+		$(use_with gcrypt gcrypt "") \
+		$(use_with gnutls gnutls "") \
+		$(use_with nss nspr "") \
+		$(use_with nss nss "") \
+		$(use_with openssl openssl "") \
+		$(use_enable openssl aes)
+}
+
+src_test() {
+	emake TMPFOLDER="${T}" check
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}