[gentoo-commits] repo/gentoo:master commit in: media-gfx/fbida/

[Jeroen Roovers]

commit:     7d64d2b5443d774b5a205f2c96476bbad426850e
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 31 11:07:47 2016 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sun Jul 31 11:11:01 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7d64d2b5

media-gfx/fbida: Add live ebuild.

Package-Manager: portage-2.3.0

 media-gfx/fbida/fbida-9999.ebuild | 126 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 126 insertions(+)

diff --git a/media-gfx/fbida/fbida-9999.ebuild b/media-gfx/fbida/fbida-9999.ebuild
new file mode 100644
index 0000000..abb2322
--- /dev/null
+++ b/media-gfx/fbida/fbida-9999.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils git-r3 toolchain-funcs
+
+DESCRIPTION="Image viewers for the framebuffer console (fbi) and X11 (ida)"
+HOMEPAGE="http://www.kraxel.org/blog/linux/fbida/"
+EGIT_REPO_URI="
+	git://git.kraxel.org/fbida
+"
+SRC_URI="
+	mirror://gentoo/ida.png.bz2
+"
+LICENSE="GPL-2 IJG"
+SLOT="0"
+KEYWORDS=""
+IUSE="curl fbcon +gif lirc pdf +png scanner +tiff X +webp"
+REQUIRED_USE="
+	pdf? ( tiff )
+"
+
+RDEPEND="
+	!media-gfx/fbi
+	>=media-libs/fontconfig-2.2
+	>=media-libs/freetype-2.0
+	media-libs/libexif
+	curl? ( net-misc/curl )
+	gif? ( media-libs/giflib:= )
+	lirc? ( app-misc/lirc )
+	pdf? (
+		media-libs/libepoxy
+		media-libs/mesa
+		x11-libs/cairo[opengl]
+		x11-libs/libdrm
+	)
+	png? ( media-libs/libpng:* )
+	scanner? ( media-gfx/sane-backends )
+	tiff? ( media-libs/tiff:* )
+	virtual/jpeg:*
+	virtual/ttf-fonts
+	webp? ( media-libs/libwebp )
+	X? (
+		>=x11-libs/motif-2.3:0
+		x11-libs/libX11
+		x11-libs/libXpm
+		x11-libs/libXt
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+	X? ( x11-proto/xextproto x11-proto/xproto )
+"
+
+src_unpack() {
+	unpack ${A}
+	git-r3_src_unpack
+}
+
+src_prepare() {
+	eapply \
+		"${FILESDIR}"/ida-desktop.patch \
+		"${FILESDIR}"/${PN}-2.10-giflib-4.2.patch \
+		"${FILESDIR}"/${PN}-2.10-fprintf-format.patch
+
+	eapply_user
+
+	tc-export CC CPP
+
+	# upstream omission?
+	echo ${PV} > VERSION
+}
+
+src_configure() {
+	# Let autoconf do its job and then fix things to build fbida
+	# according to our specifications
+	emake Make.config
+
+	gentoo_fbida() {
+		local useflag=${1}
+		local config=${2}
+
+		local option="no"
+		use ${useflag} && option="yes"
+
+		sed -i \
+			-e "s|HAVE_${config}.*|HAVE_${config} := ${option}|" \
+			"${S}/Make.config" || die
+	}
+
+	gentoo_fbida X MOTIF
+	gentoo_fbida curl LIBCURL
+	gentoo_fbida fbcon LINUX_FB_H
+	gentoo_fbida gif LIBUNGIF
+	gentoo_fbida lirc LIBLIRC
+	gentoo_fbida pdf LIBTIFF
+	gentoo_fbida png LIBPNG
+	gentoo_fbida scanner LIBSANE
+	gentoo_fbida tiff LIBTIFF
+	gentoo_fbida webp LIBWEBP
+}
+
+src_compile() {
+	emake verbose=yes
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		STRIP="" \
+		prefix=/usr \
+		install
+
+	dodoc README
+
+	if use fbcon && ! use pdf; then
+		rm "${D}"/usr/bin/fbgs "${D}"/usr/share/man/man1/fbgs.1 || die
+	fi
+
+	if use X ; then
+		doicon "${WORKDIR}"/ida.png
+		domenu desktop/ida.desktop
+	fi
+}