[gentoo-commits] repo/gentoo:master commit in: dev-python/bpython/, profiles/

[Sebastian Pipping]

commit:     4bd3056066c2ecbfebd14196f25101afe5fd2a43
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  7 17:52:11 2020 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Sat Mar  7 17:56:30 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4bd30560

dev-python/bpython: EAPI 7 + py37 + py38

Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-2.3.92, Repoman-2.3.20

 dev-python/bpython/bpython-0.18-r1.ebuild | 57 +++++++++++++++++++++++++++++++
 profiles/package.mask                     |  1 -
 2 files changed, 57 insertions(+), 1 deletion(-)

diff --git a/dev-python/bpython/bpython-0.18-r1.ebuild b/dev-python/bpython/bpython-0.18-r1.ebuild
new file mode 100644
index 00000000000..fa686ecb025
--- /dev/null
+++ b/dev-python/bpython/bpython-0.18-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Syntax highlighting and autocompletion for the Python interpreter"
+HOMEPAGE="https://www.bpython-interpreter.org/ https://github.com/bpython/bpython https://pypi.org/project/bpython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/curtsies-0.2.11[${PYTHON_USEDEP}]
+	dev-python/greenlet[${PYTHON_USEDEP}]
+	dev-python/jedi[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	>=dev-python/six-1.5[${PYTHON_USEDEP}]
+	dev-python/urwid[${PYTHON_USEDEP}]
+	dev-python/watchdog[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+DOCS=( AUTHORS CHANGELOG sample.theme light.theme )
+
+# Req'd for clean build by each impl
+DISTUTILS_IN_SOURCE_BUILD=1
+
+RESTRICT="test" #659110
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build -b html -c doc/sphinx/source/ \
+			doc/sphinx/source/ doc/sphinx/source/html || die "docs build failed"
+	fi
+}
+
+python_test() {
+	pushd build/lib > /dev/null
+	"${PYTHON}" -m unittest discover || die
+	popd > /dev/null
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/sphinx/source/html/. )
+	distutils-r1_python_install_all
+}

diff --git a/profiles/package.mask b/profiles/package.mask
index af352e79797..2d052301c5e 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -54,7 +54,6 @@ dev-python/bcolz
 dev-python/beaker
 dev-python/biplist
 dev-python/blaze
-dev-python/bpython
 dev-python/cgroup-utils
 dev-python/chameleon
 dev-python/colander