[gentoo-commits] repo/gentoo:master commit in: kde-apps/kalzium/

[Andreas Sturmlechner]

commit:     e2f07d6875cab88da6ef41660a2ad237c4ae9392
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 30 16:15:32 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Apr 30 16:16:18 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e2f07d68

kde-apps/kalzium: Raise to minimum >=sci-libs/avogadrolibs-1.93

Thanks-to: Thomas Posch <bugs.gentoo.org <AT> online.posch.name>
Closes: https://bugs.gentoo.org/719814
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/kalzium/kalzium-20.04.0-r1.ebuild | 65 ++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/kde-apps/kalzium/kalzium-20.04.0-r1.ebuild b/kde-apps/kalzium/kalzium-20.04.0-r1.ebuild
new file mode 100644
index 00000000000..96fe3432827
--- /dev/null
+++ b/kde-apps/kalzium/kalzium-20.04.0-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.69.0
+QTMIN=5.12.3
+inherit ecm kde.org flag-o-matic
+
+DESCRIPTION="Periodic table of the elements"
+HOMEPAGE="https://kde.org/applications/education/org.kde.kalzium
+https://edu.kde.org/kalzium/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="editor solver"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtscript-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kplotting-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kunitconversion-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	editor? (
+		>=dev-qt/qtopengl-${QTMIN}:5
+		dev-cpp/eigen:3
+		>=kde-frameworks/knewstuff-${KFMIN}:5
+		sci-chemistry/openbabel
+		>=sci-libs/avogadrolibs-1.93[qt5]
+	)
+	solver? ( dev-ml/facile[ocamlopt] )
+"
+RDEPEND="${DEPEND}
+	sci-chemistry/chemical-mime-data
+"
+
+src_configure(){
+	# Fix missing finite()
+	[[ ${CHOST} == *-solaris* ]] && append-cppflags -DHAVE_IEEEFP_H
+
+	local mycmakeargs=(
+		$(cmake_use_find_package editor Eigen3)
+		$(cmake_use_find_package editor AvogadroLibs)
+		$(cmake_use_find_package editor OpenBabel2)
+		$(cmake_use_find_package solver OCaml)
+		$(cmake_use_find_package solver Libfacile)
+	)
+
+	ecm_src_configure
+}