[gentoo-commits] gentoo-x86 commit in net-firewall/conntrack-tools: ChangeLog conntrack-tools-1.4.0.ebuild

[Sergey Popov (pinkbyte)]

pinkbyte    12/10/29 09:45:11

  Modified:             ChangeLog
  Added:                conntrack-tools-1.4.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha141/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.52                 net-firewall/conntrack-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/conntrack-tools/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/conntrack-tools/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/conntrack-tools/ChangeLog?r1=1.51&r2=1.52

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/conntrack-tools/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog	11 Sep 2012 16:20:05 -0000	1.51
+++ ChangeLog	29 Oct 2012 09:45:11 -0000	1.52
@@ -1,6 +1,12 @@
 # ChangeLog for net-firewall/conntrack-tools
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/conntrack-tools/ChangeLog,v 1.51 2012/09/11 16:20:05 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/conntrack-tools/ChangeLog,v 1.52 2012/10/29 09:45:11 pinkbyte Exp $
+
+*conntrack-tools-1.4.0 (29 Oct 2012)
+
+  29 Oct 2012; Sergey Popov <pinkbyte@g.o>
+  +conntrack-tools-1.4.0.ebuild:
+  Version bump
 
   11 Sep 2012; Raúl Porcel <armin76@g.o> conntrack-tools-0.9.14.ebuild,
   conntrack-tools-1.0.0.ebuild, conntrack-tools-1.0.1.ebuild:



1.1                  net-firewall/conntrack-tools/conntrack-tools-1.4.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/conntrack-tools/conntrack-tools-1.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/conntrack-tools/conntrack-tools-1.4.0.ebuild?rev=1.1&content-type=text/plain

Index: conntrack-tools-1.4.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/conntrack-tools/conntrack-tools-1.4.0.ebuild,v 1.1 2012/10/29 09:45:11 pinkbyte Exp $

EAPI="4"

inherit linux-info

DESCRIPTION="Connection tracking userspace tools"
HOMEPAGE="http://conntrack-tools.netfilter.org"
SRC_URI="http://www.netfilter.org/projects/conntrack-tools/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

RDEPEND="
	>=net-libs/libnetfilter_conntrack-1.0.2
	>=net-libs/libnetfilter_cttimeout-1.0.0
	>=net-libs/libnetfilter_cthelper-1.0.0
	>=net-libs/libnetfilter_queue-1.0.2
	>=net-libs/libnfnetlink-1.0.1
	>=net-libs/libmnl-1.0.3"
DEPEND="${RDEPEND}
	doc? ( app-text/xmlto )
	virtual/pkgconfig
	sys-devel/bison
	sys-devel/flex"

pkg_setup() {
	linux-info_pkg_setup

	if kernel_is lt 2 6 18 ; then
		die "${PN} requires at least 2.6.18 kernel version"
	fi

	#netfilter core team has changed some option names with kernel 2.6.20
	if kernel_is lt 2 6 20 ; then
		CONFIG_CHECK="~IP_NF_CONNTRACK_NETLINK"
	else
		CONFIG_CHECK="~NF_CT_NETLINK"
	fi
	CONFIG_CHECK="${CONFIG_CHECK} ~NF_CONNTRACK
		~NETFILTER_NETLINK ~NF_CONNTRACK_EVENTS"

	check_extra_config

	linux_config_exists || \
		linux_chkconfig_present "NF_CONNTRACK_IPV4" || \
		linux_chkconfig_present "NF_CONNTRACK_IPV6" || \
		ewarn "CONFIG_NF_CONNTRACK_IPV4 or CONFIG_NF_CONNTRACK_IPV6 " \
			"are not set when one at least should be."
}

src_compile() {
	default
	use doc && emake -C doc/manual
}

src_install() {
	default

	newinitd "${FILESDIR}/conntrackd.initd-r2" conntrackd
	newconfd "${FILESDIR}/conntrackd.confd-r1" conntrackd

	insinto /etc/conntrackd
	doins doc/stats/conntrackd.conf

	dodoc -r doc/sync doc/stats AUTHORS TODO
	use doc && dohtml doc/manual/${PN}.html
}