[gentoo-commits] gentoo-x86 commit in net-misc/radvd: radvd-2.3.ebuild ChangeLog

[Michael Weber (xmw)]

xmw         14/07/30 22:12:53

  Modified:             ChangeLog
  Added:                radvd-2.3.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

Revision  Changes    Path
1.123                net-misc/radvd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/radvd/ChangeLog?rev=1.123&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/radvd/ChangeLog?rev=1.123&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/radvd/ChangeLog?r1=1.122&r2=1.123

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/radvd/ChangeLog,v
retrieving revision 1.122
retrieving revision 1.123
diff -u -r1.122 -r1.123
--- ChangeLog	30 Jul 2014 22:07:44 -0000	1.122
+++ ChangeLog	30 Jul 2014 22:12:53 -0000	1.123
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/radvd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/ChangeLog,v 1.122 2014/07/30 22:07:44 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/ChangeLog,v 1.123 2014/07/30 22:12:53 xmw Exp $
+
+*radvd-2.3 (30 Jul 2014)
+
+  30 Jul 2014; Michael Weber <xmw@g.o> +radvd-2.3.ebuild:
+  Version bump
 
 *radvd-1.15 (30 Jul 2014)
 



1.1                  net-misc/radvd/radvd-2.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/radvd/radvd-2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/radvd/radvd-2.3.ebuild?rev=1.1&content-type=text/plain

Index: radvd-2.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/radvd-2.3.ebuild,v 1.1 2014/07/30 22:12:53 xmw Exp $

EAPI=4

inherit systemd user eutils

DESCRIPTION="Linux IPv6 Router Advertisement Daemon"
HOMEPAGE="http://v6web.litech.org/radvd/"
SRC_URI="http://v6web.litech.org/radvd/dist/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE="kernel_FreeBSD selinux"

RDEPEND="dev-libs/libdaemon
	selinux? ( sec-policy/selinux-radvd )"
DEPEND="${RDEPEND}
	dev-libs/check
	sys-devel/bison
	sys-devel/flex
	virtual/pkgconfig"

DOCS=( CHANGES README TODO radvd.conf.example )

pkg_setup() {
	enewgroup radvd
	enewuser radvd -1 -1 /dev/null radvd

	# force ownership of radvd user and group (bug #19647)
	[[ -d ${ROOT}/var/run/radvd ]] && chown radvd:radvd "${ROOT}"/var/run/radvd
}

src_configure() {
	econf --with-pidfile=/var/run/radvd/radvd.pid \
		--disable-silent-rules
}

src_install() {
	default

	dohtml INTRO.html

	newinitd "${FILESDIR}"/${PN}-1.9.1.init ${PN}
	newconfd "${FILESDIR}"/${PN}.conf ${PN}

	systemd_dounit "${FILESDIR}"/${PN}.service

	if use kernel_FreeBSD ; then
		sed -i -e \
			's/^SYSCTL_FORWARD=.*$/SYSCTL_FORWARD=net.inet6.ip6.forwarding/g' \
			"${D}"/etc/init.d/${PN} || die
	fi
}

pkg_postinst() {
	einfo
	elog "Please create a configuratoion ${ROOT}etc/radvd.conf."
	elog "See ${ROOT}usr/share/doc/${PF} for an example."
	einfo
	elog "grsecurity users should allow a specific group to read /proc"
	elog "and add the radvd user to that group, otherwise radvd may"
	elog "segfault on startup."
}