[gentoo-commits] gentoo-x86 commit in app-misc/mc: mc-4.7.0.2-r1.ebuild ChangeLog

[Alex Alexander (wired)]

wired       10/02/10 10:56:15

  Modified:             ChangeLog
  Added:                mc-4.7.0.2-r1.ebuild
  Log:
  [app-misc/mc-4.7.0.2-r1] added patches that fix bugs #298997 and #300913
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.188                app-misc/mc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?rev=1.188&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?rev=1.188&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/ChangeLog?r1=1.187&r2=1.188

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v
retrieving revision 1.187
retrieving revision 1.188
diff -u -r1.187 -r1.188
--- ChangeLog	10 Feb 2010 04:37:09 -0000	1.187
+++ ChangeLog	10 Feb 2010 10:56:14 -0000	1.188
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/mc
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.187 2010/02/10 04:37:09 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.188 2010/02/10 10:56:14 wired Exp $
+
+*mc-4.7.0.2-r1 (10 Feb 2010)
+
+  10 Feb 2010; Alex Alexander <wired@g.o> +mc-4.7.0.2-r1.ebuild,
+  +files/mc-4.7.0.2_hotlist_fix.patch, +files/mc-4.7.0.2_syntax_fix.patch:
+  added patches that fix bugs #298997 and #300913
 
   10 Feb 2010; Joseph Jezak <josejx@g.o> mc-4.7.0.1.ebuild:
   Marked ppc stable for bug #302733.



1.1                  app-misc/mc/mc-4.7.0.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/mc-4.7.0.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/mc/mc-4.7.0.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: mc-4.7.0.2-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.7.0.2-r1.ebuild,v 1.1 2010/02/10 10:56:14 wired Exp $

EAPI=2

inherit base

MY_P=${P/_/-}

DESCRIPTION="GNU Midnight Commander is a text based file manager"
HOMEPAGE="http://www.midnight-commander.org"
SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="+edit gpm nls samba slang X"

RDEPEND=">=dev-libs/glib-2.8:2
	gpm? ( sys-libs/gpm )
	kernel_linux? ( sys-fs/e2fsprogs )
	samba? ( net-fs/samba )
	slang? ( >=sys-libs/slang-2 )
	!slang? ( sys-libs/ncurses )
	X? ( x11-libs/libX11
		x11-libs/libICE
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libSM )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${MY_P}

# bugs (in patch order): #298997 #300913
PATCHES=(
	"${FILESDIR}/${P}_hotlist_fix.patch"
	"${FILESDIR}/${P}_syntax_fix.patch"
)

src_configure() {
	local myscreen=ncurses
	use slang && myscreen=slang

	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		--enable-vfs \
		$(use_enable kernel_linux vfs-undelfs) \
		--enable-charset \
		$(use_with X x) \
		$(use_with samba) \
		--with-configdir=/etc/samba \
		--with-codepagedir=/var/lib/samba/codepages \
		$(use_with gpm gpm-mouse) \
		--with-screen=${myscreen} \
		$(use_with edit)
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS README
}

pkg_postinst() {
	elog "To enable exiting to latest working directory,"
	elog "put this into your ~/.bashrc:"
	elog ". /usr/libexec/mc/mc.sh"
}