[gentoo-commits] repo/gentoo:master commit in: dev-python/cffi/

[Michał Górny]

commit:     69112e61fe5517d5b69b1e71d47864ae89a660a8
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 14 06:07:54 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Oct 14 07:51:00 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=69112e61

dev-python/cffi: Bump to 1.15.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/cffi/Manifest           |  1 +
 dev-python/cffi/cffi-1.15.0.ebuild | 54 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 55 insertions(+)

diff --git a/dev-python/cffi/Manifest b/dev-python/cffi/Manifest
index 6eeb020fec8..1ef47710c4b 100644
--- a/dev-python/cffi/Manifest
+++ b/dev-python/cffi/Manifest
@@ -1 +1,2 @@
 DIST cffi-1.14.6.tar.gz 475744 BLAKE2B 46e3f1f61746f659c066d83fdb07b83c289eda68056c6f9e364ea6f30cd56c190e4fdb35586c064b2402483704a7c1e9399d7f30cb49a78eec21797146da36f2 SHA512 30a8b25b74921a90a1fa96d05de1f25437d0fbbf73b7de0bb9ce22dfcaccbd78376b605525fe970212221d3e598357a9b1da420bfbd1a3e513263ed2b789e813
+DIST cffi-1.15.0.tar.gz 484058 BLAKE2B 0d2d470c7eb11b8a9526be816b153c4483a5cfb529d3d220a804842facae1f06e2a822aa2be9abb1b5648cb36a97033bffc1dd235d83bdf8c075d67a907aa7d9 SHA512 ee83efde6f77f4a0c5889088c4c208ed7b9071fe06dfc16a8d2396de07f78fe859e1e39866760198a9d700f3b7359e8715e8a3e4907feb81d3fc4b8dd0dbaca1

diff --git a/dev-python/cffi/cffi-1.15.0.ebuild b/dev-python/cffi/cffi-1.15.0.ebuild
new file mode 100644
index 00000000000..8bf3a0a6b6e
--- /dev/null
+++ b/dev-python/cffi/cffi-1.15.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+# DO NOT ADD pypy to PYTHON_COMPAT
+# pypy bundles a modified version of cffi. Use python_gen_cond_dep instead.
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="Foreign Function Interface for Python calling C code"
+HOMEPAGE="https://cffi.readthedocs.io/ https://pypi.org/project/cffi/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+DEPEND="dev-libs/libffi:="
+RDEPEND="${DEPEND}
+	dev-python/pycparser[${PYTHON_USEDEP}]"
+BDEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+distutils_enable_sphinx doc/source
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/cffi-1.14.0-darwin-no-brew.patch
+)
+
+src_prepare() {
+	if [[ ${CHOST} == *darwin* ]] ; then
+		# Don't obsessively try to find libffi
+		sed -i -e "s/.*\-iwithsysroot\/usr\/include\/ffi.*/\tpass/" setup.py || die
+	fi
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	tc-export PKG_CONFIG
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# these tests call pip
+		testing/cffi0/test_zintegration.py
+	)
+
+	"${EPYTHON}" -c "import _cffi_backend as backend" || die
+	epytest \
+		c/ testing/
+}