[gentoo-commits] repo/gentoo:master commit in: xfce-base/xfce4-panel/

[Michał Górny]

commit:     244d092bd4e212f1625e83a0266e637f789cf03a
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 11 04:36:47 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jan 11 05:08:00 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=244d092b

xfce-base/xfce4-panel: Bump to 4.14.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-base/xfce4-panel/Manifest                  |  1 +
 xfce-base/xfce4-panel/xfce4-panel-4.14.2.ebuild | 69 +++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/xfce-base/xfce4-panel/Manifest b/xfce-base/xfce4-panel/Manifest
index 1b3bda547be..014c249265c 100644
--- a/xfce-base/xfce4-panel/Manifest
+++ b/xfce-base/xfce4-panel/Manifest
@@ -1,2 +1,3 @@
 DIST xfce4-panel-4.14.1.tar.bz2 1294087 BLAKE2B d88100d068348aab32f7a133ca98e17c1586f3d6c5ffcb53493e953930108d4d1ebd0972d84c4bd077ab58c4a3ae34303682084daff4e34a168c5c2f981597bf SHA512 1c86362489677f2e04cf3b98dbc1a80b4998335c00a47d256e741446f00437ad04539041648848eca1f45fa1fa70974ca6cf65cb7f762a79a46c16484557e400
+DIST xfce4-panel-4.14.2.tar.bz2 1304078 BLAKE2B 9f504dbfac36db08de8f6eb1ea63f6c985790eb2fb31932bc5ea06895d705ed808bc8a63d42afe4ed6ead625d3cb1dfebb95098691a586af24b505b73af2310b SHA512 7582c47cf191becad32c032adf24dc351d0d60bcbb8dc4b52eb5d0ec14cc9c6fcf7dba42a2c1ca506a88068af8ff817837d73b75d13e0910868a96462660efbb
 DIST xfce4-panel-4.15.0.tar.bz2 1271290 BLAKE2B 6062ed76d8372f5e1ab9def67bcc8c4006ef269309b47740c331c8afef8f320069478846e802c6a090c4a6aa465d79c75e028d52b8f09dd8e1dafa11c8d415ec SHA512 3f4d9a097cb9b9a4ec4296b518e91b13394ca063664c78768dc3e2a964090177485c189c3ff3e118b179d58aafdb27d2edf67ddb49434290eaed157b449fc817

diff --git a/xfce-base/xfce4-panel/xfce4-panel-4.14.2.ebuild b/xfce-base/xfce4-panel/xfce4-panel-4.14.2.ebuild
new file mode 100644
index 00000000000..4c13761e1a6
--- /dev/null
+++ b/xfce-base/xfce4-panel/xfce4-panel-4.14.2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit vala xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+gtk2 introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!gtk2? ( test )"
+
+RDEPEND=">=dev-libs/glib-2.42
+	>=x11-libs/cairo-1
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	x11-libs/libX11
+	x11-libs/libwnck:3
+	>=xfce-base/exo-0.11.2:=
+	>=xfce-base/garcon-0.5:=
+	>=xfce-base/libxfce4ui-4.13:=
+	>=xfce-base/libxfce4util-4.13:=[introspection?]
+	>=xfce-base/xfconf-4.13:=
+	gtk2? ( >=x11-libs/gtk+-2.20:2 )
+	introspection? ( dev-libs/gobject-introspection:= )"
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-lang/perl
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable gtk2)
+		$(use_enable introspection)
+		$(use_enable vala)
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}