[gentoo-commits] gentoo-x86 commit in net-misc/youtube-viewer: youtube-viewer-3.1.1.ebuild ChangeLog

[Julian Ospald (hasufell)]

hasufell    14/06/20 17:46:03

  Modified:             ChangeLog
  Added:                youtube-viewer-3.1.1.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

Revision  Changes    Path
1.33                 net-misc/youtube-viewer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-viewer/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-viewer/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-viewer/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/youtube-viewer/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	11 May 2014 00:47:56 -0000	1.32
+++ ChangeLog	20 Jun 2014 17:46:03 -0000	1.33
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/youtube-viewer
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/youtube-viewer/ChangeLog,v 1.32 2014/05/11 00:47:56 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/youtube-viewer/ChangeLog,v 1.33 2014/06/20 17:46:03 hasufell Exp $
+
+*youtube-viewer-3.1.1 (20 Jun 2014)
+
+  20 Jun 2014; Julian Ospald <hasufell@g.o> +youtube-viewer-3.1.1.ebuild:
+  version bump
 
 *youtube-viewer-3.1.0 (11 May 2014)
 



1.1                  net-misc/youtube-viewer/youtube-viewer-3.1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-viewer/youtube-viewer-3.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/youtube-viewer/youtube-viewer-3.1.1.ebuild?rev=1.1&content-type=text/plain

Index: youtube-viewer-3.1.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/youtube-viewer/youtube-viewer-3.1.1.ebuild,v 1.1 2014/06/20 17:46:03 hasufell Exp $

EAPI=5

inherit gnome2-utils eutils perl-module vcs-snapshot

DESCRIPTION="A command line utility for viewing youtube-videos in Mplayer"
HOMEPAGE="http://trizen.googlecode.com"
SRC_URI="https://github.com/trizen/youtube-viewer/tarball/${PV} -> ${P}.tar.gz"

LICENSE="|| ( Artistic GPL-1+ )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gtk"

RDEPEND="
	>=dev-lang/perl-5.16.0
	dev-perl/Data-Dump
	dev-perl/libwww-perl
	|| ( media-video/mplayer[X,network]
		media-video/mplayer2[X,network]
		media-video/mpv[X] )
	virtual/perl-File-Spec
	virtual/perl-Getopt-Long
	virtual/perl-Term-ANSIColor
	virtual/perl-Text-ParseWords
	virtual/perl-Text-Tabs+Wrap
	gtk? (
		dev-perl/File-ShareDir
		>=dev-perl/gtk2-perl-1.244.0
		virtual/freedesktop-icon-theme
		x11-libs/gdk-pixbuf:2[X,jpeg]
	)"
DEPEND="virtual/perl-Module-Build"

SRC_TEST="do"

S=${WORKDIR}/${P}/WWW-YoutubeViewer

src_prepare() {
	perl-module_src_prepare
}

# build system installs files on "perl Build.PL" too
# do all the work in src_install
src_configure() { :; }
src_compile() { :; }

src_install() {
	local myconf
	if use gtk ; then
		myconf="--gtk-youtube-viewer"
	fi
	perl-module_src_configure
	perl-module_src_install

	if use gtk ; then
		domenu share/gtk-youtube-viewer.desktop
		doicon share/icons/gtk-youtube-viewer.png
	fi
}

pkg_preinst() {
	use gtk && gnome2_icon_savelist
	perl-module_pkg_preinst
}

pkg_postinst() {
	use gtk && gnome2_icon_cache_update
	perl-module_pkg_postinst
	einfo
	elog "optional dependencies:"
	elog "  dev-perl/LWP-Protocol-https or dev-perl/libwww-perl[ssl]"
	elog "  and virtual/perl-MIME-Base64"
	elog "    (for HTTPS protocol and login support)"
	elog "  dev-perl/Term-ReadLine-Gnu (for a better STDIN support)"
	elog "  dev-perl/Text-CharWidth (print the results in a fixed-width"
	elog "    format (--fixed-width, -W))"
	elog "  dev-perl/XML-Fast (faster XML to HASH conversion)"
	elog "  net-misc/gcap (for retrieving Youtube closed captions)"
	elog "  virtual/perl-File-Temp (for posting comments)"
	elog "  virtual/perl-Scalar-List-Utils (to shuffle the playlists"
	elog "    (--shuffle, -s))"
	elog "  virtual/perl-threads (threads support)"
	einfo
}

pkg_postrm() {
	use gtk && gnome2_icon_cache_update
	perl-module_pkg_postrm
}