[gentoo-commits] gentoo-x86 commit in media-sound/lame: ChangeLog lame-3.99.3.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/11/28 17:53:30

  Modified:             ChangeLog
  Added:                lame-3.99.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha79/cvs/Linux x86_64)

Revision  Changes    Path
1.136                media-sound/lame/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lame/ChangeLog?rev=1.136&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lame/ChangeLog?rev=1.136&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lame/ChangeLog?r1=1.135&r2=1.136

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v
retrieving revision 1.135
retrieving revision 1.136
diff -u -r1.135 -r1.136
--- ChangeLog	16 Nov 2011 17:20:05 -0000	1.135
+++ ChangeLog	28 Nov 2011 17:53:29 -0000	1.136
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/lame
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v 1.135 2011/11/16 17:20:05 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/ChangeLog,v 1.136 2011/11/28 17:53:29 ssuominen Exp $
+
+*lame-3.99.3 (28 Nov 2011)
+
+  28 Nov 2011; Samuli Suominen <ssuominen@g.o> +lame-3.99.3.ebuild:
+  Version bump.
 
   16 Nov 2011; Samuli Suominen <ssuominen@g.o> -lame-3.98.2-r1.ebuild,
   -files/lame-3.98.2-ffmpeg-0.5.patch, -lame-3.99.ebuild:



1.1                  media-sound/lame/lame-3.99.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lame/lame-3.99.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/lame/lame-3.99.3.ebuild?rev=1.1&content-type=text/plain

Index: lame-3.99.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/lame/lame-3.99.3.ebuild,v 1.1 2011/11/28 17:53:30 ssuominen Exp $

EAPI=4
inherit autotools eutils

DESCRIPTION="LAME Ain't an MP3 Encoder"
HOMEPAGE="http://lame.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="debug mmx mp3rtp sndfile static-libs"

RDEPEND=">=sys-libs/ncurses-5.2
	sndfile? ( >=media-libs/libsndfile-1.0.2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	mmx? ( dev-lang/nasm )"

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-3.96-ccc.patch \
		"${FILESDIR}"/${PN}-3.98-gtk-path.patch

	mkdir libmp3lame/i386/.libs || die #workaround parallel build with nasm

	sed -i -e '/define sp/s/+/ + /g' libmp3lame/i386/nasm.h || die

	AT_M4DIR=${S} eautoreconf
	epunt_cxx #74498
}

src_configure() {
	local myconf
	use sndfile && myconf="--with-fileio=sndfile"

	econf \
		$(use_enable static-libs static) \
		$(use_enable debug debug norm) \
		$(use_enable mmx nasm) \
		--disable-mp3x \
		$(use_enable mp3rtp) \
		--enable-dynamic-frontends \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" pkghtmldir="${EPREFIX}/usr/share/doc/${PF}/html" install
	dobin misc/mlame

	dodoc API ChangeLog HACKING README STYLEGUIDE TODO USAGE
	dohtml misc/lameGUI.html Dll/LameDLLInterface.htm

	find "${ED}" -name '*.la' -exec rm -f {} +
}