[gentoo-commits] repo/gentoo:master commit in: sci-libs/liborigin/

[Andreas Sturmlechner]

commit:     c8d00ec1b9e699005b6accf710d16a05ef239cda
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 14 20:32:07 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Feb 14 20:42:41 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c8d00ec1

sci-libs/liborigin: Switch to Qt5 build

Bug: https://bugs.gentoo.org/644468
Package-Manager: Portage-2.3.24, Repoman-2.3.6

 sci-libs/liborigin/liborigin-20110829-r1.ebuild | 62 +++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/sci-libs/liborigin/liborigin-20110829-r1.ebuild b/sci-libs/liborigin/liborigin-20110829-r1.ebuild
new file mode 100644
index 00000000000..27e4ccbbe0f
--- /dev/null
+++ b/sci-libs/liborigin/liborigin-20110829-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils
+
+DESCRIPTION="Library for reading OriginLab OPJ project files"
+HOMEPAGE="http://soft.proindependent.com/liborigin2/"
+SRC_URI="https://dev.gentoo.org/~dilfridge/distfiles/${PN}2-${PV}.zip"
+
+LICENSE="GPL-3"
+SLOT="2"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc"
+
+RDEPEND="
+	dev-libs/boost
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-cpp/tree
+	doc? ( app-doc/doxygen )
+"
+
+DOCS=( readme FORMAT )
+
+S="${WORKDIR}"/${PN}${SLOT}
+
+src_prepare() {
+	default
+
+	cat >> liborigin2.pro <<-EOF
+		INCLUDEPATH += "${EPREFIX}/usr/include/tree"
+		headers.files = \$\$HEADERS
+		headers.path = "${EPREFIX}/usr/include/liborigin2"
+		target.path = "${EPREFIX}/usr/$(get_libdir)"
+		INSTALLS = target headers
+	EOF
+	# use system one
+	rm -f tree.hh || die
+}
+
+src_configure() {
+	eqmake5 liborigin2.pro
+}
+
+src_compile() {
+	default
+	if use doc; then
+		cd doc || die
+		doxygen Doxyfile || die "doc generation failed"
+	fi
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/html/. )
+	einstalldocs
+	emake install INSTALL_ROOT="${D}"
+}