[gentoo-commits] repo/gentoo:master commit in: app-misc/mmv/

[Patrice Clement]

commit:     d2c5dbbe7d14460ae750258e4c5ec70c40cc72c9
Author:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
AuthorDate: Fri Feb  8 17:12:42 2019 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Wed Feb 13 22:16:38 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d2c5dbbe

app-misc/mmv: EAPI 6 bump.

Signed-off-by: Patrice Clement <monsieurp <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 app-misc/mmv/mmv-1.01b_p18-r1.ebuild | 49 ++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/app-misc/mmv/mmv-1.01b_p18-r1.ebuild b/app-misc/mmv/mmv-1.01b_p18-r1.ebuild
new file mode 100644
index 00000000000..2b92035c6ac
--- /dev/null
+++ b/app-misc/mmv/mmv-1.01b_p18-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic toolchain-funcs
+
+DEB_PATCH_VER=${PV#*_p}
+MY_VER=${PV%_p*}
+
+DESCRIPTION="Move/copy/append/link multiple files according to a set of wildcard patterns"
+HOMEPAGE="https://packages.debian.org/unstable/utils/mmv"
+SRC_URI="
+	mirror://debian/pool/main/m/mmv/${PN}_${MY_VER}.orig.tar.gz
+	mirror://debian/pool/main/m/mmv/${PN}_${MY_VER}-${DEB_PATCH_VER}.debian.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+
+S="${WORKDIR}/${PN}-${MY_VER}.orig"
+
+src_prepare() {
+	default
+	epatch "${WORKDIR}"/debian/patches/*.diff
+}
+
+src_compile() {
+	# i wonder how this works on other platforms if CFLAGS from makefile are
+	# overridden, see bug #218082
+	[[ ${CHOST} == *-interix* ]] && append-flags -DIS_SYSV -DHAS_RENAME -DHAS_DIRENT
+	[[ ${CHOST} == *-interix* ]] || append-lfs-flags
+
+	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin "${PN}"
+	dosym "${PN}" /usr/bin/mcp
+	dosym "${PN}" /usr/bin/mln
+	dosym "${PN}" /usr/bin/mad
+
+	doman "${PN}.1"
+	newman "${PN}.1" mcp.1
+	newman "${PN}.1" mln.1
+	newman "${PN}.1" mad.1
+
+	dodoc ANNOUNCE "${WORKDIR}"/debian/{changelog,control}
+}