[gentoo-commits] gentoo-x86 commit in app-misc/gtypist: ChangeLog gtypist-2.9.5.ebuild

[Jeroen Roovers (jer)]

jer         14/09/04 21:14:10

  Modified:             ChangeLog
  Added:                gtypist-2.9.5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.35                 app-misc/gtypist/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gtypist/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gtypist/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gtypist/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/gtypist/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	13 Jan 2013 14:58:18 -0000	1.34
+++ ChangeLog	4 Sep 2014 21:14:10 -0000	1.35
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/gtypist
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/gtypist/ChangeLog,v 1.34 2013/01/13 14:58:18 ago Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/gtypist/ChangeLog,v 1.35 2014/09/04 21:14:10 jer Exp $
+
+*gtypist-2.9.5 (04 Sep 2014)
+
+  04 Sep 2014; Jeroen Roovers <jer@g.o> +gtypist-2.9.5.ebuild:
+  Version bump.
 
 *gtypist-2.9.2 (13 Jan 2013)
 



1.1                  app-misc/gtypist/gtypist-2.9.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gtypist/gtypist-2.9.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/gtypist/gtypist-2.9.5.ebuild?rev=1.1&content-type=text/plain

Index: gtypist-2.9.5.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/gtypist/gtypist-2.9.5.ebuild,v 1.1 2014/09/04 21:14:10 jer Exp $

EAPI=5
inherit eutils elisp-common

DESCRIPTION="Universal typing tutor"
HOMEPAGE="http://www.gnu.org/software/gtypist/"
SRC_URI="mirror://gnu/gtypist/${P}.tar.xz
	http://colemak.com/pub/learn/colemak.typ"

LICENSE="GPL-2 public-domain"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux"
IUSE="nls emacs xemacs"

DEPEND="
	>=sys-libs/ncurses-5.2
	emacs? ( virtual/emacs )
	xemacs? ( !emacs? ( app-editors/xemacs app-xemacs/fsf-compat ) )
"
RDEPEND="${DEPEND}"

SITEFILE=50${PN}-gentoo.el

src_unpack() {
	unpack ${P}.tar.xz
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.8.3-xemacs-compat.patch
}

src_configure() {
	local lispdir=""
	if use emacs; then
		lispdir="${SITELISP}/${PN}"
		einfo "Configuring to build with GNU Emacs support"
	elif use xemacs; then
		lispdir="${EPREFIX}/usr/lib/xemacs/site-packages/lisp/${PN}"
		einfo "Configuring to build with XEmacs support"
	fi

	econf \
		$(use_enable nls) \
		EMACS=$(usev emacs || usev xemacs || echo no) \
		--with-lispdir="${lispdir}"
}

DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )

src_install() {
	default

	insinto /usr/share/gtypist
	doins "${DISTDIR}"/colemak.typ

	if use emacs; then
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}