[gentoo-commits] gentoo-x86 commit in app-text/xpdf: xpdf-3.02-r3.ebuild ChangeLog

[Peter Alfredsen (loki_val)]

loki_val    09/08/24 11:44:42

  Modified:             ChangeLog
  Added:                xpdf-3.02-r3.ebuild
  Log:
  Add xpdf-3.02-r3, which is patched to work with >=poppler-0.11.3
  (Portage version: 2.2_rc39/cvs/Linux x86_64)

Revision  Changes    Path
1.181                app-text/xpdf/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/xpdf/ChangeLog?rev=1.181&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/xpdf/ChangeLog?rev=1.181&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/xpdf/ChangeLog?r1=1.180&r2=1.181

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/xpdf/ChangeLog,v
retrieving revision 1.180
retrieving revision 1.181
diff -u -r1.180 -r1.181
--- ChangeLog	14 May 2009 19:54:42 -0000	1.180
+++ ChangeLog	24 Aug 2009 11:44:42 -0000	1.181
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/xpdf
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/xpdf/ChangeLog,v 1.180 2009/05/14 19:54:42 loki_val Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/xpdf/ChangeLog,v 1.181 2009/08/24 11:44:42 loki_val Exp $
+
+*xpdf-3.02-r3 (24 Aug 2009)
+
+  24 Aug 2009; Peter Alfredsen <loki_val@g.o> +xpdf-3.02-r3.ebuild:
+  Add xpdf-3.02-r3, which is patched to work with >=poppler-0.11.3
 
   14 May 2009; Peter Alfredsen <loki_val@g.o>
   -files/poppler-0.10.0.patch, -xpdf-3.02-r1.ebuild, xpdf-3.02-r2.ebuild,



1.1                  app-text/xpdf/xpdf-3.02-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/xpdf/xpdf-3.02-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/xpdf/xpdf-3.02-r3.ebuild?rev=1.1&content-type=text/plain

Index: xpdf-3.02-r3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/xpdf/xpdf-3.02-r3.ebuild,v 1.1 2009/08/24 11:44:42 loki_val Exp $

EAPI=2

inherit fdo-mime gnome2 eutils flag-o-matic

DESCRIPTION="An X Viewer for PDF Files"
HOMEPAGE="http://www.foolabs.com/xpdf/"
SRC_URI="http://gentooexperimental.org/~genstef/dist/${P}-poppler-20071121.tar.bz2
	mirror://gentoo/xpdf-3.02-patchset-01.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nodrm"

RDEPEND="
	>=virtual/poppler-0.11.3
	x11-libs/openmotif
	x11-libs/libX11
	x11-libs/libXpm
	nls? ( >=app-text/poppler-data-0.2.1 )
	"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${P}-poppler

PATCHDIR="${WORKDIR}/${PV}"

pkg_setup() {
	append-flags '-DSYSTEM_XPDFRC="\"/etc/xpdfrc\""'
	# We know it's there, probably won't get rid of it, so let's make
	# the build output readable by removing it.
	einfo "Suppressing warning overload with -Wno-write-strings"
	append-cxxflags -Wno-write-strings
}

src_prepare() {
	export EPATCH_SUFFIX=patch
	export EPATCH_SOURCE="${PATCHDIR}"
	epatch
	use nodrm && epatch "${PATCHDIR}/xpdf-3.02-poppler-nodrm.patch"
}

src_configure() {
	:
}

src_compile() {
	emake || die
}

src_install() {
	dobin xpdf || die
	doman xpdf.1 || die
	insinto /etc || die
	doins "${PATCHDIR}"/xpdfrc || die
	dodoc README ANNOUNCE CHANGES || die
	doicon "${PATCHDIR}"/xpdf.png || die
	insinto /usr/share/applications || die
	doins "${PATCHDIR}"/xpdf.desktop || die
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}