[gentoo-commits] gentoo-x86 commit in dev-ml/ocamlnet: ocamlnet-3.4.1.ebuild ChangeLog

[Alexis Ballier (aballier)]

aballier    11/11/02 15:05:41

  Modified:             ChangeLog
  Added:                ocamlnet-3.4.1.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha72/cvs/Linux x86_64)

Revision  Changes    Path
1.54                 dev-ml/ocamlnet/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?rev=1.54&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?rev=1.54&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ChangeLog?r1=1.53&r2=1.54

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v
retrieving revision 1.53
retrieving revision 1.54
diff -u -r1.53 -r1.54
--- ChangeLog	9 Sep 2011 15:25:49 -0000	1.53
+++ ChangeLog	2 Nov 2011 15:05:41 -0000	1.54
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ml/ocamlnet
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v 1.53 2011/09/09 15:25:49 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ChangeLog,v 1.54 2011/11/02 15:05:41 aballier Exp $
+
+*ocamlnet-3.4.1 (02 Nov 2011)
+
+  02 Nov 2011; Alexis Ballier <aballier@g.o> +ocamlnet-3.4.1.ebuild:
+  version bump
 
 *ocamlnet-3.4 (09 Sep 2011)
 



1.1                  dev-ml/ocamlnet/ocamlnet-3.4.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ocamlnet-3.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ml/ocamlnet/ocamlnet-3.4.1.ebuild?rev=1.1&content-type=text/plain

Index: ocamlnet-3.4.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/ocamlnet/ocamlnet-3.4.1.ebuild,v 1.1 2011/11/02 15:05:41 aballier Exp $

EAPI="2"

inherit eutils findlib

MY_P=${P/_beta/test}
DESCRIPTION="Modules for OCaml application-level Internet protocols"
HOMEPAGE="http://projects.camlcity.org/projects/ocamlnet.html"
SRC_URI="http://download.camlcity.org/download/${MY_P}.tar.gz"

LICENSE="as-is GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"
IUSE="cryptokit gtk ssl tk httpd +ocamlopt +pcre zip"
RESTRICT="installsources"

# the auth-dh compile flag has been disabled as well, since it depends on
# ocaml-cryptgps, which is not available.

DEPEND=">=dev-ml/findlib-1.0
		pcre? ( >=dev-ml/pcre-ocaml-5 )
		>=dev-lang/ocaml-3.10.2[tk?,ocamlopt?]
		cryptokit? ( dev-ml/cryptokit )
		gtk? ( >=dev-ml/lablgtk-2 )
		ssl? ( >=dev-ml/ocaml-ssl-0.4 )
		zip? ( dev-ml/camlzip )
		"
RDEPEND="${DEPEND}"

S=${WORKDIR}/${MY_P}

ocamlnet_use_with() {
	if use $1; then
		echo "-with-$2"
	else
		echo "-without-$2"
	fi
}

ocamlnet_use_enable() {
	if use $1; then
		echo "-enable-$2"
	else
		echo "-disable-$2"
	fi
}

src_configure() {
	./configure \
	    -bindir /usr/bin \
		-datadir /usr/share/${PN} \
		$(ocamlnet_use_enable cryptokit crypto) \
		$(ocamlnet_use_enable gtk gtk2) \
		$(ocamlnet_use_enable pcre pcre) \
		$(ocamlnet_use_enable ssl ssl) \
		$(ocamlnet_use_enable tk tcl) \
		$(ocamlnet_use_enable zip zip) \
		$(ocamlnet_use_with httpd nethttpd) \
		|| die "Error : econf failed!"
}

src_compile() {
	emake -j1 all || die "make failed"
	if use ocamlopt; then
		emake -j1 opt || die "make failed"
	fi
}

src_install() {
	export STRIP_MASK="*/bin/*"
	findlib_src_install
}