[gentoo-commits] gentoo-x86 commit in dev-libs/libebml: ChangeLog libebml-1.2.2.ebuild

[Tim Harder (radhermit)]

radhermit    11/09/26 00:15:31

  Modified:             ChangeLog
  Added:                libebml-1.2.2.ebuild
  Log:
  Version bump. Add static-libs use flag (bug #381661), add debug use flag, update to EAPI 4.
  
  (Portage version: 2.2.0_alpha59/cvs/Linux x86_64)

Revision  Changes    Path
1.110                dev-libs/libebml/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libebml/ChangeLog?rev=1.110&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libebml/ChangeLog?rev=1.110&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libebml/ChangeLog?r1=1.109&r2=1.110

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libebml/ChangeLog,v
retrieving revision 1.109
retrieving revision 1.110
diff -u -r1.109 -r1.110
--- ChangeLog	24 Sep 2011 16:53:21 -0000	1.109
+++ ChangeLog	26 Sep 2011 00:15:31 -0000	1.110
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libebml
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libebml/ChangeLog,v 1.109 2011/09/24 16:53:21 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libebml/ChangeLog,v 1.110 2011/09/26 00:15:31 radhermit Exp $
+
+*libebml-1.2.2 (26 Sep 2011)
+
+  26 Sep 2011; Tim Harder <radhermit@g.o> +libebml-1.2.2.ebuild:
+  Version bump. Add static-libs use flag (bug #381661), add debug use flag,
+  update to EAPI 4.
 
   24 Sep 2011; Raúl Porcel <armin76@g.o> libebml-1.2.1.ebuild:
   alpha/ia64/sparc stable wrt #376395



1.1                  dev-libs/libebml/libebml-1.2.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libebml/libebml-1.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libebml/libebml-1.2.2.ebuild?rev=1.1&content-type=text/plain

Index: libebml-1.2.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libebml/libebml-1.2.2.ebuild,v 1.1 2011/09/26 00:15:31 radhermit Exp $

EAPI=4

inherit eutils multilib toolchain-funcs

DESCRIPTION="Extensible binary format library (kinda like XML)"
HOMEPAGE="http://www.matroska.org/"
SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="debug static-libs"

S="${WORKDIR}/${P}/make/linux"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.2.0-makefile-fixup.patch

	sed -i -e "s:\(DEBUGFLAGS=\)-g :\1:" Makefile || die
}

src_compile() {
	local targets
	if [[ ${CHOST} != *-darwin* ]] ; then
		targets="sharedlib"
	else
		targets="macholib"
	fi
	use static-libs && targets+=" staticlib"

	# keep the prefix in here to make sure the binary is built with a correct
	# install_name on Darwin
	emake \
		prefix="${EPREFIX}/usr" \
		AR="$(tc-getAR)" \
		CC="$(tc-getCC)" \
		CXX="$(tc-getCXX)" \
		$(use debug && echo DEBUG=yes || echo DEBUG=no) \
		${targets}
}

src_install() {
	local targets="install_headers"
	if [[ ${CHOST} != *-darwin* ]] ; then
		targets+=" install_sharedlib"
	else
		targets+=" install_macholib"
	fi
	use static-libs && targets+=" install_staticlib"

	emake \
		DESTDIR="${D}" \
		prefix="${EPREFIX}/usr" \
		libdir="${EPREFIX}/usr/$(get_libdir)" \
		${targets}

	dodoc "${WORKDIR}/${P}/ChangeLog"
}