[gentoo-commits] repo/gentoo:master commit in: sci-libs/coinor-cgl/

[Michael Orlitzky]

commit:     8a5725be549e222fa1ebf14b9e0624a6ddf87b30
Author:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
AuthorDate: Thu May  7 17:13:39 2020 +0000
Commit:     Michael Orlitzky <mjo <AT> gentoo <DOT> org>
CommitDate: Fri May  8 12:20:38 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8a5725be

sci-libs/coinor-cgl: new EAPI=7 version 0.60.3.

Standardish EAPI/version bump, documenting all of the coinor-*
weirdness that I'm now familiar with. I added a subslot 0/1
corresponding to the major soname component in, for example,
libCgl.so.1.10.3.

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Michael Orlitzky <mjo <AT> gentoo.org>

 sci-libs/coinor-cgl/Manifest                 |  2 +-
 sci-libs/coinor-cgl/coinor-cgl-0.58.6.ebuild | 68 -----------------------
 sci-libs/coinor-cgl/coinor-cgl-0.60.3.ebuild | 81 ++++++++++++++++++++++++++++
 3 files changed, 82 insertions(+), 69 deletions(-)

diff --git a/sci-libs/coinor-cgl/Manifest b/sci-libs/coinor-cgl/Manifest
index cadc72470a7..d3c44518e2e 100644
--- a/sci-libs/coinor-cgl/Manifest
+++ b/sci-libs/coinor-cgl/Manifest
@@ -1 +1 @@
-DIST Cgl-0.58.6.tgz 5331274 BLAKE2B 6bd7218b7e87a700b74be322ab0b74dbab81590b0b77361d48247fc1d113db9ab9b878af987e22885ed3c2fde2e7d8641cd4e3977d5c4787fe1dcec3e2e3ef37 SHA512 28fe2e570cb2ebfa3109ca53e5ebb7dd3a38e2ddcfda4d7a9a1d78d4784abe1b6ab79734e6cbcee48e21791fe8353658df47d11253b04366ccb66c3e566db585
+DIST coinor-cgl-0.60.3.tar.gz 1267590 BLAKE2B 54a215c98bc05c65d46b6c7a469e28f06d04372e257825122693f0953582c8f1be2ede91efccdd21635dc365671653f0321d314ac41d1da01b561c2173a42da4 SHA512 e34080b893cfe46f99ffee093235618679ed47b6bed9798ea2d0dc0678716d9b8d947a66f6a6b283fe41807eb323dfcb512ba39d8d73fda1efafad92c408be9d

diff --git a/sci-libs/coinor-cgl/coinor-cgl-0.58.6.ebuild b/sci-libs/coinor-cgl/coinor-cgl-0.58.6.ebuild
deleted file mode 100644
index 8b038be15c7..00000000000
--- a/sci-libs/coinor-cgl/coinor-cgl-0.58.6.ebuild
+++ /dev/null
@@ -1,68 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-
-inherit autotools-utils multilib
-
-MYPN=Cgl
-
-DESCRIPTION="COIN-OR cutting-plane generators library"
-HOMEPAGE="https://projects.coin-or.org/Cgl/"
-SRC_URI="http://www.coin-or.org/download/source/${MYPN}/${MYPN}-${PV}.tgz"
-
-LICENSE="EPL-1.0"
-SLOT="0"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="doc examples static-libs test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	sci-libs/coinor-clp:=
-	sci-libs/coinor-dylp:=
-	sci-libs/coinor-osi:=
-	sci-libs/coinor-utils:=
-	sci-libs/coinor-vol:="
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen[dot] )
-	test? ( sci-libs/coinor-sample )"
-
-S="${WORKDIR}/${MYPN}-${PV}/${MYPN}"
-
-src_prepare() {
-	# needed for the --with-coin-instdir
-	dodir /usr
-	sed -i \
-		-e "s:lib/pkgconfig:$(get_libdir)/pkgconfig:g" \
-		configure || die
-	autotools-utils_src_prepare
-}
-
-src_configure() {
-	local myeconfargs=(
-		--enable-dependency-linking
-		--with-coin-instdir="${ED}"/usr
-		$(use_with doc dot)
-	)
-	autotools-utils_src_configure
-}
-
-src_compile() {
-	autotools-utils_src_compile all $(usex doc doxydoc "")
-}
-
-src_test() {
-	autotools-utils_src_test test
-}
-
-src_install() {
-	use doc && HTML_DOC=("${BUILD_DIR}/doxydocs/html/")
-	autotools-utils_src_install
-	# already installed
-	rm "${ED}"/usr/share/coin/doc/${MYPN}/{README,AUTHORS,LICENSE} || die
-	if use examples; then
-		insinto /usr/share/doc/${PF}
-		doins -r examples
-	fi
-}

diff --git a/sci-libs/coinor-cgl/coinor-cgl-0.60.3.ebuild b/sci-libs/coinor-cgl/coinor-cgl-0.60.3.ebuild
new file mode 100644
index 00000000000..eba0819dcc2
--- /dev/null
+++ b/sci-libs/coinor-cgl/coinor-cgl-0.60.3.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Cgl
+
+DESCRIPTION="COIN-OR cut-generation library"
+HOMEPAGE="https://projects.coin-or.org/Cgl/"
+SRC_URI="https://github.com/coin-or/${MY_PN}/archive/releases/${PV}.tar.gz
+	-> ${P}.tar.gz"
+LICENSE="EPL-1.0"
+
+# major soname component
+SLOT="0/1"
+
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples static-libs test"
+RESTRICT="!test? ( test )"
+
+# Fortran is NOT needed, but the ./configure scripts for all of the CoinOR
+# packages contain a check for it. Gentoo bug 601648 and upstream issue,
+#
+#   https://github.com/coin-or/CoinUtils/issues/132
+#
+BDEPEND="virtual/fortran
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] )
+	test? ( sci-libs/coinor-sample )"
+
+DEPEND="sci-libs/coinor-clp:=
+	sci-libs/coinor-dylp:=
+	sci-libs/coinor-osi:=
+	sci-libs/coinor-utils:=
+	sci-libs/coinor-vol:="
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-releases-${PV}/${MY_PN}"
+
+src_prepare() {
+	# Needed to make the --with-coin-instdir in src_configure happy.
+	dodir /usr
+
+	# They don't need to guess at this, but they do, and get it wrong...
+	sed -e "s:lib/pkgconfig:$(get_libdir)/pkgconfig:g" \
+		-i configure \
+		|| die "failed to fix the pkgconfig path in ${S}/configure"
+
+	default
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-dependency-linking
+		--with-coin-instdir="${ED}/usr"
+		$(use_with doc dot)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake all $(usex doc doxydoc "")
+}
+
+src_test() {
+	# NOT redundant! The build system has a "make check" target that does
+	# nothing, so if you don't specify "test" here, you'll get a no-op.
+	emake test
+}
+
+src_install() {
+	use doc && HTML_DOC=("${BUILD_DIR}/doxydocs/html/")
+
+	emake DESTDIR="${D}" install
+
+	# Duplicate junk, and in the wrong location.
+	rm -r "${ED}/usr/share/coin/doc/${MY_PN}" || die
+
+	use examples && dodoc -r examples
+}