[gentoo-commits] repo/gentoo:master commit in: dev-libs/ell/

[Lars Wendler]

commit:     99364bc1f359cdcb9dbe3d0e58fdfefb3449486d
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Sep  7 21:48:35 2020 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Sep  7 21:48:35 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=99364bc1

dev-libs/ell: Bump to version 0.33

Package-Manager: Portage-3.0.5, Repoman-3.0.1
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 dev-libs/ell/Manifest        |  1 +
 dev-libs/ell/ell-0.33.ebuild | 60 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-libs/ell/Manifest b/dev-libs/ell/Manifest
index 62f16b1d85e..cea893a53b4 100644
--- a/dev-libs/ell/Manifest
+++ b/dev-libs/ell/Manifest
@@ -1,3 +1,4 @@
 DIST ell-0.28.tar.xz 474880 BLAKE2B 2c571f952056c9f4e3e8c245b2b57645c4baa2935fdbe758170dcfe689f4db2162322f25a80cc5a7d4d5bded6159d1fa0d583be979a2708d32e61e91d1ced585 SHA512 6c3aef4d403878c0c9b8a1e5e8861656f2abbab19dd275b1aecca899ca615c00aee30e18f194435ec6be859adcffbe3703a79b13508e1e76c2192ec51f7c0cd7
 DIST ell-0.31.tar.xz 478860 BLAKE2B f8f8d109605bf62396da001bd3d9b48fd6b7a6fc94ab890ab5a56fc8afb07a216b884fdf4b624ac8f39c3196de8149c7b32790da03262400aac6f8cd8b3fb56b SHA512 e304cc3bb1355fc0671412e793530503c83b1a036bfa3dd5b0cc36cfb28684b780293dc3d81a5727e0030743529882f71ac28d3c735860f6d46477e8ccf6a6e8
 DIST ell-0.32.tar.xz 479012 BLAKE2B 909c63f590ba45e5e9aabf0e7c5ce1c44ee5b5235472071ec16c4e160eddfd38dc5383103a684c4d43e325e832965cdade5d8465990ed4c2a2aa44b52d60869b SHA512 13712ac4ff7165b749b8e2dcd5cad4cd8170600c3dca7304eb4068ee916c1187207bc24ffa5d64c9d33253d4a8f56c63b627ad0783d5ca38d78f625211fdc315
+DIST ell-0.33.tar.xz 490180 BLAKE2B fc0f558a54bd57d7866c77ba3fdd97e0f35c33fd7ca79f6209c097824b303e69924ee9eb758af3a1881e8e87ac3ad84bea20767cd824cb8366a080eacac8b4be SHA512 4f0960b757c5cae55bf46a10aabb52280a76eda2a2d55ecc92f2a1321b72e936cab47102995597e985072d032f10379fdfc4f56360e535eeac444dab8b171ded

diff --git a/dev-libs/ell/ell-0.33.ebuild b/dev-libs/ell/ell-0.33.ebuild
new file mode 100644
index 00000000000..6c1b0433977
--- /dev/null
+++ b/dev-libs/ell/ell-0.33.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic linux-info multilib-minimal
+
+DESCRIPTION="Embedded Linux Library provides core, low-level functionality for system daemons"
+HOMEPAGE="https://01.org/ell"
+if [[ "${PV}" == *9999 ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git"
+else
+	SRC_URI="https://mirrors.edge.kernel.org/pub/linux/libs/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+fi
+LICENSE="LGPL-2.1"
+SLOT="0"
+
+IUSE="glib pie test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	glib? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+	test? ( sys-apps/dbus )
+"
+
+CONFIG_CHECK="
+	~TIMERFD
+	~EVENTFD
+	~CRYPTO_USER_API
+	~CRYPTO_USER_API_HASH
+	~CRYPTO_MD5
+	~CRYPTO_SHA1
+	~KEY_DH_OPERATIONS
+"
+
+src_prepare() {
+	default
+	[[ "${PV}" == *9999 ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	append-cflags "-fsigned-char" #662694
+	local myeconfargs=(
+		$(use_enable glib)
+		$(use_enable pie)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	local DOCS=( ChangeLog README )
+	einstalldocs
+
+	find "${ED}" -name "*.la" -delete || die
+}